[[20150626190703]]　『条件付き累計計算を教えて頂きたいのですが』（史）　ページの最後に飛ぶ

『条件付き累計計算を教えて頂きたいのですが』（史）

何時も参考にさせて頂いております。

仕事で、下記の様な表を作成する事になり本日作業をして来ました。
本当の表は、４月から３月まで１２ヶ月有ります。
分からない所が２ケ所有りました。
１.　実績の入った月までの計画と実績の累計を自動で出したいのですが、式が分かりませんでした。
２.　セルＬ-１に累計期間 04月～05月累計と自動で表示させたいのですが分かりませんでした。

   Ａ   Ｂ   Ｃ   Ｄ   Ｅ   Ｆ   Ｇ   Ｈ   Ｉ   Ｊ   Ｋ    Ｌ     Ｍ
1	            04月      05月      06月      07月   04月～05月累計	
2 支店 課名 商品 計画 実績 計画 実績 計画 実績 計画 実績  計画   実績
3 札幌 一課  苺	  10   11   10   12   10    0   10    0    20     23
4 東京 二課  柿   11   12   11   13   11    0   11    0    22     25

エクセルは、簡単な関数を使用している程度のほぼ初心者ですが
宜しくお願い致します。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 実績が何月までというのは全行共通なんだよね？
 3行目の実績は5月までですが、4行目は6月までです、なんてことはないということだよね？

 実績は必ず「0より大きい値」が入力されるということでいいのかな？
 6月の実績が「0」になってますが、それが実績なんです、本当に「0」だったんです、ウフフ、
 なんてことはないんだよね？

	A	B	C	D	E	F	G	H	I	J	K		X	Y	Z	AA	AB	AC
1				4		5		6		7		～～～	2		3		04～05月累計	
2	支店	課名	商品	計画	実績	計画	実績	計画	実績	計画	実績		計画	実績	計画	実績	計画	実績
3	札幌	一課	苺	10	11	10	12	10	0	10	0		10	0	10	0	20	23
4	東京	二課	柿	11	12	11	13	11	0	11	0		15	0	12	0	22	25

 4月～3月までということは
 計画の最初はD列、最後はZ列
 実績の最初はE列、最後はAA列

 AB3 =SUMIFS(D3:Z3,$D$2:$Z$2,"計画",E3:AA3,">0")
 または
 AB3 =SUMPRODUCT(($D$2:$Z$2="計画")*(E3:AA3>0),D3:Z3)

 AC3 =SUMIF($E$2:$AA$2,"実績",E3:AA3)

 AB1 =IF(E3=0,"",TEXT(MOD(COUNTIFS(E2:AA2,"実績",E3:AA3,">0")+2,12)+1,"[=4]!04月分;!04～00月累計"))
　
 AB1ちょっと変えました。23:57頃。

 こんな感じかな、検証してないけど。
（笑） 2015/06/26(金) 23:33

笑様
有難うございました。

説明不足もフォローして頂き、希望通りに完璧に出来ました。

AB1の式は、本当に出来るとは思いませんでしたが

凄いですね　本当に出来るものなんですね

月曜日に、会社で表を完成させます。

本当に、有難うございました。
（史） 2015/06/27(土) 05:41

コメント返信：

[ 一覧(最新更新順) ]

[[20150626190703]] 『条件付き累計計算を教えて頂きたいのですが』（史） ページの最後に飛ぶ

[[20150626190703]]　『条件付き累計計算を教えて頂きたいのですが』（史）　ページの最後に飛ぶ