[[20160615194013]]　『複数の条件に当てはまる結果を表示したい』（uniuni）　ページの最後に飛ぶ

『複数の条件に当てはまる結果を表示したい』（uniuni）

初心者ですみませんが、教えて頂けますでしょうか。

  1　　 2    3
A 関東　60cm 600円
B 関東  80cm 800円
C 関西　60cm 900円
D 関西  80cm 1100円

上記の表を元に

E1が"関東"かつE2"60"であればE3は"600円"

という風に複数の条件を入れた関数を作成する場合には
どのようにすれば良いでしょうか？
上記は4パターンですが合計10パターンあります。

IF関数などでいくつか方法がありそうな気がするのですが、
上手くいきませんでした。

宜しくお願いします。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

データベース関数で検索してみてください
DGET関数が使えそうです。ただし、見出しが必要ですが。

（マナ） 2016/06/15(水) 20:41

 提示のサンプル、行番号と列番号が逆だとして、
 C列の価格（？）は「円」も入力してるんですかね？
　
「円」を削除して数値にすれば SUMIFS 関数でもできます。
　
「円」を表示したければ、表示形式のユーザー定義で。
（笑） 2016/06/15(水) 21:34

	A	B	C	D	E
1	関東	60cm	600円		関東
2	関東	80cm	800円		60cm
3	関西	60cm	900円
4	関西	80cm	1100円

実はこういうレイアウトと値だったとします。
E3: =INDEX(C:C,MATCH(E1&E2,INDEX(A:A&B:B,0),0))
（???） 2016/06/16(木) 09:37

E3=INDIRECT("C" & SUMPRODUCT((A:A=E1)*(B:B=E2),ROW(C:C)*1))
（mm） 2016/06/16(木) 10:10

 ???さんのレイアウトを借りて。

 =INDEX(C:C,MATCH(1,INDEX((A:A=E1)*(B:B=E2),0),0))

 それとmmさん、ROW関数の結果は数値なので*1はいらないと思うが。
（ねむねむ） 2016/06/16(木) 10:20

 > E2"60"であれば

 この「60」は「60cm」の間違いなのか、
 それとも条件は「cm」を省略したいのか、
 あるいは実際の表に「cm」は入力されていないのか、
 どれだかわかりませんが、とりあえず条件入力は表の値に合わせるとして･･･

 条件の指定が1度に1パターンのみなら、見出し行を作って DGET 関数がお勧め。

	A	B	C	D	E	F	G
1	地域	長さ	価格		地域	長さ	
2	関東	60cm	600円		関西	80cm	1100円
3	関東	80cm	800円				
4	関西	60cm	900円				
5	関西	80cm	1100円

 見出しはあくまで例です。

 G2 =DGET(A1:C20,C1,E1:F2)

 他にも

 =LOOKUP(1,0/((A2:A20=E2)*(B2:B20=F2)),C2:C20)

 こんな感じでもできますが（見出しはなくても可）
 こんな式にするぐらいなら、C列を数値にして、SUMIFS 関数でやるほうがいいですね。

 参考まで。
（笑） 2016/06/16(木) 11:43

元の表の行と列を間違えたり、cmや円を入れてしまったりで
ややこしくしてしまい申し訳ありません。
cmや円は必要ありませんでした。
皆様有難うございました。

皆さんの数式で試させて頂き、指定の条件が複数パターンあったため、
??さん、mmさん、ねむねむさんの方法で上手くいきました！！
最終的にねむねむさんの教えて頂いた物で落ち着きました･･･。

ほんっとうに助かりました！！
有難うございました。
（uniuni） 2016/06/16(木) 18:45

 ほう、するってえと、なんですかい、
 ↓ の式ではできなかったと、そうおっしゃるんですかい？

 =LOOKUP(1,0/((A2:A20=E2)*(B2:B20=F2)),C2:C20)

 それはなんとも不可解ですな。

 それと SUMIFS は試してもらったんですかね？

 最終的にどの式を選択するかは、もちろん質問者の自由ではあるけれど、
 できるできないは、また別問題だからね。

 一応、気になったもんで。
（笑） 2016/06/16(木) 22:44

コメント返信：