[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『有給残の計算』（ごましお）
前月の繰越日数と、今月取得した有給を引いて有給残を計算したいのですが、有給は入社と同時に3日、半年で10日、1年半で11日、2年半で12日付与されます。
有給付与月には、付与分と、前回付与分しか繰越できません。
たとえば1年5ヶ月目のＡさんの有給残が12日あっても、1年6ヶ月目には21日しか繰り越せません。
どのように計算すれば良いか教えて頂けないでしょうか？
よろしくお願いいたします。
＜ 使用 Excel：Excel2007、使用 OS：Windows8 ＞
最大で何日になるのかな？ 3年半で13日、4年半で14日･････10年半で20日と増えていくのか、 それとも、12日が最大で、3年半でも新規付与12日、前回付与繰越12日で 計24日となるのか？
ルールが分からないと答えようがないような・・・
ちなみに、労働基準法第39条で定められた有給休暇日数は 6ヶ月 1年半 2年半 3年半 4年半 5年半 6年半以上 10日 11日 12日 14日 16日 18日 20日 となっています。
また、有給休暇の取得時効は2年ですので、前年付与分の残日数しか繰り越せない というルールは、労基法に添った運用のようですね。
（jjj） 2015/02/26(木) 09:40
前回付与分の繰越日数
=MIN(有給残,VLOOKUP(DATEDIF(入社年月日,付与年月日,"M")-12,{0,3;6,10;18,11;30,12;42,14;54,16;66,18;78,20},2))
新たに付与する日数
=MIN(有給残,VLOOKUP(DATEDIF(入社年月日,付与年月日,"M"),{0,3;6,10;18,11;30,12;42,14;54,16;66,18;78,20},2))
こんな感じかな？
（jjj） 2015/02/26(木) 10:26
短期雇用なのでＭＡＸ3年、毎月入社があります。
人によって有給付与月が違います。
最大有給日数は23日、有給付与は30ヶ月目に12日が最後です。
Ａさんの場合。
29ヶ月目の有給残は12日。
30ヶ月目に有給付与12日。有給を2日取得。
合計24日となるが、前年分の付与分しか繰越できない。
入社 6ヶ月 18ヶ月 30ヶ月
付与 3日 10日 11日 12日
計算式は12＋11−2＝21 というのは解りますが、人によって付与月が違うため、
関数の式の組み方がわかりません。
お解りになる方よろしくお願いします。
（ごましお） 2015/02/28(土) 18:57
どんなレイアウトになっているのか示して頂けませんか？
有給取得のデータとか現在残日数が、どこにあるのか分からないと数式が作れません。 (勝手に作ってもいいですけど、そんな管理の仕方はしてないです・・なんて、あとで言われると二度手間です。）
（半平太） 2015/02/28(土) 19:52
前の有給表はどこにあるのですか？ 別のシート？ 同じシートの上の方？
今度の有給表はいつ作るのですか？ 毎日？ 月一回(月初、月末）？ 誰かが新しく有給を付与されることになった日 ？
因みに、何人くらいが対象ですか？
（半平太） 2015/02/28(土) 23:56
よろしくお願いいたします。
（ごましお） 2015/03/01(日) 00:11
起算日は入社日。その応当日到来で有給を付与すると想定 ※3/31に入社した者は、9/30ではなく、10/1に10日が付与される （10月末時点では、3/30入社の者と同じ経過月数である)
月末に作ると云うことは、月中に付与がある場合、月中において繰越制限の適用が不可欠。 下図はそれ用にレイアウトを作った場合です。
１．入力する数式
(1) C3セル =IF(B3="","",DATEDIF(B3,$B$1,"M"))
(2) F3セル =IF(G3="","",MAX((DATEDIF(B3,G3,"M")={0,6,18,30})*{3,10,11,12}))
(3) G3セル =IF(MONTH($B$1)=MONTH(LOOKUP($B$1,EDATE(B3,{0,6,18,30})+(DAY(EDATE(B3,{0,6,18,30}))<DAY(B3)))),LOOKUP($B$1,EDATE(B3,{0,6,18,30})+(DAY(EDATE(B3,{0,6,18,30}))<DAY(B3))),"")
(4) H3セル =IF(B3="","",IF(N(F3)=0,"",MIN(D3-E3,MAX((DATEDIF(B3,G3,"M")={0,6,18,30})*{0,3,10,11}))+F3))
(5) J3セル =IF(C3="","",IF(AND(N(F3)<1,I3>0),"←入力不可",IF(OR(D3<E3,N(H3)<I3),"取り過ぎ",IF(N(F3)>0,H3-I3,D3-E3))))
全て、下方にコピー
２．使い方 (1)B1セルに月末日を手入力する(カレンダの純粋月末とする。最終営業日とは無縁） (2)A:B列とD列を前月ファイルからコピーして、値だけ貼り付ける
<結果図>
行 ___A___ _____B_____ ____C____ ______D______ _____E_____ ____F____ _____G_____ ______H______ _____I_____ _____J_____
1 基準日 2015/10/31
2 氏名 入社日 在籍月数 前月繰越日数 付与前取得 今月付与 付与日 付与後有給残 付与後取得 月末有給残
3 Aさん 2014/4/15 18 13 1 11 2015/10/15 21 2 19
4 Bさん 2015/3/30 7 1 1
5 Cさん 2015/3/31 7 1 10 2015/10/1 11 11
6 Dさん 2014/4/15 18 1 11 2015/10/15 12 12
7 Eさん 2014/4/1 18 1 11 2015/10/1 12 12 0
8 Fさん 2015/9/30 1 0 1 ←入力不可
9 Gさん 2015/5/30 5 2 2
10 Hさん 2015/4/30 6 3 1 10 2015/10/30 12 1 11
11 Iさん 2014/5/30 17 11 2 9
12 Jさん 2014/4/30 18 10 11 2015/10/30 21 21
13 Kさん 2014/3/30 19 10 10
14 Lさん 2013/5/30 29 10 11 取り過ぎ
15 Mさん 2013/4/30 30 10 12 2015/10/30 22 22
（半平太） 2015/03/01(日) 15:56
お忙しい所詳細にご教示頂きありがとうございました。
式通り入力したらできました！
助かりました！
他の方もコメントありがとうございました。
（ごましお） 2015/03/01(日) 21:18
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.