[[20161021152451]] 『最大値の関数について』(集計) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『最大値の関数について』(集計)

  4月   5月   6月   7月  … 各月の合計が最大値の数値
A 12,000 10,000 22,000 34,000 … 34,000
B 25,000 34,000 12,000 10,000 … 10,000
C 11,000 19,000 19,000 23,000 … 23,000
計 48,000 63,000 53,000 67,000 … 67,000

それぞれの項目の最大値ではなく、合計が最大値の数値を求める関数ってありますか?

< 使用 Excel:Excel2010、使用 OS:Windows7 >


 MAX関数でよさそうな気がしますが。
 ちなみにBのところは34,000ですよね?
(bi) 2016/10/21(金) 15:42

 合計の最大値が複数あった場合はどうするのか?

 biさん、合計の最大値が7月の67000なのですべて7月の値を持ってくるのだと思うが。
(ねむねむ) 2016/10/21(金) 15:43

ねむねむさんの、とおりです。
(集計) 2016/10/21(金) 15:51

 最大値が複数あった場合の扱いに返答がないが。

 最大値が複数無い場合。
 =SUMIF(A$5:L$5,MAX(A$5:L$5),A2:L2)

 複数ある場合は一番左の物。
 =INDEX(A2:L2,MATCH(1,INDEX((A$5:L$5=MAX(A$5:L$5))*1,0),0))

 複数ある場合は一番右の物
 =INDEX(A2:L2,MATCH(1,INDEX(0/(A$5:L$5=MAX(A$5:L$5)),0),1))
(ねむねむ) 2016/10/21(金) 15:55

ねむねむさん、最大値が複数あった場合は、どれでも問題ないです。

ありがとうございます。
(集計) 2016/10/21(金) 16:00


 勘違いでしたか。失礼しました。
(bi) 2016/10/21(金) 16:01

 M5セルに合計の最大値が出ているならば式中のMAX(A$5:L$5)部分は全てM$5に置き換えれるか。
(ねむねむ) 2016/10/21(金) 16:08

前回は、ありがとうございました。

月々の集計に、件数・金額

  4月     …
3件 12,000円 … という場合は、

=INDEX(A2:L2,MATCH(1,INDEX((A$5:L$5=MAX(A$5:L$5))*1,0),0))
     ↑範囲選択って、どのようにすれば良いでしょうか??
(集計) 2016/10/28(金) 13:15


 以下のようなレイアウトだとする。

      A      B      C      D      E      F      G      H      I    〜    Z      AA
 1               4月           5月          6月          7月         各月の合計が最大値の数値
 2    A      3    12,000   2    10,000   1    22,000   3    34,000       3    34,000
 3    B      3    25,000   1    34,000   1    12,000   1    10,000       1    10,000
 4    C      4    11,000   6    19,000   2    19,000   2    23,000       2    23,000
 5   計     10     48000   9     63000   4     53000   6     67000       6    67,000

 Z2セルに
 =INDEX(B2:X2,MATCH(1,INDEX((C$5:Y$5=AA$5)*1,0),0))
 と入力してZ5セルまでフィルコピー。

 AA2セルに
 =INDEX(C2:Y2,MATCH(1,INDEX((C$5:Y$5=AA$5)*1,0),0))
 と入力してAA4セルまでフィルコピー、AA5セルに
 =MAX(C5,E5,G5,I5,K5,M5,O5,Q5,S5,U5,W5,Y5)
 または
 =MAX(INDEX(MOD(COLUMN(B5:Y5),2)*B5:Y5,0))
 と入力、ではどうか。

 なお、上記式は件数計と金額計が同じ値にはならないことを前提としている。
 (金額計内・件数計内で同じ値があるのはかまわない)
(ねむねむ) 2016/10/28(金) 13:41

ねむねむさん。

前回に続き、ありがとうございました。

すばらしい!!
(集計) 2016/10/28(金) 14:38


コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.