[[20160820202257]] 『営業時間内の実質稼動時間を計算したい』(ほんわ) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『営業時間内の実質稼動時間を計算したい』(ほんわ)

類似質問で、20040927082338 があるのですが
下記の式でできました。
=B1-A1-((DATEDIF(A1,B1,"d")+1-NETWORKDAYS(A1,B1,祝日)))

こちらの質問は24時間体制の土日祝日を除く営業時間内で実質稼動経過時間を計算しているようです。
祝日の除外は別途、名前を定義して設定しているようです。
例)
(受付)2004年9月10日16時
(終了)2004年9月13日 10時
     
9/10金 16時〜24時 ・・・ 8時間
9/11土 0時〜24時 ・・・24時間(土曜なので省く) 
9/12日 0時〜24時 ・・・24時間(日曜なので省く) 
9/13月 0時〜10時 ・・・10時間
土日を省けば 金の8時間と月曜の10時間で 作業時間は18時間
※もし祝日があればそれも省きたい。

****************************************************************

今回、質問したいのは、営業時間24時間体制ではなく
8:00から17:30の営業時間内で分単位まで計算したいです。

例)
(受付)2004年9月10日16時15分
(終了)2004年9月13日 10時20分

9/10金 16時15分〜17時半・・・ 1時間15分
9/11土 8時〜17時半・・・(土曜なので省く) 
9/12日 8時〜17時半・・・(日曜なので省く) 
9/13月 8時〜10時20分・・・2時間20分

土日を省けば 金の1時間15分と月曜の2時間20分で 作業時間は3時間35分という計算をしたいです。
※もし祝日があればそれも省きたい。

< 使用 Excel:Excel2007、使用 OS:WindowsXP >


 受付と終了は、必ず営業日であるものとします。

 (1) C2セル =IF(D2="","",E2+IF(D2<0,0,D2*"9:30"+F2))
 (2) D2セル =IF(COUNT(A2:B2)<2,"",NETWORKDAYS(A2,B2,祭日リスト)-2)
 (3) E2セル =IF(D2="","",MAX(0,MIN(B2,INT(A2)+"17:30")-MAX(A2,INT(A2)+"8:00")))
 (4) F2セル =IF(D2="","",MAX(0,MIN(B2,INT(B2)+"17:30")-MAX(A2,INT(B2)+"8:00")))

 <結果図>
  行  _______A_______  _______B_______  ____C____  ______D______  _______E_______  _______F_______
   1        受付             終了       作業時間   中間フル日数   受付日作業時間   終了日作業時間 
   2  2004/9/10 16:15  2004/9/13 10:20    3:35           0               1:15             2:20    
   3  2004/9/10 16:15  2004/9/10 17:30    1:15          -1               1:15             1:15    
   4  2004/9/10 16:15  2004/9/14 10:20   13:05           1               1:15             2:20    
   5  2004/9/10 16:15  2004/9/14 17:30   20:15           1               1:15             9:30    
   6  2004/9/10 16:15  2004/9/15  8:30   20:45           2               1:15             0:30    

(半平太) 2016/08/20(土) 23:07


ありがとうございました!とてもわかりやすかったです!
(ほんわ) 2016/08/21(日) 10:16

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.