[[20140819163014]]　『重複するデータの先頭にフラグをつけるには』（tera）　ページの最後に飛ぶ

『重複するデータの先頭にフラグをつけるには』（tera）

上記の様に、B列に入力されている重複データの
最上位行にフラグを付けたいと
考えております。
数千行あり、マクロをご教授いただければ幸いです。

＜使用 Excel：Excel2010、使用 OS：unknown ＞

	[A]	[B]	
[1]	○	1111	
[2]		1111	
[3]		1111	
[4]	○	2222	
[5]		2222	
[6]		3333	←ここは提示した例だと重複していないようですが、○なんですか？
[7]	○	4444	
[8]		4444	
[9]		5555	←連続していない場合も○になりますか？
[10]		6666	
[11]		5555	←不連続

（稲葉） 2014/08/19(火) 17:13

説明不足をお詫びします。

[6]は重複しておりませんがユニークなデータなので○を付けたいです。
[9]連続していない場合も○を付けたいです。

初めて書き込むため、至らぬ点があればご指南願います。

（tera） 2014/08/19(火) 17:22

 こちらでいかがですか？
    Sub tera()
        Dim dic As Object
        Dim 基点 As Range
        Dim tbl
        Dim i As Long, tmp As String
        Dim Result
        Set dic = CreateObject("Scripting.Dictionary")
        Set 基点 = Range("B1")
        tbl = Application.Transpose(Range(基点, Cells(Rows.Count, 基点.Column).End(xlUp)).Value)
        ReDim Result(1 To UBound(tbl))
        For i = 1 To UBound(tbl)
            tmp = tbl(i)
            If Not dic.exists(tmp) Then
                dic.Add tmp, ""
                Result(i) = "○"
            End If
        Next i
        基点.Offset(, -1).Resize(UBound(tbl)).Value = Application.Transpose(Result)
    End Sub

（稲葉） 2014/08/19(火) 17:27

「基点」に何を書き込めばよいか分かりません。
エクセル初心者のため、お手数をおかけします。
（tera） 2014/08/19(火) 17:49

 基点は変数です。
 提示された表は行の指定がありませんでしたので、B1から始まるのか、B100から始まるのか
 分かりませんでした。

 デフォルトではB1からデータが始まっていることになっています。
 B100から始まるのであれば、
 Set 基点 = Range("B1")　ここを
 Set 基点 = Range("B100")このように

 B3512から始まるのであれば、
 Set 基点 = Range("B1")　 ここを
 Set 基点 = Range("B3512")このように直してください。

（稲葉） 2014/08/19(火) 18:01

迅速なご返信ありがとうございました。
（tera） 2014/08/19(火) 19:00

 Loopなしで
 Sub test()
    [a2:a1000] = [if(countif(offset(b2:b1000,,,row(1:1000)),b2:b1000)=1,"○","")]
End Sub
（seiya） 2014/08/19(火) 20:00

 teraさん少しスレッドお借りします。

 seiyaさん
 Evaluateの使い方で少し教えてください。
 研究スレで勉強してみて、自分なりに使っているのですが、今回のように範囲が可変になる場合の
 使い方が分かりませんでした。

 SUMIFで行毎の累計を出すやり方等など、「こういうときはこうする！」のような定石がありましたら、
 いくつか教えていただきたいです・・・。

 ちなみに今回のものは
 dim tmp
 tmp = filter([if(countif(offset(b2:b1000,,,row(1:1000)),b2:b1000)=1,b2:b1000,"-")],"-",False)
 のようにすれば、DictionaryやArrayListなどを使わずに重複の無い配列が取得できるよ
 うな使い方としても有効なのでしょうか？

（稲葉） 2014/08/20(水) 08:52

[[20130214110527]]　『重複チェックを行いたい』（ミカン）

 Evaluateでは、配列関数(Transpose等)以外の関数を使用して配列を返す場合は
 まず、仮想配列を作成してそこへ埋め込んでいくような作業になります。

 参考になりますか？

（seiya） 2014/08/20(水) 13:10

 dim tmp
 tmp = filter(Application.Transpose([if(countif(offset(b2:b1000,,,row(1:1000)),b2:b1000)=1,b2:b1000,"-")]),"-",False)
              ~~~~~~~~~~~~~~~~~~~~~             ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
                       (1)                                   (2)
 (1)1点目の間違いに気付きました・・
 (2)この「仮想配列」の考え方がいまいち理解出来ていないようで、ROW関数で配列作ってあげている
 　 ところまでは分かったのですが
 　 OFFSETの第4引数「高さ」に入れるとどのようになるのか?
 　 数式の検証も使ってみたのですがVALUEエラーのあと、2行目から1000行目までのCOUNTIFの配列が
 　 出来て、TRUE/FALSEの配列になり、すぐ結論になってしまい、OFFSETの「高さ」についてよく
 　 理解できませんでした・・・。

 当面「公式」のようにOFFSETを引数に使う方法を色々試して、後々理解できるように頑張ります！

 ありがとうございました。
（稲葉） 2014/08/20(水) 13:41

 仮想配列の考え方はちょっと難解かもしれませんが。

 If関数を使用して作成すると理解しやすいかな？
 4例目と5例目の結果に注目してください。
 Sub test()
    Dim temp
    temp = [countif(a1:a100,a1:a100)]
    temp = [if(row(1:100),countif(a1:a100,a1:a100))]
    temp = [countif(offset(a1:a100,,,row(1:100)),a1:a100)]
    temp = [if(countif(offset(a1:a100,,,row(1:100)),a1:a100)=1,"OK","NO")]
    temp = [if(row(1:100),countif(offset(a1:a100,,,row(1:100)),a1:a100))]
End Sub
（　seiya） 2014/08/20(水) 14:21

 3例目で躓きました・・・
 配列ではなく、数値が戻ってきたのですが、数式の検証をしてみると、OFFSETのところが&A&1に変換
 されてからCOUNTIFの計算がされます。
 これが4例目になるといきなり配列になっちゃうってところが頭が悪い所為でよくわかってないみたいです・・・

 4例目は各要素が1ならOK、それ以外ならNG
 5例目は疑似配列のROWを与えて、0以上（True）の配列を渡して、COUNTIFの戻り値になるというところ
 まで分かりました。偽はありえないので、省略されているのですかね？

 計算結果の理屈はわかるのに、配列にする理屈がわかっていない、そんな感じです。

（稲葉） 2014/08/20(水) 16:48

 3例目は、仮想配列ができてないので最初の値が返ってくるはずです。
 計算自体はできているがその結果を入れる器が無い状態です。

 そこで5例目でIf関数を使用して、仮想配列を作る。
 if(row(1:100)
 計算された結果が、配列に格納される。
（seiya） 2014/08/20(水) 16:58

 IF(ROW　はTrueFalseに関係なく、器を作るってことですね！
 といいつつ、まだまだ理解出来ていないところがありそうですので、何回も使ってみて徐々に理解して
 いきます・・・

 丁寧に教えていただいたのに申し訳ございません。
（稲葉） 2014/08/20(水) 17:39

コメント返信：

[ 一覧(最新更新順) ]

[[20140819163014]] 『重複するデータの先頭にフラグをつけるには』（tera） ページの最後に飛ぶ

[[20140819163014]]　『重複するデータの先頭にフラグをつけるには』（tera）　ページの最後に飛ぶ