[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『グループ内の上から順にアルファベットを自動ではいるようにしたい』（ぴこ）
組織図のような表で、同じ所属のグループ内で、上から順番にアルファベットＡから
順番にふっていきたいのですが、自動で入力できるような関数などがありましたら、
教えていただきたいのです。
部署なので、多い部署もあれば、１つの部署もあります。
例として下記のようになっています。
++++++++++++++++++++++++++++++++++++++++++++++++++++
A 総務部 AA 総務課 AAA 第１グループ
A 総務部 AA 総務課 AAB 第２グループ
A 総務部 AA 総務課 AAC 第３グループ
A 総務部 AB 宣伝課 ABA 第１グループ
A 総務部 AB 宣伝課 ABB 第２グループ
A 総務部 AC 総務課 ACA 第１グループ
A 総務部 AC 総務課 ACB 第２グループ
A 総務部 AC 総務課 ACC 第３グループ
B 営業部 BA 営業課 BAA 第１グループ
C 調達部 CA 調達課 CAA 第１グループ
C 調達部 CA 調達課 CAB 第２グループ
＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
よろしくお願いいたします。
＜ 使用 Excel：Excel2010、使用 OS：Windows7 ＞
同じ所属グループは固まって並んでいるのか？ 例えば「総務部」の次に「営業部」そのあとにまた「総務部」ということはあるのか？
所属グループが24個以上（A～Z以上）出てくることはあるのか？ もしある場合はどうするのか？ （ねむねむ） 2015/05/18(月) 14:08
◆同じ所属グループは固まって並んでいるのか？
例えば「総務部」の次に「営業部」そのあとにまた「総務部」ということはあるのか？
⇒所属グループはかたまっています。
「総務部」の次に「営業部」そのあとにまた「総務部」という事も
ありません。
所属グループが24個以上（A～Z以上）出てくることはあるのか？
⇒多くても15個くらいです。
いままで一つづつ手作業なため、自動で入るようにできればいいなって思ってます。
よろしくお願いいたします！！！
（ぴこ） 2015/05/18(月) 15:01
最初考えていたよりも長くなってしまった。
一行目が見出しで二行目から実際のデータだとして。
A2セルに「A」と入力し、A3セルに =IF(B3="","",IF(B3=INDEX(B$2:B2,MATCH(1,INDEX(0/(B$2:B2<>""),0),1)),INDEX(A$2:A2,MATCH(1,INDEX(0/(A$2:A2<>""),0),1)),CHAR(CODE(INDEX(A$2:A2,MATCH(1,INDEX(0/(A$2:A2<>""),0),1)))+1))) と入力して下へフィルコピーしてみてくれ。
間の空行が必ず一行であるならば =IF(B3="","",IF(B3=IF(B2="",B1,B2),IF(A2="",A1,A2),CHAR(CODE(A1)+1)))
間の空行をなくしてもいいのであれば =IF(B3="","",IF(B3=B2,A2,CHAR(CODE(A2)+1))) とできる。
追記 >所属グループが24個以上（A～Z以上） 24ではなく26だった… （後、正確には「以上」ではなく「を超える」だった） （ねむねむ） 2015/05/18(月) 15:32
空白行はいらないので、
=IF(B3="","",IF(B3=IF(B2="",B1,B2),IF(A2="",A1,A2),CHAR(CODE(A1)+1))) で試してみました。 一桁の「A」だと大丈夫なのですが、「AA」と２ケタになると、「AA」以外は「B」や「C」と１ケタとなってしまいました。
ただ、私の説明が間違っていたので、もう一度書きますので、できればもう一度教えてください。
同じ「室」の中の「課」で上から順にアルファベットを振っていくイメージです。
たとえば、
総務部＝A、営業部＝B、調達部＝C、と、アルファベットを振ります。
その「部」の中の「課」にも上から順番にアルファベットを振ります。
横の振り方は、部が１ケタ、課が２ケタ、グループが３ケタ、になります。
アルファベットを入れたいのは、部、課、グループのそれぞれに入れたいです。
「Ａ」の列も「ＡＡ」の列も「ＡＡＡ」の列もということになります。
例は下の通りです。
◆総務部 総務課
総務部＝「A」、総務課＝「A」 で、「AA」
◆総務部 総務課 第１グループ
総務部＝「A」、総務課＝「A」、第１グループ＝「A」 で、「AAA」
◆総務部 総務課 第２グループ
総務部＝「A」、総務課＝「A」、第２グループ＝「B」 で、「AAB」
◆総務部 宣伝課 第１グループ
総務部＝「A」、宣伝課＝「B」、第１グループ＝「A」 で、「ABA」
◆総務部 宣伝課 第２グループ
総務部＝「A」、宣伝課＝「B」、第２グループ＝「B」 で、「ABB」
何度も申し訳ございません。。。
できましたら、もう一度教えていただけたら幸いです。
宜しくお願い致します！！！m(__)m
（ぴこ） 2015/05/18(月) 17:03
空白行がないのであれば >=IF(B3="","",IF(B3=B2,A2,CHAR(CODE(A2)+1))) なのでは？
A2:A A3:=IF(B3="","",IF(B3=B2,A2,CHAR(CODE(A2)+1))) と入力して下へフィルコピー。
C2:=IF(D2="","",A2&IF(B2<>B1,"A",IF(D2=D1,RIGHT(C1),CHAR(CODE(RIGHT(C1))+1)))) と入力して下へフィルコピー、また、C2セルをコピーしてE2セルに張り付け、E2セルを下へフィルコピーでどうだろうか？ （ねむねむ） 2015/05/18(月) 17:19
ねむねむさんとそない変わりませんが。。。
A B C D E 1 部署1 部署2 2 A 総務部 AA 総務課 AAA 3 A 総務部 AA 総務課 AAB 4 A 総務部 AA 総務課 AAC 5 A 総務部 AB 宣伝課 ABA 6 A 総務部 AB 宣伝課 ABB 7 A 総務部 AC 総務課 ACA 8 A 総務部 AC 総務課 ACB 9 A 総務部 AC 総務課 ACC 10 B 営業部 BA 営業課 BAA 11 C 調達部 CA 調達課 CAA 12 C 調達部 CA 調達課 CAB 13
A2に「A」、C2に「AA」、E2に「AAA」
A3 =IF(B3="","",CHAR(CODE(A2)+(B2<>B3))) C3 =IF(B3="","",A3&IF(A2<>A3,"A",CHAR(CODE(RIGHT(C2))+(B2&D2<>B3&D3)))) E3 =IF(B3="","",C3&CHAR(64+COUNTIFS(B$2:B3,B3,C$2:C3,C3)))
それぞれ下へコピー。 （GobGob） 2015/05/19(火) 08:44
手入力でもなんとか頑張れる量だったので、いままで手入力だったのですが、
どうしても間違えてふってしまうことがあったので、これで安心できます。
ねむねむさん、GobGobさん、ありがとうございました！！！
（ぴこ） 2015/05/19(火) 11:12
いままで、1.部 2.課 3.グループ だけだったものが、
4.班 5.担当者と、５段階くらいになった場合、Ｅ列の数式と同じように作成すれば
よいのでしょうか？
（ぴこ） 2015/05/19(火) 12:49
私の式の場合は単純にE2セル（C2セルでもいいが）をコピーしてG2セル、I2セルに張り付けて下へフィルコピーしてみてくれ。
（ねむねむ） 2015/05/19(火) 13:04
５段階の表になっても、↑のやり方でやってみたら、こちらもできました。
ありがとうございました！！！
ほんとに、うれしいです(*^_^*)
（ぴこ） 2015/05/19(火) 14:41
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.