[[20150417002244]]　『名前で検索すると一覧で表示』（小春）　ページの最後に飛ぶ

『名前で検索すると一覧で表示』（小春）

 sheet1のB1に名前を入力すると4行目の
 A4    　B4    　　 C4     　 D4    　 E4
 部署名　課長名　　係長名　　班長名　　副班長名
 と
 A4～E4セルに部署と名前が表示できるようにしたいのですが

 データはsheet2のＡ2～Ｅ2に記入してあり以下50行ほど名簿があります
 VLOOKUP関数とCOUNTIF関数の組み立て方がいまいちわかりません
 作業の効率を計るためにも　どなたか御教授お願いします

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 B1に入れる名前は、Sheet2のどこにあるんですか？
（コナミ） 2015/04/17(金) 06:42

 すみません
 sheet2のＡ1～Ｅ1は表題にしてあります
 A2には部署が入力されています
 B2～E2に個人の名前が入力されています
 このデータが50行くらいあります

（小春） 2015/04/17(金) 14:12

 Sheet1のB1に入るのは

 課長名・係長名・班長名・副班長名のどれも可能性があるということですか？

 仮の名前でいいのでサンプルがあるといいのですが。
（コナミ） 2015/04/17(金) 14:33

 横から失礼します＆勝手に予想

 Sheet1のA4セル =IFERROR(INDEX(Sheet2!A$2:A$101,SMALL(IF(Sheet2!$B$2:$E$101=$B$1,ROW($A$1:$A$100)),ROW(A1))),"")
 Ctrl+Shift+Enterで確定　←必ずこれで確定
 右にフィルコピー
（se_9） 2015/04/17(金) 14:50

 コナミさんへ
 sheet2
 A1(部署） 　B1（課長）    C1（係長）    D1（班長）    E1（福班長）
 技術Ａ課　　斉藤　　　　　佐藤　　　　　後藤　　　　　伊藤
 生産Ｂ課　　川上　　　　　川中　　　　　川下　　　　　川崎
 日程Ｃ課　　河　　　　　　海　　　　　　山　　　　　　空

 こんな感じです
（小春） 2015/04/17(金) 15:01

 se_9さんの式は如何だったでしょうか？

 こちらの方で、いただいたサンプルと合わせてみたらうまくいきましたが。
（コナミ） 2015/04/17(金) 15:53

 ありがとうございました
（小春） 2015/04/17(金) 16:11

 B1の名前は必ずSheet2にあるの？

 =INDEX(Sheet2!A:A,SUMPRODUCT((Sheet2!$A$2:$E$100=$B$1)*ROW($A$2:$A$100)))&""

 =INDEX(Sheet2!A:A,MAX(INDEX((Sheet2!$A$2:$E$100=$B$1)*ROW($A$2:$A$100),0)))&""

 Enterだけで確定っす。

 ない場合も考慮しないとダメなら、COUNTIFを使って確認してちょｗ
　
（帰って来た名無しのおっさん） 2015/04/17(金) 16:53

 ↑ は、Sheet2に同じ名前はないっていう前提っすｗ

 同じ名前もあって、その場合は該当するもの全部表示ってことなら

 =IFERROR(INDEX(Sheet2!A:A,SMALL(INDEX((Sheet2!$A$2:$E$100<>$B$1)*10^10+ROW($A$2:$A$100),0),ROW(A1)))&"","")

 Enterのみで確定、右と下にコピーしてちょｗ
　　
（帰って来た名無しのおっさん） 2015/04/17(金) 17:04

コメント返信：

[ 一覧(最新更新順) ]

[[20150417002244]] 『名前で検索すると一覧で表示』（小春） ページの最後に飛ぶ

[[20150417002244]]　『名前で検索すると一覧で表示』（小春）　ページの最後に飛ぶ