[[20170109215315]]　『カンマで区切った名前もCOUNTIFで数えたい』（Ｙ２）　ページの最後に飛ぶ

『カンマで区切った名前もCOUNTIFで数えたい』（Ｙ２）

EXCEL初心者です。
COUNTIF関数で名前を検索してカウントしているのですが、
下記のようにセル内で、カンマで区切っている場合、
名前がカウントされません。
COUNTIFかもしくは他の関数でカウントする方法ないでしょうか？

A1　山田
A2　山本
A3　山田，花井
A4　藤田
A5　山田，鈴木

=COUNTIF(A1:A5,"山田")　　とした場合、1となる

⇒3となるようにカウントしたい。

ご教授のほど、よろしくお願いします。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞.

 =COUNTIF(A1:A5,"*山田*")
であってますか？
(ken)

 ＞ =COUNTIF(A1:A5,"*山田*")

 ↑ だと「藤」をカウントすると「藤田」が引っかかって「1」になってしまうけど、いいんですかね？

 サンプル通り、区切りが「全角のカンマ」だとして、

 =SUMPRODUCT(ISNUMBER(FIND("，山田，","，"&A1:A10&"，"))*1)

 検索条件（山田）をC1セルに入力して、セル参照にすれば

 =SUMPRODUCT(ISNUMBER(FIND("，"&C1&"，","，"&A1:A10&"，"))*1)

 とか。
（笑） 2017/01/09(月) 22:52

早速ありがとうございます。

 =COUNTIF(A1:A5,"*山田*")　　で解決しました。

助かりました。

 >>=COUNTIF(A1:A5,"*山田*")　　で解決しました。

 小山田　といった名前はないんですかねぇ・・・・？

（β） 2017/01/09(月) 23:28

 別案で。

 =COUNT(INDEX(FIND("，山田，","，"&A1:A10&"，"),))
 =COUNT(INDEX(FIND("，"&C1&"，","，"&A1:A10&"，"),))
　
（GobGob） 2017/01/10(火) 08:12

 セルの中に山田が現れるケースは

 山田　　　　　　　　　　（山田のみ）
 山田，吉田　　　　　　　（山田が最初で後続に別名）
 吉田，山田　　　　　　　（先に別名がきて山田が最後）
 吉田，山田，田中　　　　（先に別名があり、山田があって、後続でも別名）

 だとしたら、ベタベタですけど

 =COUNTIF(A1:A4,"山田")+COUNTIF(A1:A4,"山田，*")+COUNTIF(A1:A4,"*，山田")+COUNTIF(A1:A4,"*，山田，*")

（β） 2017/01/10(火) 08:53

コメント返信：