[[20150327103349]]　『特定できるセルがある場合にその他の情報をコピー』（なお）　ページの最後に飛ぶ

『特定できるセルがある場合にその他の情報をコピーしたい』（なお）

     A     B     C      D       E
1  XXX1   ○           △△     10 
2  XXX2   ○           △△     20  
3  XXX3         ○     △△     20  
4  XXX4         ○     △△     20  
5  XXX5                △△     20

上図のようなセルの構成で
「Bに○」のものを「A:E」までの範囲でコピーし「A10」に貼り付け、
「Cに○」のものを「A:E」までの範囲でコピーし「A50」に貼り付け、
「どちらも空白」のものを「A:E」までの範囲でコピーし「A90」に貼り付けを
したいのですがどのようにすればいいでしょうか？

前提として
必ず上から「Bに○」、「Cに○」、「どちらも空白」の順になります。
ただ、上記の３パターンが全てあるとは限りません。

以上、宜しくお願い致します。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 元データのA列はすべて違う値なのだろうか？
 同じ値が出てくることもあるのだろうか？
（ねむねむ） 2015/03/27(金) 11:25

ねむねむさん

全て違う値です。
また数も一定ではありません。」

以上、宜しくお願い致します。
（なお） 2015/03/27(金) 11:37

 A10セルに
 =IFERROR(INDEX(A$1:A$9,SMALL(IF(B$1:B$9="○",ROW(B$1:B$9),""),ROW(A1))),"")
 A50セルに
 =IFERROR(INDEX(A$1:A$9,SMALL(IF(C$1:C$9="○",ROW(C$1:C$9),""),ROW(A1))),"")
 A90セルに
 =IFERROR(INDEX(A$1:A$9,SMALL(IF((A$1:A$9<>"")*(B$1:B$9="")*(C$1:C$9=""),ROW(C$1:C$9),""),ROW(A1))),"")
 と入力してShiftキーとCtrlキーを押しながらEnterキーで確定（確定後、式が{}で囲まれればOK）、その後、それぞれ下へフィルコピー。

 B10セルに
 =IF($A10="","",IF(VLOOKUP($A10,$A$1:$E$9,COLUMN(B1),FALSE)="","",VLOOKUP($A10,$A$1:$E$9,COLUMN(B1),FALSE)))

 B50セルに
 =IF($A50="","",IF(VLOOKUP($A50,$A$1:$E$9,COLUMN(B1),FALSE)="","",VLOOKUP($A50,$A$1:$E$9,COLUMN(B1),FALSE)))

 B90セルに
 =IF($A90="","",IF(VLOOKUP($A90,$A$1:$E$9,COLUMN(B1),FALSE)="","",VLOOKUP($A90,$A$1:$E$9,COLUMN(B1),FALSE)))
 と入力（こちらは通常通りEnterで確定）、その後右および下へフィルコピー。

 なお、数値が文字列の数字になっても構わないのであれば
 =IF($A10="","",VLOOKUP($A10,$A$1:$E$9,COLUMN(B1),FALSE))&""
 =IF($A50="","",VLOOKUP($A50,$A$1:$E$9,COLUMN(B1),FALSE))&""
 =IF($A90="","",VLOOKUP($A90,$A$1:$E$9,COLUMN(B1),FALSE))&""
 でも。
（ねむねむ） 2015/03/27(金) 13:22

コメント返信：

[ 一覧(最新更新順) ]

[[20150327103349]] 『特定できるセルがある場合にその他の情報をコピー』（なお） ページの最後に飛ぶ

[[20150327103349]]　『特定できるセルがある場合にその他の情報をコピー』（なお）　ページの最後に飛ぶ