[[20120521000404]]　『Excelファイル・条件にて列と数字をまとめる』（Mik）　ページの最後に飛ぶ

『Excelファイル・条件にて列と数字をまとめる』（Mik）
現在、オーダシステムから宅配用のファイルに落とし込む
Excelファイル作成を行っています。

name No amount　set
hana 1 10 AA
taro 1 10 BB
taro 2 50 DD
masa 1 90 GG
↓
name No amount set
hana 1 10 AA
taro 1 60 BB
masa 1 90 GG

このようにNoが２以上（３，４など含む）の場合はNoを「１」に統一し、1列にまとめる。
更にAmountを合計させる。Amountではない項目は
No[1]のに元々あった数値／文字を適用させる。

以上のような式を作ることは可能でしょうか？
ご教授のほう、よろしくお願いいたします。

バージョン「Excek2007」、「Win7」

 回答が付かないようなので、アイデアだけですが、
 オートフィルタで No = 1 でフィルタし、結果を別の列に出力。

 たとえばA:D 列を F:I列へ出力したとして
 H列に H1=SUMIF(A:A,F1,C:C) としてデータ範囲に出力
 でできないでしょうか。

 ただし、A列の名前は複数同じ群が無いことが条件になりそうです。
 (Mook)

	A	B	C	D	E	F	G	H	I
1	name	No	amount	set		name	No	amount	set
2	hana	1	10	AA		hana	1	10	AA
3	taro	1	10	BB		taro	1	60	BB
4	taro	2	50	DD		masa	1	140	GG
5	masa	1	90	GG		yuki	1	40	ZZ
6	masa	2	10	SS					
7	masa	3	30	RR					
8	masa	4	10	QQ					
9	yuki	1	40	ZZ					
10									
11

 F～I列でまとめ。

 F2 =A2  G2にコピー。
 I2 =D2

 F3 =IF(OR(F2="",INDEX(A$2:A$100,COUNTA(A$2:A$100))=F2),"",INDEX(A$2:A$100,MATCH(F2,A$2:A$100,0)+COUNTIF(A$2:A$100,F2)))
 G3 =IF(F3="","",1)
 I3 =IF(F3="","",INDEX(D$2:D$100,MATCH(F2,A$2:A$100,0)+COUNTIF(A$2:A$100,F2)))

 F3:I3を100行目までコピー。

 H2 =IF(F2="","",SUM(INDEX(C$2:C$100,MATCH(F2,$A$2:$A$100,0)):C$100)-SUM(H3:H$101))
 H2をH100までコピー。

 ※データ100行目まで
 ※H101セルは空欄で。
 ※A列名前ごとにB列 １、２、３ ・・・ と並んでいること。
 ※B列数値にダブリ並びが無いこと。
 ※A列名前のグループ（１、２、３の並び）が複数ないこと。
 ※A～D列2行目 かならず B列「1」 のこと。

 (GobGob)

 MookさんのSUMIF案がカンタンでしたなぁｗ。

 F2 =A2   F2 を I2までコピー。

 F3 =IF(SUM($H$2:$H2)=SUM($C:$C),"",INDEX(A:A,MATCH($F2,$A:$A,0)+COUNTIF($A:$A,$F2)))
 F3 を G3、I3にコピー。

 H3 =IF(F3="","",SUMIF(A:A,F3,C:C))

 F3:I3 を下へコピー。

 (GobGob)

コメント返信：

[ 一覧(最新更新順) ]

[[20120521000404]] 『Excelファイル・条件にて列と数字をまとめる』（Mik） ページの最後に飛ぶ

[[20120521000404]]　『Excelファイル・条件にて列と数字をまとめる』（Mik）　ページの最後に飛ぶ