[[20140918165740]] 『中間値と昇給回数を求める』(ぴろ) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『中間値と昇給回数を求める』(ぴろ)

説明が難しいのですが…

・等級と賃金範囲

 1等級 120,000〜150,000
 2等級 140,000〜160,000
 3等級 150,000〜170,000

・昇給2,000/回

・各個人賃金

 Aさん 1等級 130,000
 Bさん 1等級 145,000
 Cさん 2等級 140,000
 Dさん 3等級 150,000

上記のデータを利用して、各個人の等級中間値と上限まであと何回昇給できるかを
関数で求めたいのですが、どのように式を作ればよいのでしょうか?
お願い致します。

< 使用 Excel:Excel2007、使用 OS:Windows8 >


Aさんは,中間は =ROUNDDOWN(ABS((150000+120000)/2-130000/2000,0)
上限は=ROUNDDOWN(ABS((150000-130000)/2000,0)

(Hara) 2014/09/18(木) 17:45


中間は

=IF(((150000+120000)/2-130000)<0,"",ROUNDDOWN(((150000+120000)/2-130000)/2000,0))
かも?
(Hara) 2014/09/18(木) 17:59


 (1) D2セル =INT(MAX(0,INDEX((H$2:H$4+I$2:I$4)/2,LEFT(B2))-C2)/J$2)
 (2) E2セル =INT(MAX(0,INDEX(I$2:I$4,LEFT(B2))-C2)/J$2)

 <結果図>
 行 ___A___ __B__ ___C___ ____D____ ____E____ _F_ __G__ ___H___ ___I___ ___J___
  1 氏名    等級  現賃金  中間まで  上限まで            下限    上限    昇給額 
  2 Aさん  1等級 130,000        2        10      1等級 120,000 150,000  2,000 
  3 Bさん  1等級 145,000        0         2      2等級 140,000 160,000        
  4 Cさん  2等級 140,000        5        10      3等級 150,000 170,000        
  5 Dさん  3等級 150,000        5        10                                   

(半平太) 2014/09/18(木) 20:25


 半平太さん表をお借りして別案。

 D2 =MAX(0,INT(((SUMIF(G:G,B2,H:H)+SUMIF(G:G,B2,I:I))/2-C2)/J$2))
 E2 =MAX(0,INT((SUMIF(G:G,B2,I:I)-C2)/J$2))

 D2 は =MAX(0,INT((SUMPRODUCT(VLOOKUP(B2,G:I,{2,3},))/2-C2)/J$2))
 でも。 (配列定数なのにSUMじゃなんでだめなんだろ? Excel2010)
 
(GobGob) 2014/09/19(金) 08:14

皆さんありがとうございます。

半平太さん表をお借りして
散布図や株価グラフのようなものを作成しようと思いますが、
いま一つうまくいきません。

イメージとしては、下記の様な感じにしたいのですが…

150,000              D:150,000
     B:145,000
140,000        C:140,000
  
130,000  A:130,000

賃金
↑   
→ 等級   1      2      3     4     5

宜しくお願い致します。
(ぴろ) 2014/09/24(水) 18:39


 >中間値と昇給回数
 がどこに絡んでくるのかわからないですが

 ↓の様な配置にすれば
	Aさん	Bさん	Cさん	Dさん
  1	130,000	145,000		
  2			140,000	
  3				150,000
 散布図を選択して(行列の入れ替えは必要かもしれませんが)
 イメージの様なグラフになりそうですがどうですか?

 元の表のままであれば、一人ずつ系列を追加してX,Yの値を設定すれば
 同じグラフになると思います。
  
(HANA) 2014/09/26(金) 16:46

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.