[[20151007143533]]　『同じ商品のある条件での最新日付を抽出したい。』（マルカミ）　ページの最後に飛ぶ

『同じ商品のある条件での最新日付を抽出したい。』（マルカミ）

過去ログ[[20120915231942]]を参考させて頂き、条件なしの抽出はできましたが、
条件がついた場合、どのようにすればいいのかわからない状態です。

また、商品に対し、日付が未入力の場合、1900/1/0と表示されるため、
条件付書式で表示させないようにしていますが、数式で表示させない方法が
あればご教示お願いいたします。

　　　　A　　　　　　　B　　　　　　　　　　C　　　　　　　　D
1　　　品名　　　　　出荷日　　　　　　　　条件
2　　　商品A　　　　2015/10/1　　　　　　　　1　　　
3　　　商品A　　　　2015/10/5　　　　　　　　2
4　　　商品A　　　　2015/10/6　　　　　　　　1
5　　　商品B　　　　2015/10/3　　　　　　　　1
6　　　商品B　　　　2015/10/7　　　　　　　　2
7　　　商品B　　　　2015/10/8　　　　　　　　1
8　　　商品C　　　　　　　　　　　　　　　　 2
9
10
11
12
13　　品名　　最新出荷日（条件1）　　品名　　　　　最新出荷日（条件2）
14　　商品A　　　　　　　　　　　　　　　　商品A　　　　　
15　　商品B　　　　　　　　　　　　　　　　商品B
16　　商品C　　　　　　　　　　　　　　　　商品C

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

 リンク先の数式

 =MAX(INDEX((A列条件式)*日付列)

 の条件式を増やせばいいんでないの？
　
（GobGob） 2015/10/07(水) 15:09

 ピボットテーブルではダメなのかな？

 ちなみに
 > 1900/1/0と表示される

 表示形式～ユーザー定義　　yyyy/m/d;;　← 「;;」を付ける

 これで「1900/1/0」は表示されない。

 参考まで。
（笑） 2015/10/07(水) 15:18

 結果を日付データにしたいのであれば
 =IFERROR(TEXT(MAX(INDEX(($A$2:$A$8=A14)*($C$2:$C$8=1)*$B$2:$B$8,0)),"yyyy/m/d")*1,"")

 結果が文字列でも構わなければ
 =TEXT(MAX(INDEX(($A$2:$A$8=A14)*($C$2:$C$8=1)*$B$2:$B$8,0)),"yyyy/m/d;;")
 ではどうか？

 なお、上記の式は条件列(C列)が1のもの。
（ねむねむ） 2015/10/07(水) 15:19

GobGobさん、笑さん、ねむねむさん、有難う御座います。

ねむねむさんの数式にて、思いとおりの結果を得ることができました。
すごく助かりました。
（マルカミ） 2015/10/07(水) 16:03

 一応、参考まで。

 B14 =MAX(INDEX(($A$2:$A$10=A14)*($C$2:$C$10=1)*$B$2:$B$10,0))

 表示形式～ユーザー定義　yyyy/m/d;;　←「;;」を付ける

 B16に「1900/1/0」は表示されない（ただし値は「0」）

 これだと何か問題あるのかな？
（笑） 2015/10/07(水) 16:33

笑さん、有難うございます。

他のセルで1900/1/0と表示されるため、
条件付書式にて、0の場合文字色を白にしていましたが、
ユーザー定義にて yyyy/m/d;;とすることで、
表示されなくなりすっきりしました。
有難うございました。
（マルカミ） 2015/10/08(木) 08:08

コメント返信：

[ 一覧(最新更新順) ]

[[20151007143533]] 『同じ商品のある条件での最新日付を抽出したい。』（マルカミ） ページの最後に飛ぶ

[[20151007143533]]　『同じ商品のある条件での最新日付を抽出したい。』（マルカミ）　ページの最後に飛ぶ