[[20160429112825]]　『同じ列の複数条件の計算式を教えて頂きたいのです』（つむつむ）　ページの最後に飛ぶ

『同じ列の複数条件の計算式を教えて頂きたいのですが』（つむつむ）

日頃から参考にさせて頂いて降ります。
有難うございます。

下記の様な表があります。
Ａ列とＢ列の条件で合計の金額を計算したいのです。
Ａ列の条件は、一個です
Ｂ列の条件は、複数有ります。
アバウトの条件で検索したいのですが
答えは　Ｅ－１３＝７　Ｅ－１４＝２１

       A          B         C         D        E	
  1  地域	商品       金額			
  2  東京    大根（小）     1			
  3  東東京  赤にんじん     2			
  4  西東京  男爵いも       3			
  5  東京    トマト         4			
  6  大阪    大根（中）     5			
  7  大阪    ねぎ	    6		
  8  大阪    たまねぎ       7			
  9  大阪    いも	    8			
 10           			
 11            			
 12  地域      商品         商品      商品     金額	
 13 *東京*  *にんじん*    *トマト*   *大根*      7
 14 *大阪*  *ねぎ*        *たまねぎ* *いも*     21

自分で考えてやって見ましたが、出来ませんでした。

宜しくお願い致します。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

１４行目の条件　答え　を変更致します。（*ねぎ*と*たまねぎ*の条件では重複すると思われるため）

      A          B         C         D        E	
  1  地域	商品       金額			
  2  東京    大根（小）     1			
  3  東東京  赤にんじん     2			
  4  西東京  男爵いも       3			
  5  東京    トマト         4			
  6  大阪    大根（中）     5			
  7  大阪    ねぎ	    6		
  8  大阪    たまねぎ       7			
  9  大阪    いも	    8			
 10           			
 11            			
 12  地域      商品         商品      商品     金額	
 13 *東京*  *にんじん*    *トマト*   *大根*      7
 14 *大阪*  *大根*        *ねぎ*     *いも*     26

宜しくお願い致します。

（つむつむ） 2016/04/29(金) 12:21

 こんにちわ。
 検索条件を下のように変更して、

      A          B         C         D        E	
  1  地域	商品       金額			
  2  東京    大根（小）     1			
  3  東東京  赤にんじん     2			
  4  西東京  男爵いも       3			
  5  東京    トマト         4			
  6  大阪    大根（中）     5			
  7  大阪    ねぎ	    6		
  8  大阪    たまねぎ       7			
  9  大阪    いも	    8			
 10           			
 11            			
 12  地域      商品         商品      商品     金額	
 13  東京    にんじん      トマト     大根       7
 14  大阪    大根          ねぎ       いも      26

 E13=SUM((IFERROR(FIND(A13,A$2:A$9)*FIND(B13:D13,B$2:B$9),0)>0)*C$2:C$9)
 [Ctrl]+[Shift]+[Enter]同時押し
 下にフィルコピー

 でどうでしょうか？

（sy） 2016/04/29(金) 14:13

sy様
ご連絡有難うございます。

sy様の式で完璧に出来ました。
有難うございました。
（つむつむ） 2016/04/29(金) 16:55

 補足です。

 今気付きましたが、 私の式で商品の条件欄が3つ埋まってる時は問題ないですが、
 1つでも空欄になっていれば、空欄1つに付き全て一致で合計されてしまいます。

 なので条件が2つ以下の時は、残りを空欄の代わりに-などの絶対に一致しない文字を入力して下さい。

（sy） 2016/04/29(金) 18:50

sy様
ご連絡有難うございます。

補足　有難うございます。
なんとか理解しましたので、空欄にならない様に致します。

最後まで有難うございます。
（つむつむ） 2016/04/29(金) 21:40

 おはようございます。

 普通にSUMIFで行けました。
 単に検証する時に操作を間違えた為、使用できないと勘違いしてしまいました。
 すいません。
 こちらなら条件が2つ以下で空欄が出来ても大丈夫です。

 E13=SUM(SUMIFS($C$2:$C$9,$B$2:$B$9,B13:D13,$A$2:$A$9,A13))
 [Ctrl]+[Shift]+[Enter]同時押し

 下のようにすれば普通にエンターで確定できます。

 E13=SUM(INDEX(SUMIFS($C$2:$C$9,$B$2:$B$9,B13:D13,$A$2:$A$9,A13),0))

      A          B         C         D        E	          			
 12  地域      商品         商品      商品     金額	
 13 *東京*  *にんじん*    *トマト*   *大根*      7
 14 *大阪*  *大根*        *ねぎ*     *いも*     26

（sy） 2016/04/30(土) 07:00

sy様
ご連絡有難うございます。

さらに新しい数式　感激です。
有難うございます。

色々な式が有ることを、あらためて実感しました。

配列数式の理解度は低いのですが、
SUMIFS関数は何度も使用した事が有りますので
今後の応用も可能ではないかと思い
今回は、教えて頂きました中から下記の配列数式でやってみます。
今後、会社での仕事も楽になり幅も広がるものと思います。
E13{=SUM(SUMIFS($C$2:$C$9,$B$2:$B$9,B13:D13,$A$2:$A$9,A13))}

感謝申し上げます。
本当に有難うございました。
（つむつむ） 2016/04/30(土) 08:07

コメント返信：

[ 一覧(最新更新順) ]

[[20160429112825]] 『同じ列の複数条件の計算式を教えて頂きたいのです』（つむつむ） ページの最後に飛ぶ

[[20160429112825]]　『同じ列の複数条件の計算式を教えて頂きたいのです』（つむつむ）　ページの最後に飛ぶ