[[20140917082504]]　『ＩＦ関数？』（1）　ページの最後に飛ぶ

『ＩＦ関数？』（1）

例えば
Ａ1セルに「3」が入ったらＢ1セルは「A」
Ａ1セルに「4」が入ったらＢ1セルは「B」
Ａ1セルに「5」が入ったらＢ1セルは「C」
Ａ1セルに「6」が入ったらＢ1セルは「D」
Ａ1セルに「7」が入ったらＢ1セルは「E」
Ａ1セルに「8」が入ったらＢ1セルは「F」
と、したいのですが、どのようにＩＦをつなげればいいのか？
ＩＦではなくどの関数を使ってどういう式になるのか
教えてください。
宜しくお願いいたします。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 IF案。

 =IF(A1=3,"A",IF(A1=4,"B",IF(A1=5,"C",IF(A1=6,"D",IF(A1=7,"E",IF(A1=8,"F",""))))))

 IFでない案。

 =LOOKUP(N(A1),{0,3,4,5,6,7,8,9},{"","A","B","C","D","E","F",""})

 =MID(" ABCDEF ",MIN(MAX(1,N(A1)-1),8),1)

 とか。

 =IF(AND(A1>=3,A1<=8),CHAR(62+A1),"") とかも。。。 ってこれIFつかってるｗｗ
　
（GobGob） 2014/09/17(水) 08:36 → 08:40 加筆

CHOOSE関数を使う

=IF(AND(A1<3,A1>8),"",CHOOSE(A1-2,"A","B","C","D","E","F"))

（wisemac21） 2014/09/17(水) 10:21

 作業列を使う
 例えばK3～K8にA～Fを入力しておく。

 B1 =IF(AND(A1>2,A1<9),INDIRECT("K"&A1),"")
（ところてん） 2014/09/18(木) 01:30

 Address関数を使う！
 B1=IFERROR(LEFT(ADDRESS(1,A1-2,2),1),"")
（稲葉） 2014/09/18(木) 09:19

 Char関数を使う！
 B1=Char(A1+62)
（あおい） 2014/09/18(木) 15:16

コメント返信：

[ 一覧(最新更新順) ]

[[20140917082504]] 『ＩＦ関数？』（1） ページの最後に飛ぶ

[[20140917082504]]　『ＩＦ関数？』（1）　ページの最後に飛ぶ