[[20150823081526]]　『設定した数値まで加算する方法』（クヤサン）　ページの最後に飛ぶ

『設定した数値まで加算する方法』（クヤサン）

A　　　　　B　　　　　　C
２　　　　１３　　　　　結果
３
６
１
３
３
８

A１からA2,A3と加算しB1の数値まで加算し続け、B1の数値に達したら
その数値の合計をC1に出すという式にしたい。

２＋３＋６＋１＋３でB1の１３を越えて１５になり
その１５をC1に出す。

A　　　　　B　　　　　　C
２　　　　１３　　　　　１５
３
６
１
３
３
８

VBAではなくエクセルでこのようなことは出来るのでしょうか。

お知恵を拝借できればと思います。

よろしくお願い致します。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 「マイナスの数値は存在しない」と云う条件で・・

 C1セル =IF(SUM(A1:A10)<B1,"",MIN(TEXT(MMULT(N(ROW(A1:A10)>=TRANSPOSE(MMULT(ROW(A1:A10),1))),A1:A10*1),"[<"&B1&"]"&SUM(A1:A10)&";G/標準")*1))

 <結果図>
  行  _A_  _B_  _C_
   1   2   13   15
   2   3          
   3   6          
   4   1          
   5   3          
   6   3          
   7   8          
   8               
   9               
  10

（半平太） 2015/08/23(日) 11:17

 =SUM(A1:INDEX(A1:A10,MATCH(TRUE,INDEX(SUMIF(INDIRECT("A1:A"&ROW(A1:A10)),"<>")>=B1,),0)))

 =SUM(A1:INDEX(A1:A10,MATCH(TRUE,INDEX(SUMIF(OFFSET(A1,0,0,ROW(A1:A10)),"<>")>=B1,),0)))
　
（GobGob） 2015/08/24(月) 15:50 ⇒ 16：20 OFFSET案追加。

 追記。 A列合計が昇順であることが条件。（＝半平太さんと同条件）
　
（GobGob） 2015/08/24(月) 16:12

 作業列に累計を出しておけば簡単だと思うんだけど、
 それでは何か不都合なことでもあるのかな？

 2行目からデータ開始にしておけばDMIN関数が使えるのでなおよし。

	A	B	C	D	E	F	G
1	データ						条件
2	2	2		13	15		FALSE
3	3	5					
4	6	11		D2：設定値			
5	1	12		E2：結果			
6	3	15					
7	3	18					
8	8	26

 B列作業列

 ■DMIN関数での例

 B2 =IF(A2="","",A2+N(B1))　　下へコピー

 G2 =B2>=$D$2

 E2 =IF(MAX(B:B)>=D2,DMIN(B:B,1,G1:G2),"")

 作業列を設けておけば、DMIN以外にも
 SMALLとCOUNTIFの組み合わせとか、MINの配列数式なんかでもできると思う。

 このまま放置のような気がしないでもないが、一応回答してみた。
（笑） 2015/08/24(月) 17:16

 作業列ならこんなのでもいいね。

 B1 =IF(SUM(A$1:A1)>=C$1,SUM(A$1:A1),"")  下へコピー。
 D1 =MIN(B:B,SUM(A:A))
　
（GobGob） 2015/08/24(月) 17:36

みなさま、ありがとうございます！
これで完成致しました。
（クヤサン） 2015/08/25(火) 07:34

コメント返信：

[ 一覧(最新更新順) ]

[[20150823081526]] 『設定した数値まで加算する方法』（クヤサン） ページの最後に飛ぶ

[[20150823081526]]　『設定した数値まで加算する方法』（クヤサン）　ページの最後に飛ぶ