[[20150131095934]]　『ある特定の数値以下のセルの値』（ブラザー）　ページの最後に飛ぶ

『ある特定の数値以下のセルの値』（ブラザー）

こんにちは

下記のような場合の抽出の仕方を教えて下さい。

A B C D E F G H I J K L
8 5 9 12 1 7 3 2 4 6 10 11

65 63 60 57 56 53 51 49 47 45 43 42

75 70 67 63 59 54 48 46 43 42 41 40

2行目と3行目で、49以下の1行目のセルの値を求めたいです。

この場合、

2行目の結果は、「２」「４」「６」

3行目の結果は、「３」「２」「４」

宜しくおねがいします。

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

 結果はどこにどのように表示するのでしょう？
（カリーニン） 2015/01/31(土) 10:14

結果は、A4・B4・C4に表示しようと思います。
（ブラザー） 2015/01/31(土) 10:21

 =IF(COLUMN(A1)>COUNTIF($A2:$L2,"<=49"),"",INDEX($A$1:$L$1,SMALL(($A2:$L2>49)*100+COLUMN($A1:$L1),COLUMN(A1))))

 ★この式は「配列数式」です。式を入力後、CtrlとShiftを押しながらEnterを押して式を確定させてください
 ★式が確定すれば、式の両端に、｛　｝がつきます
 ★式を確定後、右と下にコピー

（maron） 2015/01/31(土) 10:28

 maronさんと似たような式ですが…
 =IFERROR(INDEX($A$1:$L$1,SMALL(IF($A2:$L2<=49,COLUMN($A$1:$L$1)),COLUMN(A1))),"")
 同じくCtrl+Shift+Enterで確定です。

 ところで2行目は「2」「4」「6」「10」「11」、3行目は「3」「2」「4」「6」「10」「11」に
 なると思うのですが、なぜ3つだけなのでしょうか？
（se_9） 2015/01/31(土) 10:50

 なんで結果が3つだけしかないんかというのも不可解やけど
 例示のように、2行目と3行目は必ず降順で、
 全部のセルが数値で埋まってるんやったら（空白セルがないんやったら）

 =IFERROR(INDEX($A$1:$L$1,COUNTIF($A2:$L2,">49")+COLUMN(A1)),"")

 普通にEnter

 降順でA列から順に埋まっていくけど、
 途中から空白になることもあるんやったら

 =IF(COUNTIF($A2:$L2,"<=49")<COLUMN(A1),"",INDEX($A$1:$L$1,COUNTIF($A2:$L2,">49")+COLUMN(A1)))

 普通にEnter

 A列から始まってなくても COLUMN(A1) はそのままにしておくこと。
　
（よみびとしらず） 2015/01/31(土) 11:43

（maron）さん

問題なく出来ました。

（se_9）さん

3つだけで十分なんです。（説明は難しいので、割愛させて頂きます）

（よみびとしらず）さん

途中で空白になることはないです。

皆さん、どれもこれも素晴らしい式で、とても勉強になりました。

有難う御座いました。

（ブラザー） 2015/01/31(土) 12:08

コメント返信：