[[20150325143023]]　『書類の有効期限の管理について』（ゆか）　ページの最後に飛ぶ

『書類の有効期限の管理について』（ゆか）

医療の仕事をしております。

医師の同意日によって、書類の有効期限が変わってきます。

医師の同意日が例えば　3/1～3/15　の間の日付の場合は　　有効期限　5/31　
　　　　　　　　　　　3/16～3/31の間の日付の場合は　　有効期限　6/30　　
上記のように月の15日までの日付でしたら　翌々月末

16日以降の日付なら　　翌々々月末になる計算式についてです。　　　

=IF(DAY(P4)<=15,DATE(YEAR(P4),MONTH(P4)+3,1)-1,DAYE(YEAR(P4),MONTH(P4)+4,1)-1)

パソコン教室でこちらの計算式を教えてもらい。家でやってみた処、15日までの日付の場合は上手くいきましたが、16日以降の日付の場合が#NAME?　となってしまいます。

同意年月日　　有効期限
3月2日　　　　5月31日
2月16日　　　　#NAME?　　5/31が正解
11月21日　　　　#NAME?　　2/28が正解
1月1日　　　　3月31日
　　
同意年月日欄が上の式のＰ4です。
どのように修正したらよいでしょうか。恐れ入りますが、教えていただけますでしょうか。宜しくお願いします。
分かりにくい質問で申し訳ありません。

＜使用 Excel：Excel2013、使用 OS：Windows8 ＞

DAYEをDATEに変えてください
（デイト） 2015/03/25(水) 14:58

 かぶったが。

 #NAME?はそういう名前の関数やセル範囲、名前が無い場合に表示される。
 DATE関数がDAYEになってる部分があるようだが。

 このような式も。
 =EOMONTH(P4,2+(DAY(P4)>15))
（ねむねむ） 2015/03/25(水) 14:59

ところで年月日とありますが年を表示しないでいいのですか？
（デイト） 2015/03/25(水) 15:02

 ＞11月21日→2/28が正解

 来年はうるう年なので11月21日→2/29が正解じゃないですかね？
（se_9） 2015/03/25(水) 15:03

 =IF(DAY(P4)<=15,DATE(YEAR(P4),MONTH(P4)+3,1)-1,DAYE(YEAR(P4),MONTH(P4)+4,1)-1) 
 の式の場合、
 =IF(DAY(P4)<=15,DATE(YEAR(P4),MONTH(P4)+3,0),DAYE(YEAR(P4),MONTH(P4)+4,0)) 
 でも。
（ねむねむ） 2015/03/25(水) 15:06

 =DATE(YEAR(P4),MONTH(P4)+IF(DAY(P4)<=15,3,4),0)
 でもいいかも？
（se_9） 2015/03/25(水) 15:11

 これでもいいかも。

 =EOMONTH(P4-15,3)

 表示形式を「日付」にしてください。
　
（JKT） 2015/03/25(水) 16:03

コメント返信：

[ 一覧(最新更新順) ]

[[20150325143023]] 『書類の有効期限の管理について』（ゆか） ページの最後に飛ぶ

[[20150325143023]]　『書類の有効期限の管理について』（ゆか）　ページの最後に飛ぶ