[[20160525160551]]　『複数列の比較方法？』（ナナコ）　ページの最後に飛ぶ

『複数列の比較方法？』（ナナコ）

わりと初心者でございます・・
何卒宜しくお願い致します。

下記のような＜Aシート＞と＜Bシート＞を比較し、
[住所]列か[ピル名]列に変更があれば、
＜Aシート＞の確認欄に"変"を返す、というような
関数を教えて下さいませ。

＜Aシート＞
番号名前住所ビル名確認
101 AAAAAA 東京 FFﾋﾞﾙ
102 BBBBBB 横浜 GGﾋﾞﾙ
103 CCCCCC 埼玉 HHﾋﾞﾙ
104 DDDDDD 埼玉 IIﾋﾞﾙ
105 EEEEEE 東京 JJﾋﾞﾙ

＜Bシート＞
番号名前住所ビル名
101 AAAAAA 東京 FFﾋﾞﾙ
102 BBBBBB 横浜 GGﾋﾞﾙ
103 CCCCCC 横浜 GGﾋﾞﾙ
104 DDDDDD 埼玉 HHﾋﾞﾙ
105 EEEEEE 東京 JJﾋﾞﾙ

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 =IF(COUNTIFS(B!A:A,A2,B!B:B,B2,B!C:C,C2),"","変更")
 下へコピー。
　
（GobGob） 2016/05/25(水) 16:22

 >[住所]列か[ピル名]列に変更があれば、 
 だと
 =IF(COUNTIFS(B!A:A,A2,B!C:C,C2,B!D:D,D2),"","変更")
 では。
（ねむねむ） 2016/05/25(水) 16:25

GobGob様、ねむねむ様、ありがとうございます。
言葉足らずなのと、例が雑すぎました…
＜A＞と＜B＞の[番号]列の文字が同一文字の列の、
[住所]列か[ピル名]列に変更があれば、、、
という条件が加わります、
このような説明でわかるでしょうか。

 =IF(COUNTIFS(B!A:A,A2,B!C:C,C2,B!D:D,D2),"","変更")
 の式でどのような場合に意図と反した結果になるのだろうか？

（ねむねむ） 2016/05/25(水) 16:38

ねむねむ様、ありがとうございます、できていました、
ただし、＜A＞にあって＜B＞にはない番号も「変更」とでてきて
しまうのですね
でも、そんなに数がありませんので、全然いいです、
本当にありがとうございまし。

 その場合であれば
 =IF(COUNTIF(B!A:A,A2),IF(COUNTIFS(B!A:A,A2,B!C:C,C2,B!D:D,D2),"","変更"),"対象なし")
 などとしてはどうだろうか？

 追記
 「対象なし」よりも「新規」のほうがいいか。

（ねむねむ） 2016/05/25(水) 17:03

ねむねむ様、ありがとうございました！
希望通りの大満足です！
本当にいつもお名前を拝見して尊敬しております。。
今後ともよろしくお願い致します。

毎度使い回しで活用していますが、、、
引き続き上記関数の質問をさせてください。
比較対象セルがどちらもブランクの場合、「変更」とでてしまいます、
解消方法はありますか？（ナナコ）
＜追記＞
どちらもブランクで変わりがないなら、何も表示なしとしたいです。

 =IF(COUNTIF(B!A:A,A2),IF(COUNTIFS(B!A:A,A2&"",B!C:C,C2&"",B!D:D,D2&""),"","変更"),"新規")
 ではどうだろうか？

 あと、返事や追加質問時は編集で行わずに下にあるコメント欄から行ってくれ。
 今回の＜追記＞のような場合に編集を使ってくれ。
（ねむねむ） 2016/07/13(水) 16:06

ありがとうございます、ねむねむ様
完璧になりました!!
コメント欄の件も承知致しました。大変失礼いたしました･･･

（ナナコ） 2016/07/13(水) 16:24

コメント返信：