[[20120516101103]]　『2つの列を参照してカウントしたい』（sakura）　ページの最後に飛ぶ

『2つの列を参照してカウントしたい』（sakura）

 下記のような日報を作っています。
 ひと月ごとに1シートになっています。

  　A　　　　B　　　　　C　　　　　D
 1 場所　　行先　　　　　　　　　　　　　　（タイトル行です）
 2 現場　　東京　　
 3 工場
 4 現・工　大阪
 5 現場　　大阪
 6
 7
 8 
 9 ＜現場ごと集計＞　　東京　　　1
 10　　　　　　　　　　大阪　　　1.5

 行先ごとに1カウントしているのですが、
 A4のように「現・工」となっている場合は、
 半日だけ現場に行っているので、0.5カウントになります。
 また「工場」は会社にいるので、「行先」は空欄です。

 「行先」が、毎月変わるので集計の際にC列に行先名を入力して
 集計するように、下記の式を入れています。

 D9=IF(C9="","",COUNTIF($B$2:$B$5,CONCATENATE(C9)))

 これだと、すべて１カウントしてしまうので、
 A列を参照して、「現・工」の場合は0.5カウントにして集計したいのですが
 どのようにしたらいいでしょうか？

 過去ログも探したのですが、見つからなかったので・・
 よろしくお願いいたします。

 Windows 7　Excel2010

 もし、工・現っていうパターンがないんだったら
 =IF(C9="","",COUNTIFS(A$2:A$5,"現場",B$2:B$5,C9)+COUNTIFS(A$2:A$5,"現・工",B$2:B$5,C9)/2)
 または
 =IF(C9="","",SUM(COUNTIFS(A$2:A$5,{"現場","現・工"},B$2:B$5,C9)/{1,2}))

 工・現ってパターンもあるんだったら
 =IF(C9="","",COUNTIFS(A$2:A$5,"現場",B$2:B$5,C9)+COUNTIFS(A$2:A$5,"*・*",B$2:B$5,C9)/2)
 または
 =IF(C9="","",SUM(COUNTIFS(A$2:A$5,{"現場","*・*"},B$2:B$5,C9)/{1,2}))
 で、どうかな？
 (春日野馨)

 春日野馨さま

 ありがとうございました！
 出来ました。お世話になりました

 SAKURA

コメント返信：

[ 一覧(最新更新順) ]

[[20120516101103]] 『2つの列を参照してカウントしたい』（sakura） ページの最後に飛ぶ

[[20120516101103]]　『2つの列を参照してカウントしたい』（sakura）　ページの最後に飛ぶ