[[20090623113502]]　『特定条件があるセルを別シートに一覧表示する』（エクセル初心者）　ページの最後に飛ぶ

『特定条件があるセルを別シートに一覧表示する』（エクセル初心者）

 初めまして、エクセル初心者です。
 今、顧客リストを作成しています。
 過去ログからうまくヒットした内容が見つからなかったのでお助けください。

 シート１に以下の表があります。

 　  A         B        C         D          E
 1　FAX送信　顧客名    住所     FAX番号    TEL番号
 2   ○      イチロー  aaaaaa   111-1111   00-0
 3  空欄     ジロー  　bbbbbb   222-22222  22-2222
 4   ○  　  サブロー  cccccc   33-33333   33-3333

 この中でFAX送信(A列)に○のある行を別のシートに一覧で表示したいです。
 ＶＬＯＯＫＵＰを使ったのですが、2行目は表示できたのですが4行目以降がうまく表示できません。
 マクロも考えたのですが、まだ初心者でわからないので関数で処理できればと思っています。

 どなたか教えていただけませんでしょうか。宜しくお願いいたします。
 使用エクセルのバージョンはMicrosoft Office Excel 2003です。

 参考になりますか？
[[20080704141202]]『ある条件を含む行を別シートにまとめたい』（あい）

 オートフィルタ等で抽出して
 貼り付けるのはだめでしょうか？

 数式で処理するのは向かないと思います。

 （えくせる青年）2009/6/23 12:22

 別シートのA2に
 =If(CountIf(Sheet1!$A$1:$A$10,"○")<Row($A1),"",
  Index(Sheet1!A$1:A$10,Small(Index((Sheet1!$A$1:$A$10<>"○")*9^9+Row($A$1:$A$10),),Row($A1))))
 と入力して、必要分右と下にフィルコピー。

 自分でするならば、Sheet1を別シートにリンク貼り付けし、オートフィルタを設定、A列をキーとして○を抽出して表示します。

 (ROUGE)

ご回答ありがとうございます。教えていただいた
『ある条件を含む行を別シートにまとめたい』は確認もれておりました。すいません。

参考になりますか？ [[20080704141202]]『ある条件を含む行を別シートにまとめたい』（あい）

→教えていただいた箇所にあった式を自分のエクセルに置きかえチャレンジしてみましたが、うまく表示できませんでした。。。。
式は=IF(ROW(1:1)>COUNTIF(Sheet1!$A$1:$A$6,$A$1),"",INDEX(Sheet1!B$1:B$6,SMALL(IF(Sheet1!$A$1:$A$6=$A$1,ROW(Sheet1!$A$1:$A$6),""),ROW(1:1))))です。

自分の勉強不足です。すいません。。。可能であれば上記の表に置き換えた式を教えていただけますか

（えくせる青年）さんご回答ありがとうございます。

オートフィルタ等で抽出して

 貼り付けるのはだめでしょうか？

やはりシートを修正したり、新規追加したりメンテも行うので可能であれば関数で自動表示させたいです。

 (ROUGE)さん、ご回答ありがとうございます。
教えていただいた式と”Sheet1を別シートにリンク貼り付けし、オートフィルタを設定、A列をキーとして○を抽出して表示”でやってみます。

 ＞自分の勉強不足です。すいません。。。可能であれば上記の表に置き換えた式を教えていただけますか 
 式自体は間違ってないと思いますよ！
 配列関数なんで Ctrl＋Alt＋Enter で確定されてますか？
 （とおりすがり）

 数式の一部に誤記があったので、修正しました。(ROUGE)

 =IF(ROW(1:1)>COUNTIF(Sheet1!$A$1:$A$6,$A$1),"",
    INDEX(Sheet1!B$1:B$6,SMALL(IF(Sheet1!$A$1:$A$6=$A$1,ROW(Sheet1!$A$1:$A$6),""),ROW(1:1))))
　　　　　　　　　　　　　　↓
 =IF(COUNTIF(Sheet1!$A$2:$A$6,"○")<ROW(A1),"",
    INDEX(Sheet1!B$1:B$6,SMALL(IF(Sheet1!$A$2:$A$6="○",ROW($A$2:$A$6)),ROW(A1))))

 Ctrl＋Alt＋Enter で配列確定（とおりすがりさんがご指摘しています）

 “達人”芳坂和行氏に学ぶ、エクセル(Excel)「配列数式」講座
http://pc.nikkeibp.co.jp/pc21/special/hr/index.shtml

 ※ROUGEさんの式を試されましたか。。。(EnterのみでOK)
 (gon-2)

 Sheet1
     A         B           C           D          E             F
1  FAX送信   顧客名       住所	FAX番号	  TEL番号	      作業列
2    ○	   イチロー    アメリカ	111-1111	  001-0001	1
3	   ジロー	        東京	222-2222	  002-0002	
4    ○	   サブロー      大阪	333-3333	  003-0003	3

 F2= =IF(A2="○",ROW(A1),"")
 フィルダウン

 Sheet2
      A             B          C           D
1   顧客名        住所	FAX番号	   TEL番号
2   イチロー    アメリカ	111-1111	   001-0001
3   サブロー      大阪	333-3333	   003-0003

 A2=IF(COUNT(Sheet1!$F$2:$F$4)<ROW(A1),"",
　　　INDEX(Sheet1!B$2:B$4,SMALL(Sheet1!$F$2:$F$4,ROW(A1))))
 D2までオートフィルして、A2:B2をフィルダウン

 こちらを試されてから、配列数式に取り組むのがよろしいと思います。。。(gon-2)

皆様
いろいろコメントいただきありがとうございました。
gon-2さんにいただいた式で無事対応できました。

本当にありがとうございました！！

 > Ctrl＋Alt＋Enter で配列確定（とおりすがりさんがご指摘しています）

 Ctrl＋Alt＋Enter ってなんじゃらほい？

 Ctrl＋Shift＋Enter　じゃなかとですか？　（たいしょう）

 ＞Ctrl＋Shift＋Enter　じゃなかとですか？

 これは失礼。
 ×：Ctrl＋Alt＋Enter
 ○：Ctrl＋Shift＋Enter
 （とおりすがり）

コメント返信：

[ 一覧(最新更新順) ]

[[20090623113502]] 『特定条件があるセルを別シートに一覧表示する』（エクセル初心者） ページの最後に飛ぶ

[[20090623113502]]　『特定条件があるセルを別シートに一覧表示する』（エクセル初心者）　ページの最後に飛ぶ