[[20170113113641]] 『経験年数』(まる) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『経験年数』(まる)

社員の経験年数が必要で、当社での経験のみの社員の数式をもとに、他社での経験年数を加算する式を次のように考えてみたのですが、月数が12か月を超えた場合の年数への加算ができません。+4と+9は他社での経験年月数です。よろしくお願いします。

 =DATEDIF(E4,NOW(),"Y")+4&"年"&DATEDIF(E4,NOW(),"YM")+9&"ヶ月"

< 使用 Excel:unknown、使用 OS:unknown >


 Excelのバージョンが不明ですけど、EDATE 関数が使えるものとして、

 =DATEDIF(EDATE(E4,-57),TODAY(),"Y")&"年"&DATEDIF(EDATE(E4,-57),TODAY(),"YM")&"ヶ月"

 EDATE関数の第2引数「-57」は、57ヶ月前(4年9ヶ月前)ということ。

 NOW() → TODAY() に変更しました。

 参考まで。
(笑) 2017/01/13(金) 12:30

 ↑ で合ってるとして、

 =TEXT(DATEDIF(EDATE(E4,-57),TODAY(),"Y"),"0年;;")&TEXT(DATEDIF(EDATE(E4,-57),TODAY(),"YM"),"0ヶ月;;")

 このように数式を変更すると、
 3年0ヶ月 → 3年
 0年9ヶ月 → 9ヶ月
 になります。

 参考まで。
(笑) 2017/01/13(金) 12:51

 EDATE 関数が使えない場合は

 =INT((DATEDIF(E4,TODAY(),"M")+57)/12)&"年"&MOD(DATEDIF(E4,TODAY(),"M")+57,12)&"ヶ月"

 こんな感じですかね?

 参考まで。
(笑) 2017/01/13(金) 13:08

早速のご回答、助かりました。本当にありがとうございます。
13:20頃にお礼を送信したのですが表示されていないようですので、再送しました。
ちなみに当社だけの経験値の数式も変更したほうが良いでしょうか?

 =DATEDIF(E4,NOW(),"Y")&"年"&DATEDIF(E4,NOW(),"YM")&"ヶ月"
(まる) 2017/01/13(金) 16:42


 >当社だけの経験値の数式

 他社での経験期間を加算する必要がない場合、ということならそれでもいいと思いますけど、
 NOW() → TODAY() でいいのでは?(時刻は関係ないので)

 =DATEDIF(E4,TODAY(),"Y")&"年"&DATEDIF(E4,TODAY(),"YM")&"ヶ月"

 それと最初の質問はどんな式で解決したのか知りませんけど、
 3年0ヶ月 → 3年、0年9ヶ月 → 9ヶ月になるようにしたんだったら、
 こっちも

 =TEXT(DATEDIF(E4,TODAY(),"Y"),"0年;;")&TEXT(DATEDIF(E4,TODAY(),"YM"),"0ヶ月;;")

 ですね。
(笑) 2017/01/13(金) 22:06

再度のご回答、ありがとうございました。確かにご指摘の通り TODAY でいいですね。最初のご回答に関しては社内で検討中です。これまでは思い込みと自己流で数式の作成をしていましたが、これからもよろしくお願いいたします。本当にありがとうございました。
(まる) 2017/01/16(月) 14:23

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.