[[20150120142641]]　『アルファベットの大文字と小文字を区別して抽出』（はしるっぺ）　ページの最後に飛ぶ

『アルファベットの大文字と小文字を区別して抽出』（はしるっぺ）

過去質問を検索しましたが、見つかりませんでした。
教えてください。

VLOOKUP関数です。
下の図のような検索範囲の場合です。

A　ねずみ
B　うし
a　とら
b　うさぎ

VLOOKUP(A,検索範囲）のときに「ねずみ」
VLOOKUP(a,検索範囲）のときに「とら」
↑このように、大文字と小文字を区別させて抽出させたいのですが。
EXACT関数を使う方法があることは分かりましたが、
この関数の具体的なネスト方法が分かりません。
よろしくおねがいします。

＜使用 Excel：Excel2010、使用 OS：Windows8 ＞

 Vlookupでは無理です。
[[20040203142255]]

 こちらは参考になりますか？
（稲葉） 2015/01/20(火) 14:55

稲葉さんありがとうございます。
ですが…ちんぷんかんぷんです…うえーん…
（はしるっぺ） 2015/01/20(火) 15:01

 でしたら、そんな難しいことを考えずに、一意の値を準備されてはいかがでしょう？
（稲葉） 2015/01/20(火) 15:03

一意の値を準備… やっぱりそうなりますかね…残念です。
ありがとうございました。
（はしるっぺ） 2015/01/20(火) 15:07

 関数は苦手ですが、こういう式でもできると思います。
 理解しないで使うと、後々困るのは使わされているほうですので、
 やりたいことが単純なら、単純な式を準備されたほうがいいと思います。

	[A]	[B]	[C]	[D]
[1]	A	ねずみ	a	とら
[2]	B	うし		=INDEX($B$1:$B$4,MAX(MMULT(NOT(ISERROR(FIND($C$1,$A$1:$A$4)))*ROW($1:$4),1)))
[3]	a	とら		
[4]	b	うさぎ		
[5]

（稲葉） 2015/01/20(火) 15:10

 ↑ の稲葉さんの表をお借りして。

 D1: =INDEX($B$1:$B$10,MATCH(1,INDEX(EXACT(C1,$A$1:$A$10)*1,0),0))

 または

 D1: =INDEX(B:B,SUMPRODUCT(EXACT(C1,$A$1:$A$10)*ROW($A$1:$A$10)))
　
（JKT） 2015/01/20(火) 15:23

 ↓ でもできるかもしれません。

 D1: =LOOKUP(1,0/EXACT(C1,$A$1:$A$10),$B$1:$B$10)
　
（JKT） 2015/01/20(火) 15:27

 勉強になります！
 EXACT関数なんて今まで使ったことなかったです。
（稲葉） 2015/01/20(火) 15:29

うおお！稲葉さんの15:10のレスを検証してる間に、皆さん凄いです。。
勉強になります。
稲葉さんの関数もよく分かりました。これは使えそうです。
FINDの後の値を関数で検索させてもいいですね。素晴らしいです。
JKTさんの関数もよく分かりました。特に、EXACT関数を使う方法は素晴らしい。
みなさん、すごいです。尊敬～。ありがとうございました。
（はしるっぺ） 2015/01/20(火) 15:42

 エラー処理するならFINDでもいいかも。

 =LOOKUP(1,FIND(C1,A1:A10),B1:B10)
　
（GobGob） 2015/01/23(金) 10:03

コメント返信：

[ 一覧(最新更新順) ]

[[20150120142641]] 『アルファベットの大文字と小文字を区別して抽出』（はしるっぺ） ページの最後に飛ぶ

[[20150120142641]]　『アルファベットの大文字と小文字を区別して抽出』（はしるっぺ）　ページの最後に飛ぶ