[[20140422210810]]　『Wordの表をExcelに貼り付ける際に表内の文字がセメx（さらさ）　ページの最後に飛ぶ

『Wordの表をExcelに貼り付ける際に表内の文字がセル分割されてしまう』（さらさ）

Wordの表をエクセルに貼り付けたいのですが、Wordの表の中で1つのセル内の
文言に改行が入っているところがExcelに貼り付けた時に改セルになってしまい
複数のセルに分割されてしまいます。
Wordで1つのセル（改行あり）にあるデータをExcelでも1つのセルに入れることは
出来ないでしょうか。

wordからexcelにコピーしなければならない表が50ページ以上ありかなり大変です。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

何か方法があるのかもしれませんが、
ワードの表をエクセルに転記するマクロです。
結合セルとかない単純な表のみ対応です。

 新規シートをアクティブにした状態で、下記のマクロを実行です。
 シートに転記されます。

 Sub test()
    Dim myWd As Word.Application
    Dim myDoc As Word.Document
    Dim t As Table
    Dim r As Long, c As Long
    Dim i As Long, j As Long
    Dim v()
    Dim n As Long

    On Error Resume Next
    Set myWd = CreateObject("Word.Application")
    On Error GoTo 0
    myWd.Visible = True
    Set myDoc = myWd.Documents.Open("D:\***\****\***.docx") '★実際のwordファイルに修正

    For Each t In myDoc.Tables
        r = t.Rows.Count
        c = t.Columns.Count
        ReDim v(1 To r, 1 To c)
        For i = 1 To r
            For j = 1 To c
                With t.Cell(i, j).Range
                    v(i, j) = Replace(Replace(.Text, Chr(13) & Chr(7), ""), Chr(13), Chr(10))
                End With
            Next
        Next
        Range("A1").Offset(n).Resize(r, c).Value = v
        n = n + r + 1
    Next
    myDoc.Close
    myWd.Quit
    Set myDoc = Nothing
    Set myWd = Nothing
 End Sub

（マナ） 2014/04/22(火) 23:24

 手動方法

 まずワードで置換をする。
 置換の｢オプション」をクリックして｢あいまい検索」のチェックを外し、
 検索する文字列の欄に下の方の「特殊文字」ボタンを押して「段落記号」を選択。
 検索する文字列の欄に文章内で使われていない文字（例えば「♪」などの）をいれて「すべて置換」。

 この表をエクセルに貼り付けて、エクセルでも置換で、
 検索する文字列に「♪」、置換後の文字列の欄にCtrl+J（何も入力されていないように見えるけどセル内改行が入力されてる）
 を入れて｢すべて置換」する。

 同じブック内ならシートが分かれていても置換ダイアログの「検索場所」を「ブック」にすれば一回の置き換えで済むよ。

（1111） 2014/04/23(水) 09:02

（1111）さん

ありがとうございます。
この方法で対応できました！

（マナ）さんもありがとうございます。マクロは使用しませんでしたが感謝いたします。

（さらさ） 2014/04/23(水) 11:30

コメント返信：

[ 一覧(最新更新順) ]

[[20140422210810]] 『Wordの表をExcelに貼り付ける際に表内の文字がセメx（さらさ） ページの最後に飛ぶ

[[20140422210810]]　『Wordの表をExcelに貼り付ける際に表内の文字がセメx（さらさ）　ページの最後に飛ぶ