[[20140728114054]]　『項目の表示・非表示をしたい』（XENO）　ページの最後に飛ぶ

『項目の表示・非表示をしたい』（XENO）

いくつかの行で下記のように複数の項目を作成し、各項目をクリックしたら該当項目の詳細を表示（他項目の詳細は非表示）されるようにしたいと考えています。
グループ化で似たような状態にはなると思うのですが、文字列（またはセル）をクリック
して実行する方法はあるでしょうか。
なお、詳細項目にはそれぞれ異なるハイパーリンクを設定したいと考えています。

１）
＋項目Ａ
＋項目Ｂ
ー項目Ｃ
　　項目Ｃ１
　　項目Ｃ２
＋項目Ｄ

２）
＋項目Ａ
ー項目Ｂ
　　項目Ｂ１
＋項目Ｃ
＋項目Ｄ

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

左クリックのイベントは拾えないので、右クリックで代用。
あと、一般的なツリー表示に合わせ、クリックした以外の詳細項目は閉じない例です。

[標準モジュール]
Public Const IMAX = 9

 Sub Auto_Open()
    Dim i As Long

    With Sheets(1)
        .Range("A1") = "＋項目Ａ"
        .Range("A2") = "　　項目Ａ１"
        .Range("A3") = "＋項目Ｂ"
        .Range("A4") = "　　項目Ｂ１"
        .Range("A5") = "＋項目Ｃ"
        .Range("A6") = "　　項目Ｃ１"
        .Range("A7") = "　　項目Ｃ２"
        .Range("A8") = "＋項目Ｄ"
        .Range("A9") = "　　項目Ｄ１"

        For i = 1 To IMAX
            If Left(.Cells(i, "A").Value, 1) <> "＋" Then
                .Rows(i).EntireRow.Hidden = True
            Else
                .Rows(i).EntireRow.Hidden = False
            End If
        Next i
    End With
End Sub

[シートモジュール]

 Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    Dim i As Long

    If Target.Value = "" Then Exit Sub

    If Left(Target.Value, 1) = "＋" Then
        Target.Value = "－" & Mid(Target.Value, 2)
        For i = Target.Row + 1 To IMAX
            If Left(Cells(i, "A").Value, 1) <> "　" Then
                Exit For
            End If
            Rows(i).EntireRow.Hidden = False
        Next i
    ElseIf Left(Target.Value, 1) = "－" Then
        Target.Value = "＋" & Mid(Target.Value, 2)
        For i = Target.Row + 1 To IMAX
            If Left(Cells(i, "A").Value, 1) <> "　" Then
                Exit For
            End If
            Rows(i).EntireRow.Hidden = True
        Next i
    End If

    Cancel = True
End Sub
（???） 2014/07/28(月) 15:44

ご回答ありがとうございます。
ＶＢＡは未経験なので勉強してやってみます。
（XENO） 2014/07/28(月) 16:59

コメント返信：

[ 一覧(最新更新順) ]

[[20140728114054]] 『項目の表示・非表示をしたい』（XENO） ページの最後に飛ぶ

[[20140728114054]]　『項目の表示・非表示をしたい』（XENO）　ページの最後に飛ぶ