[[20150916151744]] 『複数条件で合致したデータ抽出 別シートのリスト』(n) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『複数条件で合致したデータ抽出 別シートのリストから。』(n)

お世話になります。初心者です。
DGET関数というのが当てはまりそうでしたので自分で試しましたがVALUE!になってしまうので、教えていただければ幸いです。別の式でも結構です。

シート1(C列に自動で番号が入るようにしたい)
  A       B           C          Y
1 依頼者  引取名義人   引取名義人番号  引取場所
2 A      A                     横浜   
3 A      B                     東京   
4 C      C                     東京

シート2(組み合わせリスト)
  E      F        G        H
1 依頼者  引取名義人  引取場所   引取名義人番号
2  A      A        東京      Y-4321
3   A      B        東京      T-5555
4   C      C        東京      2345008932
5  A      A        横浜      A-000123

C1=DGET(Sheet2!$E$1:$H$1828,Sheet2!H1,???)
シートにまたがってはだめなのでしょうか。Criteriaのところは、B1,C1,Y1と離れていてはだめなのでしょうか。
依頼者は50か所くらい、名義人は20か所くらい、場所との組み合わせで今のところ1828個の引き取名義人番号があります。IFとかVlookupでもできるようなことを過去ログで見ました。お手数おかけします。どうぞよろしくお願いいたします。9時4時の間に見にきます。

< 使用 Excel:Excel2013、使用 OS:7pro >


 名義人番号が数値なら

 =SUMIFS('シート2'!H:H,'シート2'!E:E,A2,'シート2'!F:F,B2,'シート2'!G:G,Y2)

 で、いいんでないの?
 
(GobGob) 2015/09/16(水) 16:17

 C2セルに
 =IF(A2="","",IFERROR(INDEX(Sheet2!H$2:H$2000,MATCH(1,INDEX((Sheet2!E$2:E$2000=A2)*(Sheet2!F$2:F$2000=B2)*(Sheet2!G$2:G$2000=Y2),0),0)),""))
 と入力して下へフィルコピーではどうか?

 なお、組合せリストのほうは2000行まで対応としている。
 もっと行数が増える可能性がある場合は「H$2000」「E$2000」「F$2000」「G$2000」部分を大きく(同じ数値で)してくれ。
(ねむねむ) 2015/09/16(水) 16:21

GobGobさん、ねむねむさん、おはようございます。ご返信をいただきありがとうございます。GobGobさん、引取名義人番号は、アルファベットと数字の組み合わせなどもありましたので修正しました。それでも数値設定で式はなりたつでしょうか。お二方のパターンともこれから試させていただきます。ありがとうございます。

(n) 2015/09/17(木) 09:24


GobGobさん、引取名義人番号のところは数値にして式を入れましたが、結果は0と表示されてしまいました。ねむねむさんの式で成功しました。ありがとうございました!
(n) 2015/09/17(木) 10:22

↓ここから書き直しました。?@11:42 ?A11:54
お世話になります。上記条件に追加事項が出てきました。もし解決方法があれば教えていただければ幸いです。

引き取り場所の名前が、会社名と開催地という組み合わせが多いのですが、
同じ引取会社でも開催地によって引き取り名義人番号がちがうものや、
同じ引取会社であればどこで開催されても同じ引き取り名義人番号という場合もあるため、
下記のように引取場所の名前を前半と後半で分けてみたらどうかと考えました。
中には、”△店”のように、とくに会社名がなくて、店の名前もどんな名前でもよくて、
依頼者がDで引取名義人名がZとくれば必ずP-4444 のようなときもあります。
条件が複雑すぎるでしょうか。

シート1(C列に自動で番号が入るようにしたい)

   A       B           C     W        X
1 依頼者  引取名義人   引取名義人番号  引取場所会社名   引取場所詳細 
2 A      A       Y-4321       アイウ     横浜    
3 A      B       T-5555       アイウ     東京    
4 C      C      2345008932      カキク     東京 
5 D      Z       P-4444               △店
6  A      A       Y-4321       アイウ     大阪
7  A      A       Y-4321       アイウ     福岡

シート2(組み合わせリスト)

   E      F        G        H         I
1 依頼者  引取名義人  引取場所会社名   引取場所詳細   引取名義人番号 
2  A      A        アイウ    どこでも    Y-4321 
3   A      B        アイウ    どこでも    T-5555 
4   C      C        カキク    東京      2345008932 
6    D      Z               △店      P-44444     

(n) 2015/09/28(月) 11:04


 シート2は以下のようにして

   E      F        G        H         I
1 依頼者  引取名義人  引取場所会社名   引取場所詳細   引取名義人番号 
2  A      A        アイウ            Y-4321 
3   A      B        アイウ            T-5555 
4   C      C        カキク    東京      2345008932 
6    D      Z                       P-44444     

 式を
 =IF(A2="","",IFERROR(INDEX(Sheet2!I$2:I$2000,MATCH(1,INDEX((Sheet2!E$2:E$2000=A2)*(Sheet2!F$2:F$2000=B2)*((Sheet2!G$2:G$2000="")+(Sheet2!G$2:G$2000=W2)>0)*((Sheet2!H$2:H$2000="")+(Sheet2!H$2:H$2000=X2)>0),0),0)),""))
 ではどうか?
(ねむねむ) 2015/09/28(月) 12:17

ねむねむさん、ありがとうございます。データの整理も必要なので、少し時間をかけて試してみます。
(n) 2015/09/28(月) 13:14

ねむねむさん、成功することができました。いつもありがとうございます。
(n) 2015/09/30(水) 10:17

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.