[[20150516000641]]　『○○がもっている担当企業数を数える関数を知りた』（むーみん）　ページの最後に飛ぶ

『○○がもっている担当企業数を数える関数を知りたい（企業数は重複しているものは数えない）』（むーみん）

エクセルで担当者が何社の企業を担当しているか知りたいですが、
関数の組み立て方がわかりません。教えて頂きたいです。

A列　　　B列
佐藤　AAA株式会社
佐藤　BBB株式会社
鈴木　CCC株式会社
佐藤　AAA株式会社
鈴木　EEE株式会社
鈴木　EEE株式会社
高橋　FFF株式会社
高橋　FFF株式会社

答え
佐藤→2社
鈴木→2社
高橋→1社

というように企業名が重複しているところは数えずに担当者が何社の会社を担当して
いるのかを出したいです。

関数以外の方法でも良いので教えていただけたらと思います。
よろしくお願いいたします。

＜使用 Excel：unknown、使用 OS：unknown ＞

 ちゃんとした関数での回答が出るまでのつなぎで。

 このデータが A:B列にあるとして

 A列を別の場所、たとえば C列にコピー
 C列で重複削除
 A:B列を別の場所（たとえば E:F列)にコピペ
 E:F列で重複の削除
 D1 : =COUNTIF(E:E,C1) で、下にフィルコピー

（β） 2015/05/16(土) 02:41

 カバ丸、参上！

	D	E
1	担当者	担当数
2	佐藤	2
3	鈴木	2
4	高橋	1
　
　
 A列・B列は、1行目が見出し、データは2行目からだとする。

 E2　=COUNT(INDEX(1/(MATCH(D2&$B$2:$B$100,$A$2:$A$100&$B$2:$B$100,0)=ROW($A$1:$A$100)),0))

 下へフィルコピー

 ROW($A$1:$A$100)　←　必ず1行目からにすること！

 参考にしてくれい。では！ε=ε=ε= ﾍ(*¨)ﾉ
　
（カバ丸） 2015/05/16(土) 11:01

 カバ丸さんのレイアウトをお借りして。

 E2セルに
 =COUNT(0/FREQUENCY(IF(A$2:A$100=D2,MATCH(B$2:B$100,B$2:B$100,0),""),ROW(A$1:A$100)))
 と入力してShiftキーとCtrlキーを押しながらEnterキーで式を確定（確定後、式が{}で囲まれればOK）
 その後下へフィルコピー、でどうか。

 なお、A,B列のデータの最大行を100行目までとしているのでもっとデータがある場合は「$100」分部を大きくしてくれ。

 また、「A$1:A$100」部分は1から最大行数までとしてくれ。
（ねむねむ） 2015/05/18(月) 09:38

 A列B列に空欄がなければ
 =SUMPRODUCT(($A$2:$A$10=D2)*(1/COUNTIF($B$2:$B$10,$B$2:$B$10)))
 これでどうですかね。
（Ksaku） 2015/05/18(月) 11:45

 Ksakuさん
 その場合は一つの会社を複数の人が担当していない、という条件も必要だと思うが。
（ねむねむ） 2015/05/18(月) 11:52

コメント返信：

[ 一覧(最新更新順) ]

[[20150516000641]] 『○○がもっている担当企業数を数える関数を知りた』（むーみん） ページの最後に飛ぶ

[[20150516000641]]　『○○がもっている担当企業数を数える関数を知りた』（むーみん）　ページの最後に飛ぶ