[[20150225153154]]　『A列のデータが条件に当てはまればB列に指定した文』（WAKA）　ページの最後に飛ぶ

『A列のデータが条件に当てはまればB列に指定した文字を書き込む』（WAKA）

A列にデータが並んでいて、
条件1にあてはまれば、B列に"文字列1"
条件2にあてはまれば、B列に"文字列2"
を書き込むような関数かマクロを作る事は可能ですか？
条件の内容ですが、
条件1"文字列A"と"文字列B"を含む
条件2"文字列C"と"文字列D"を含む
といったものです。

よろしくお願いします

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

=IF(AND(COUNTIF(A1,"*文字列A*"),COUNTIF(A1,"*文字列B*")),"文字列1",IF(AND(COUNTIF(A1,"*文字列C*"),COUNTIF(A1,"*文字列D*")),"文字列2",""))

このようなことでしょうか
（とらねこ） 2015/02/25(水) 16:07

 こんなでも。
 =IF(0<COUNTIFS($A1,"*文字列A*",$A1,"*文字列B*"),"文字列1",IF(0<COUNTIFS($A1,"*文字列C*",$A1,"*文字列D*"),"文字列2",""))
（???） 2015/02/25(水) 16:14

とらねこさん
？？？さん
ありがとうございます。

条件3,条件4と追加していきたい場合はどのようにしたらいいですか？

よろしくお願いします。
（WAKA） 2015/02/26(木) 09:35

IF文の基本が、以下。
=IF(条件, Trueの場合, Falseの場合)

今回の場合、条件が2つあるので、これをネストして実現。
=IF(条件1, Trueの場合, IF(条件2, Trueの場合, Falseの場合))

同じように、条件が4つあるなら、ネストを深くするだけ。
=IF(条件1, Trueの場合, IF(条件2, Trueの場合, IF(条件3, Trueの場合, IF(条件4, Trueの場合, Falseの場合))))
（???） 2015/02/26(木) 09:58

???さんが既に回答していますが
=IF(AND(COUNTIF(A1,"*文字列A*"),COUNTIF(A1,"*文字列B*")),"文字列1",IF(AND(COUNTIF(A1,"*文字列C*"),COUNTIF(A1,"*文字列D*")),"文字列2",IF(AND(COUNTIF(A1,"*文字列E*"),COUNTIF(A1,"*文字列F*")),"文字列3",IF(AND(COUNTIF(A1,"*文字列G*"),COUNTIF(A1,"*文字列H*")),"文字列4",""))))
追加した式になります

エクセル　関数　IF
などで調べるとたくさん解説が出るので勉強してみてはいかがでしょうか

（とらねこ） 2015/02/26(木) 10:25

 > 条件3,条件4と追加していきたい場合

 どこまで追加したいのかわかりませんが、別表にまとめたらどうですか？

	E	F	G
1	文字列A	文字列B	文字列1
2	文字列C	文字列D	文字列2
3	文字列E	文字列F	文字列3
4	文字列G	文字列H	文字列4
5	文字列I	文字列J	文字列5
　
　
 条件5まであり、E1:G5 が条件表だとして。

 B1: =IFERROR(LOOKUP(1,0/(FIND($E$1:$E$5,A1)+FIND($F$1:$F$5,A1)),$G$1:$G$5),"")
　
（JKT） 2015/02/26(木) 12:58

コメント返信：

[ 一覧(最新更新順) ]

[[20150225153154]] 『A列のデータが条件に当てはまればB列に指定した文』（WAKA） ページの最後に飛ぶ

[[20150225153154]]　『A列のデータが条件に当てはまればB列に指定した文』（WAKA）　ページの最後に飛ぶ