[[20161025135123]]　『使用料の自動計算』（あほまる）　ページの最後に飛ぶ

『使用料の自動計算』（あほまる）

施設の使用料自動計算式を作りたいです。

●子ども　9：00～17：00＝100円/時間
　　　　　17：00～21：00＝200円/時間

●大人　　 9：00～17：00＝300円/時間
　　　　　17：00～21：00＝500円/時間

●暖房料　1000円/時間

※1時間未満の場合は1時間とみなす。

上記条件のもと、子どもか大人の区分入力、使用時間の入力、
暖房時間の入力で使用料の自動計算式を作りたいので
よろしくお願いします。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 たとえば16:30から17;30の場合、単純な経過時間は1時間だが、この場合300*0.5+500*0.5（大人の場合）になるのか、
 17:00までの30分、17:00からの30分をそれぞれ1時間とみて300*1+500*1と見るのか、どちらだろうか？

（ねむねむ） 2016/10/25(火) 14:05

ねむねむ様、お早いご回答ありがとうございます。
利用規則からそれぞれ1時間とみなすこととなりますので
300*1+500*1となります。
（あほまる） 2016/10/25(火) 14:19

 横入りすんませんｗ。

 16:30～17:30 = 300*1 + 500*1 のときの暖房代は1000円？ 2000円？
　
（GobGob） 2016/10/25(火) 14:28

GobGob様、ありがとうございます。
暖房料はそのまま1時間とみますので1,000円です。
（あほまる） 2016/10/25(火) 14:42

 勘違いで削除

 １ 9:30～10:30 は 1時間使用
 ２ 9:00～10:30 は 2時間使用
 ３ 時間帯を跨ぐと それぞれ繰り上げ

 こんな観点っぽいので。。。
　
（GobGob） 2016/10/25(火) 15:31

GobGob様、仰るとおりです。
単純に1時間使用はそのまま1時間ですが
1時間30分は2時間の使用料となります。
（あほまる） 2016/10/25(火) 15:38

 仕切りなおし。。。

	A	B	C	D	E
1	区分	暖房	FROM	TO	金額
2	子ども	×	9:00	17:00	800
3	子ども	○	17:00	21:00	4,800
4	子ども	×	16:30	17:30	300
5	子ども	○	16:30	17:30	1,300
6	子ども	×	16:00	18:00	300
7	子ども	×	17:00	19:00	400
8	大人	×	9:00	17:00	2,400
9	大人	○	17:00	21:00	6,000
10	大人	×	16:30	17:30	800
11	大人	○	16:30	17:30	1,800
12	大人	×	16:00	18:00	800
13	大人	×	17:00	19:00	1,000
14	大人	×	9:30	10:30	300

 E2 =CEILING(MAX(0,MIN("17:",MAX(C2:D2))-MIN(C2:D2)),"1:")*24*IF(A2="子ども",100,300)
     +CEILING(MAX(0,MAX(C2:D2)-MAX("17:",MIN(C2:D2))),"1:")*24*IF(A2="子ども",200,500)
     +IF(B2="○",CEILING(D2-C2,"1:"))*24*1000
　
（GobGob） 2016/10/25(火) 15:43

 GobGobさんの表をお借りして。

 =ROUNDUP(TEXT(MAX(0,MIN("17:",D2)-C2),"[h].m"),0)*IF(A2="子ども",100,300)+
  ROUNDUP(TEXT(MAX(0,D2-MAX("17:",C2)),"[h].m"),0)*IF(A2="子ども",200,500)+
  (B2="○")*ROUNDUP(TEXT(D2-C2,"[h].m"),0)*1000,0
 ではどうか。

 なお、式を入力したセルの表示形式を標準あるいは数値にしてくれ。
（ねむねむ） 2016/10/25(火) 16:04

 ねむねむさんの回答をみて。。。。

 よくよく考えたらC:D列のMAX、MIN いりませんでしたーｗ
　
（GobGob） 2016/10/25(火) 16:09

 もしかしたらこちらのパターンか？
 (使用時間中すべて暖房をたくわけではない場合）
 B列、C列が使用時間、D列、E列が暖房使用時間。

	A	B	C	D	E	F
1	区分	FROM	TO	FROM	TO	金額

 =ROUNDUP(TEXT(MAX(0,MIN("17:",C2)-B2),"[h].m"),0)*IF(A2="子ども",100,300)+
  ROUNDUP(TEXT(MAX(0,C2-MAX("17:",B2)),"[h].m"),0)*IF(A2="子ども",200,500)+
  ROUNDUP(TEXT(E2-D2,"[h].m"),0)*1000
（ねむねむ） 2016/10/25(火) 16:18

GobGob様、ねむねむ様ありがとうございました。

（あほまる） 2016/10/25(火) 18:04

コメント返信：

[ 一覧(最新更新順) ]

[[20161025135123]] 『使用料の自動計算』（あほまる） ページの最後に飛ぶ

[[20161025135123]]　『使用料の自動計算』（あほまる）　ページの最後に飛ぶ