[[20150709164236]]　『特定の文字を抽出してその文字に関する数字の最大』（えくせるむずい）　ページの最後に飛ぶ

『特定の文字を抽出してその文字に関する数字の最大値を表示したい』（えくせるむずい）

1　りんご　25
2　みかん　54
3　メロン　85
4　いちご　98
5　りんご　68
6　いちご　85
7　りんご　21

上のような表があって、りんごの数をセルに抽出したいのですが、りんごの行が何か所かあるためその一番大きい数だけ出したいです。（上の図だと「68」を抽出。）よろしくお願いいたします。

＜使用 Excel：excel2010、使用 OS：Windows7 ＞

 7/10 9:10 セル領域の不整合訂正

 =MAX((IF(A1:A100="りんご",B1:B100)))

 これをCtrl/Shift/Enter　で確定。　一応、でますね。

（β） 2015/07/09(木) 17:55

 項目名を入れてDMAX関数という手もありますね。
（コナミ） 2015/07/10(金) 08:59

 マイナスがない場合。

 =MAX((A1:A10="りんご")*B1:B10)
 と入力してShiftキーとCtrlキーを押しながらEnterで確定(確定後、式が{}でかこまれればOK)

 =MAX(INDEX((A1:A10="りんご")*B1:B10,0))
 こちらは通常通りEnterで確定。

 どちらもデータが10行目までの場合。
（ねむねむ） 2015/07/10(金) 09:08

皆様ありがとうございます。
ただ出ないのです…。

実際の数値は％なのですが、それだと式は変わってくるのでしょうか？
βさんの式だとエラーは出ないのですが、表示は0.000％となってしまします…。
説明足らずで申し訳ありません。また、データ自体は300行ほどあり、別のシートに羅列しております
マイナスはありません。

　　　　　A　　　　　　　B
1　　　　0.08　　　　　りんご
2　　　　0.15　　　　　いちご
3　　　　0.06　　　　　もも　
4　　　　0.09　　　　　りんご
5　　　　0.12　　　　　みかん
6　　　　0.11　　　　　りんご
7　　　　0.05　　　　　ぶどう

（えくせるむずい） 2015/07/10(金) 12:02

 実際に入力した式を示してみてくれ。
（ねむねむ） 2015/07/10(金) 13:11

 質問からコピペすると、りんごの後ろにスペースみたいなのがあるんですがそれは関係ないですか？

（コナミ） 2015/07/10(金) 13:25

上の例と今の例だとA列とB列が逆なので、βさんの式のAをBにBをAにします。
（デイト） 2015/07/10(金) 13:27

皆様大変お騒がせいたしました。
できました！！

Shift+Ctrl+Enterの押し忘れでした…あんなに上で言っていただいているのにっ…！

これでスイスイ表出しできるようになりました！
本当にありがとうございました！！

（えくせるむずい） 2015/07/10(金) 15:37

以前質問させていただいたものです。
下記のような表で、「りんご」の一番大きい数字を抽出しました。
式は =MAX((IF(B1:B100="りんご",A1:A100)))です。

同様の表から、りんごの数字の平均を出せますでしょうか？
AVERAGEIFで作ってみたりしましたがうまくいきません。
宜しくお願いいたします。

（えくせるむずい） 2015/07/23(木) 11:47

 なぜどのような式にして、どうなるはずがどうなってしまうという説明をしないのだろうか？

 こちらでは
 =AVERAGEIF(B1:B7,"りんご",A1:A7)
 という式で
 0.093333333
 という結果になり
 =AVERAGE(A1,A4,A6)
 と合致した。

（ねむねむ） 2015/07/23(木) 11:53

ねむねむさん、作れました！
=AVERAGEIF((IF(B1:B100="りんご",A1:A100)))という不明な式で格闘してました…。
勉強いたします。
ありがとうございました！
（えくせるむずい） 2015/07/23(木) 12:17

 IF(B1:B100="りんご",A1:A100)
 を使うのはAVERAGE関数になる。

 =AVERAGE(IF(B1:B100="りんご",A1:A100))
 これでShift+Ctrl+Enterで。

 2003以前の場合はAVERGEIF関数がないため、こちらを使うことになる。

 SUMIF関数とCOUNTIF関数を使って
 =SUMIF(B1:B100,"りんご",A1:A100)/COUNTIF(B1:B100,"りんご")
 という方法もあるが。
（ねむねむ） 2015/07/23(木) 13:14

コメント返信：