[[20160525125633]] 『1つのセルに改行されている文字を1番下の行だけ』(nobipan) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『1つのセルに改行されている文字を1番下の行だけ残して抽出したい』(nobipan)

 いつもお世話になっております。

 A列の1つのセルに
 商品名1
 商品名2
 店舗名
 が改行されて入力されています。
 (商品名は、1つの場合もあれば、2つ以上の場合は商品名ごとに改行されています。)
 
 これを、商品名のみB列に(商品名が2つ以上の場合は改行されたままのじょうたいで)抽出したいのです。
 ※商品名の中には、カンマが使用されているものもあります。

 B列には、どんな関数を入れたらいいでしょうか?

 ご教授願います。 Excel2007です 宜しくお願い致します。

< 使用 Excel:Excel2007、使用 OS:Windows7 >


 商品名、店舗名に「$」が使われていない場合。

 =LEFT(A1,FIND("$",SUBSTITUTE(A1,CHAR(10),"$",LEN(A1)-LEN(SUBSTITUTE(A1,CHAR(10),""))))-1)

 もし、「$」が使われているならば式中の「$」を商品名、店舗名で使われていない文字に変えてくれ。
(ねむねむ) 2016/05/25(水) 13:23

 ねむねむ様 ありがとうございます!

 しかし、1つ記述忘れた事がありました・・・
 場合によっては、店舗名が記載されておらず
 商品名が1つしか記載されてない場合もあるのです。
 この場合も商品名のみB列に抽出したいのです。

 大変申し訳ありませんが 宜しくお願い致しますm(_ _)m

(nobipan ) 2016/05/25(水) 13:33


 =LEFT(A1,FIND("$",IFERROR(SUBSTITUTE(A1,CHAR(10),"$",LEN(A1)-LEN(SUBSTITUTE(A1,CHAR(10),""))),A1&"$"))-1)
 ではどうだろうか?
(ねむねむ) 2016/05/25(水) 13:38

 =LEFT(A1,FIND("$",SUBSTITUTE(A1,CHAR(10),"$",MAX(1,LEN(A1)-LEN(SUBSTITUTE(A1,CHAR(10),""))))&"$")-1)
 でも。
(ねむねむ) 2016/05/25(水) 13:40

 B1 =SUBSTITUTE(A1,CHAR(10)&TRIM(RIGHT(SUBSTITUTE(A1,CHAR(10),REPT(" ",100)),100)),"")
 
「折り返して全体を表示する」にチェック

 とかでもオッケー?
(笑) 2016/05/25(水) 13:42

 「店舗名が記載されていない」ってのは「改行は2回されている」の?
 されてないと 店舗名なのか商品名なのかExcelには判断できまへんよ。
 
 
(GobGob) 2016/05/25(水) 14:08

 あー。「商品名二つ + 店舗名」と「商品名1つのみ」の2種類のみってことね。

 =IFERROR(LEFT(A1,FIND(CHAR(10),A1,FIND(CHAR(10),A1)+1)-1),A1)
 
(GobGob) 2016/05/25(水) 14:12

 GobGobさん

 >(商品名は、1つの場合もあれば、2つ以上の場合は商品名ごとに改行されています。) 
 と店舗名がある場合は商品名は二つとは限らないようだ。

 店舗名がない場合は商品名は必ず一つのようだが。
(ねむねむ) 2016/05/25(水) 14:18

 「以上」を見逃してました。
 ねむねむさんサンキューですw。

 オイラの回答は無視してくださいなー。
 
(GobGob) 2016/05/25(水) 14:19

 =IFERROR(LEFT(A1,MATCH(1,INDEX(0/(MID(A1,ROW(1:100),1)=CHAR(10)),0),1)),A1)
 これでもいいかな。

 修正
 おっと
 =IFERROR(LEFT(A1,MATCH(1,INDEX(0/(MID(A1,ROW(1:100),1)=CHAR(10)),0),1)-1),A1)
 だった。
(ねむねむ) 2016/05/25(水) 14:41

ねむねむ様、 GobGob様 

2つ以上の商品
=IFERROR(LEFT(A1,MATCH(1,INDEX(0/(MID(A1,ROW(1:100),1)=CHAR(10)),0),1)-1),A1)
でいけました。

お忙しいところ ありがとうございました!
(nobipan ) 2016/05/25(水) 17:05


コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.