[[20160824191408]]　『数字を右から１つずつ抜き出す関数を教えてくださ』（派遣社員）　ページの最後に飛ぶ

『数字を右から１つずつ抜き出す関数を教えてください。』（派遣社員）

リストシートのＧ２セルに入力した数字（最大9桁）を
振込シートのセルに右端から１つずつ抜き出す関数を教えてください。
※リストシートのＧ２セルに入力した数字の桁数は変動します。
振込シートに表示される数字の頭には￥を表示させたいです。

例1）リストシート　Ｇ２セル⇒123456

　　振込シート　I9　k5　M5　O5　Q5　S5　U5　W5　Y5　（セル番号)
　　　　　　　　　　￥　 1　　2　　3　　4　　5　　6　　7　　8

例2）リストシート　Ｇ２セル⇒12345

　　振込シート　I9　k5　M5　O5　Q5　S5　U5　W5　Y5　（セル番号)
　　　　　　　　　　　　　　　　　　￥　　1　　2　　3　　4　　5

よろしくお願いします

＜使用 Excel：Excel2010、使用 OS：WindowsXP ＞

 交通整理だけ。

 １．I9 は I5 ではなく、I9 なんですか？

 ２．9桁の場合は、どうなりますか？

 ３．結果をセットする各セルは結合セルなんですか？

（β） 2016/08/24(水) 21:49

(β)様
ご連絡ありがとうございます。
1.I9ではなくてI5でした。すみません。
2.9桁の場合はすべて数字の表示で\は不要です。
3.振り込み用紙に金額を印刷するため位置合わせ
するためにセルを結合しています。

（派遣社員） 2016/08/24(水) 21:59

 こんばんわ。

 一応以下の式で出来ます。

 I5 =IF(INT(LOG($G$2))<=7-(COLUMN(A1)+1)/2,"",IF(INT(LOG($G$2))=8-(COLUMN(A1)+1)/2,"\",INT(MOD($G$2,10^10/10^((COLUMN(A1)+1)/2))/(10^9/10^((COLUMN(A1)+1)/2)))))
 右にオートフィル

（sy） 2016/08/24(水) 22:04

 I5セルに
 =MID(RIGHT(TEXT($G$2,REPT(" ",14)&"\"&REPT(" 0",LEN($G$2))),17),COLUMN(A1),1)
 と入力して右へフィルコピーではどうか。

 なお、結果は文字列となる。

 追記
 空いているセルにはスペースが入っている。
 もし、スペースを消したい場合は
 =TRIM(MID(RIGHT(TEXT($G$2,REPT(" ",14)&"\"&REPT(" 0",LEN($G$2))),17),COLUMN(A1),1))
 とTRIM関数をかませてくれ。
（ねむねむ） 2016/08/24(水) 22:29

（sy）さん（ねむねむ）さん回答ありがとうございました。
リストシートに入力したデータを振込シートに反映させたいのですが
うまくいきません。（同一シート内でしたらできました）

すみませんがご教授いただけませんでしょうか？

（派遣社員） 2016/08/24(水) 23:23

 ねむねむさんの式でも私の式でも修正方法は同じで、全ての$G$2の左にシート名!を付ければ良いです。

 例えば「リスト」と言うシート名なら、「リスト!$G$2」になります。

 書式を後で修正するでも良いなら、式の入っているセルを全て選択して、切取→振込シートの式を入れたい範囲を選択して貼り付けでも良いです。

（sy） 2016/08/24(水) 23:40

 数式の入っているセルを全て選択して、置換で検索文字に「$G$2」、置換後の文字に「リスト!$G$2」、オプションのセルの内容が完全に同一のチェックを外して、全て置換でも行けますね。

 シート名は適切な名前にして下さい。

（sy） 2016/08/24(水) 23:45

 I5 =MID(RIGHT(TEXT($G2,"       \0"),9),COLUMN(A1)/2+1,1)
 I5:J5を選択して右へコピー。

 I5 =IF(MOD(COLUMN(A1),2),MID(RIGHT(TEXT($G2,"       \0"),9),COLUMN(A1)/2+1,1),"")
 右へコピー。
　
（GobGob） 2016/08/25(木) 09:59 → 10:08 加筆

 GobGobさん
 >3.振り込み用紙に金額を印刷するため位置合わせするためにセルを結合しています。 
 とI・J列、K・L列…Y・Z列で結合しているようだ。

 なのでGobGobさんの最初の式をI5・J5の結合セルに入力して右へコピーするだけでよさそうだ。
（ねむねむ） 2016/08/25(木) 10:10

 ＞ねむねむさん。

 あー。そういうことでしたか。（よく読んでなかったｗ）
　
（GobGob） 2016/08/25(木) 10:16

書き込み頂きありがとうございました。
ちゃんと出来ました。
（派遣社員） 2016/08/25(木) 19:37

コメント返信：

[ 一覧(最新更新順) ]

[[20160824191408]] 『数字を右から１つずつ抜き出す関数を教えてくださ』（派遣社員） ページの最後に飛ぶ

[[20160824191408]]　『数字を右から１つずつ抜き出す関数を教えてくださ』（派遣社員）　ページの最後に飛ぶ