[[20160521143008]]　『特定のセルに日付を入力したら別表の同日とその下』（だいふく）　ページの最後に飛ぶ

『特定のセルに日付を入力したら別表の同日とその下のセルに色を付け、さらに・・・。』（だいふく）

下記のようなこと（特に２、３）を、関数や条件付き書式でできるでしょうか？
１）Ａ２に日付（当日ではありません）を入力すると、その下にある別表の同日と入力日（この場合5/10、入力日05エ）のセルを赤にしたい思っています。
２）できれば、色が付いた入力日の単語（この場合、05エ）と同じ単語が回答日にあれば、その単語と日付のセルを青色にしたい…と思っています。（この場合、5/12と05エ）
３）さらに、できるなら、青セルの日付5/12をＢ２に入力できるようにしたいと思っています。（この場合、5/12）

　　　Ａ　　　　Ｂ　　　　
１　入力日　　5月10日　←手入力したら別表の5/10と入力日の「05エ」のセルが赤くなる。　
２　回答日　　5月12日　←別表の入力日の5/12を入力できるようにしたい。

＜別表＞
　日付　　5/9　 5/10　5/11　5/12　5/13　5/14　5/15　・・・
　入力日　05ウ　05エ　05オ　05カ　05キ　05ク　05ケ　・・・
　回答日　05ア　05イ　05ウ　05エ　05オ　05カ　05キ　・・・
　　　
１）だけでも、できればと思ってます。
よろしくお願いします。

＜使用 Excel：Excel2010、使用 OS：WindowsXP ＞

B2はMATCHとINDEXで求められませんか
http://www.eurus.dti.ne.jp/~yoneyama/Excel/kansu/index_function.htm

（マナ） 2016/05/21(土) 20:31

 ダミー行(14行目）を追加した簡便式を示します。
 本格版は他の方の回答をお待ちください。

    A             B
 1  入力日        5月11日
 2  回答日        5月13日

     A            B    C    D    E    F    G    H   
 11 日付          5/9  5/10 5/11 5/12 5/13 5/14 5/15 ・・・ 
 12 入力          05ウ 05エ 05オ 05カ 05キ 05ク 05ケ ・・・ 
 13 回答          05ア 05イ 05ウ 05エ 05オ 05カ 05キ ・・・ 
 14 回答に対する            5/9  5/10 5/11 5/12 5/13 ・・・
    入力日

 ●B14は、=IFERROR(INDEX($B$11:$H$11,1,MATCH(B13,$B$12:$H$12,0)),"")

 ●条件付き書式
 B11:H12  を適用先範囲にして、
 ルールの算式は、
       =$B$1=B$11

 ●回答日セル（B2）は
       =INDEX($B$11:$H$11,1,MATCH(B1,$B$14:$H$14,0))

 範囲は適当にモデル化しています。
 実際に合わせて修正してください。

 「一日に一つの入力と回答しかない」という前提が簡略化しすぎた前提でないことを願う。

（γ） 2016/05/21(土) 20:35

 こんばんわ。

 下のようなレイアウトになっているとして、

    |[A]   |[B]    |[C]    |[D]    |[E]    |[F]    |[G]    |[H]    
 [1]|入力日|5月10日|       |       |       |       |       |       
 [2]|回答日|5月12日|       |       |       |       |       |       
 [3]|      |       |       |       |       |       |       |       
 [4]|      |       |       |       |       |       |       |       
 [5]|日付  |5月9日 |5月10日|5月11日|5月12日|5月13日|5月14日|5月15日
 [6]|入力日|05ウ   |05エ   |05オ   |05カ   |05キ   |05ク   |05ケ   
 [7]|回答日|05ア   |05イ   |05ウ   |05エ   |05オ   |05カ   |05キ

 1)は、5～6行目全体を選択して、条件付き書式→数式に
 =A$5=$B$1

 2)は、5と7行目全体を選択して、条件付き書式→数式に
 =INDEX($6:$6,MATCH($B$1,$5:$5,0))=A$7

 3)は、関数で表示させるんですか？
 もしくは、入力規則で5月12日のみ入力できるようにするんですか？
 どちらにしても数式は同じで、
 =INDEX(5:5,MATCH(INDEX(6:6,MATCH(B1,5:5,0)),7:7,0))
 関数で表示させるなら、B2セルに数式を入力。
 入力規則で制限するなら、B2セルを選択、入力規則→リスト→ドロップダウンリストから選択するのチェックを外す
 →数式欄に上記の関数を入力。

 で、どうでしょうか？

（sy） 2016/05/21(土) 20:42

詳しい説明をありがとうございました。
お二人の方法を、同僚と話しあって、関数が崩れた（？）時、直しやすい方を考えています。
とは言っても、次に使う人のために、お二人の方法を残していきます。

ほんとにありがとうございました。

（だいふく） 2016/05/24(火) 22:47

コメント返信：

[ 一覧(最新更新順) ]

[[20160521143008]] 『特定のセルに日付を入力したら別表の同日とその下』（だいふく） ページの最後に飛ぶ

[[20160521143008]]　『特定のセルに日付を入力したら別表の同日とその下』（だいふく）　ページの最後に飛ぶ