[[20170115161539]] 『重複する名前に該当する回数で最大値を求めたい』(たかなし) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『重複する名前に該当する回数で最大値を求めたい』(たかなし)

A2〜A32までは1ヶ月分の日付、B2〜B32までは曜日、C列とD列には名前(空欄あり)が入ります。
E列とF列には数字(回数:同じ名前には上から昇順に数字が入ります<1・2・3・4・5…>)。
E列 IF(C2="","",COUNTIF(C$2:C2,C2))で回数を表示
F列 IF(D2="","",COUNTIF(D$2:D2,D2))で回数を表示

名前と回数の列は1列だけにしていましたが、二人の場合があるためD列とF列を増やしました。
D列とF列は空白があります。

I列に名前(重複なし・できれば昇順)、J列にIの名前に該当する最大値(回数)を表示させたいです。

よい方法があれば教えて下さい。
また他により良い方法があればご教示ください。


< 使用 Excel:Excel2013、使用 OS:Windows7 >


 こんばんわ。

 名前で並べ替えるならマクロですね。
 数式だと大量の作業列と複雑な計算が必要になると思います。

 マクロで良いならマクロ記録でする時の手順を説明しますが、数式なら手間すぎるので他の方の回答をお待ち下さい。

(sy) 2017/01/15(日) 18:26


手作業だとこんな感じでできます。
「統合」に慣れていれば、そんなに時間かからないはず。
ただし、数式ではないので、データ更新のたび実行が必要です。

1)C列、D列をどこかに1列にコピー
2)その隣の列にすべて1を入力
3)「データ」タブの「統合」を実行(集計方法:データの個数)
4)並べ替えを実行
5)1)2)の列を削除

(マナ) 2017/01/15(日) 18:41


 数式は苦手ですけど、いじくってみました。

 >>できれば昇順

 できれば ということなので無視します。
 作業列も使いますし、前提もあります。

 ・M1 空白
 ・M2 =INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""
  これを、M63までフィルコピー

 ・I1 空白(空白じゃないと具合悪くなります)
 ・I2 =IFERROR(VLOOKUP("*",IF(COUNTIF(I$1:I1,M$1:M$100)=0,M$1:M$100),1,FALSE),"")
  これを Ctrl/Shift/Enter で配列数式として入力し、下にフィルコピー

 あとは J列にCOUNTIFで数をカウント。

(β) 2017/01/15(日) 18:41


 ネットをさがしてみましたらアップした数式に少し作業列を加えることで昇順並びができるようです。

 M列についてはアップした数式の通り。

 I列で提示した数式を N列に以下のように。

 N1 : 空白
 N2 : =IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N1,M$1:M$100)=0,M$1:M$100),1,FALSE),"")
   これをCtrl/Shift/Enter で入力して下にフィルコピー

 O1 : 空白
 O2 : =COUNTIF(N:N,"<"&N2)+1

 O2 を下にフィルコピー

 こうしておいて

 I2 : =IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A1)),O:O,0)),"")
 これを下にフィルコピー

 この場合、I1 は空白でなくてもかまいません(必要ならタイトルをセットしておいてもOK)

 (ネットには O列なしで、N列から直接I列を作り上げる例も出ていましたが理解できないのでアップしません)

(β) 2017/01/15(日) 20:25


 早速コメントいただきまして有難うございます。
 エクセルはあまり詳しくないので申し訳ないのですが、J列のカウント(最大値)表示の数式を教えていただけないでしょうか?
I列の名前はI2からでは無理でしょうか? 教えていただいた通りだと、I55から先頭が表示されます。
(たかなし) 2017/01/16(月) 10:17

 >>I列の名前はI2からでは無理でしょうか? 教えていただいた通りだと、I55から先頭が表示されます。

 私がアップした数式の結果でしょうか?
 I2 から昇順で表示されますけど???

 >>J列のカウント(最大値)表示の数式を教えていただけないでしょうか?

 J2 : =IF(I2="","",COUNTIF(M:M,I2))

 これを下にフィルコピーすればいいのですが?

(β) 2017/01/16(月) 10:25


 ちなみに、こちらでのシートイメージです。
 数式のところ、配列数式(Ctrl/Shift/Enterで入力するところ)も 通常数式のイメージでコピペされてますが
 実際には {数式} でセットされています。

     |[A]      |[B] |[C]  |[D]  |[E]|[F]|[G]|[H]|[I]                                                     |[J]                            |[K]|[L]|[M]                                                        |[N]                                                                         |[O]                    
 [1] |日付     |曜日|名前1|名前2|   |   |   |   |名前                                                    |件数                           |   |   |                                                           |                                                                            |                       
 [2] |2017/1/1 |日  |nm1  |xy1  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A1)),O:O,0)),"") |=IF(I2="","",COUNTIF(M:M,I2))  |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N1,M$1:M$100)=0,M$1:M$100),1,FALSE),"") |=COUNTIF(N:N,"<"&N2)+1 
 [3] |2017/1/2 |月  |nm2  |     |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A2)),O:O,0)),"") |=IF(I3="","",COUNTIF(M:M,I3))  |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N2,M$1:M$100)=0,M$1:M$100),1,FALSE),"") |=COUNTIF(N:N,"<"&N3)+1 
 [4] |2017/1/3 |火  |nm3  |xy3  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A3)),O:O,0)),"") |=IF(I4="","",COUNTIF(M:M,I4))  |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N3,M$1:M$100)=0,M$1:M$100),1,FALSE),"") |=COUNTIF(N:N,"<"&N4)+1 
 [5] |2017/1/4 |水  |     |     |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A4)),O:O,0)),"") |=IF(I5="","",COUNTIF(M:M,I5))  |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N4,M$1:M$100)=0,M$1:M$100),1,FALSE),"") |=COUNTIF(N:N,"<"&N5)+1 
 [6] |2017/1/5 |木  |nm5  |xy5  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A5)),O:O,0)),"") |=IF(I6="","",COUNTIF(M:M,I6))  |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N5,M$1:M$100)=0,M$1:M$100),1,FALSE),"") |=COUNTIF(N:N,"<"&N6)+1 
 [7] |2017/1/6 |金  |nm6  |xy6  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A6)),O:O,0)),"") |=IF(I7="","",COUNTIF(M:M,I7))  |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N6,M$1:M$100)=0,M$1:M$100),1,FALSE),"") |=COUNTIF(N:N,"<"&N7)+1 
 [8] |2017/1/7 |土  |nm7  |     |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A7)),O:O,0)),"") |=IF(I8="","",COUNTIF(M:M,I8))  |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N7,M$1:M$100)=0,M$1:M$100),1,FALSE),"") |=COUNTIF(N:N,"<"&N8)+1 
 [9] |2017/1/8 |日  |nm8  |xy8  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A8)),O:O,0)),"") |=IF(I9="","",COUNTIF(M:M,I9))  |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N8,M$1:M$100)=0,M$1:M$100),1,FALSE),"") |=COUNTIF(N:N,"<"&N9)+1 
 [10]|2017/1/9 |月  |     |xy9  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A9)),O:O,0)),"") |=IF(I10="","",COUNTIF(M:M,I10))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N9,M$1:M$100)=0,M$1:M$100),1,FALSE),"") |=COUNTIF(N:N,"<"&N10)+1
 [11]|2017/1/10|火  |nm10 |     |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A10)),O:O,0)),"")|=IF(I11="","",COUNTIF(M:M,I11))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N10,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N11)+1
 [12]|2017/1/11|水  |nm1  |xy1  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A11)),O:O,0)),"")|=IF(I12="","",COUNTIF(M:M,I12))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N11,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N12)+1
 [13]|2017/1/12|木  |nm2  |     |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A12)),O:O,0)),"")|=IF(I13="","",COUNTIF(M:M,I13))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N12,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N13)+1
 [14]|2017/1/13|金  |     |xy3  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A13)),O:O,0)),"")|=IF(I14="","",COUNTIF(M:M,I14))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N13,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N14)+1
 [15]|2017/1/14|土  |nm4  |xy4  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A14)),O:O,0)),"")|=IF(I15="","",COUNTIF(M:M,I15))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N14,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N15)+1
 [16]|2017/1/15|日  |nm5  |     |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A15)),O:O,0)),"")|=IF(I16="","",COUNTIF(M:M,I16))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N15,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N16)+1
 [17]|2017/1/16|月  |nm6  |xy6  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A16)),O:O,0)),"")|=IF(I17="","",COUNTIF(M:M,I17))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N16,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N17)+1
 [18]|2017/1/17|火  |     |xy7  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A17)),O:O,0)),"")|=IF(I18="","",COUNTIF(M:M,I18))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N17,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N18)+1
 [19]|2017/1/18|水  |nm8  |xy8  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A18)),O:O,0)),"")|=IF(I19="","",COUNTIF(M:M,I19))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N18,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N19)+1
 [20]|2017/1/19|木  |nm9  |xy9  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A19)),O:O,0)),"")|=IF(I20="","",COUNTIF(M:M,I20))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N19,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N20)+1
 [21]|2017/1/20|金  |nm10 |xy10 |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A20)),O:O,0)),"")|=IF(I21="","",COUNTIF(M:M,I21))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N20,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|=COUNTIF(N:N,"<"&N21)+1
 [22]|2017/1/21|土  |     |xy1  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A21)),O:O,0)),"")|=IF(I22="","",COUNTIF(M:M,I22))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N21,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|                       
 [23]|2017/1/22|日  |nm2  |xy2  |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A22)),O:O,0)),"")|=IF(I23="","",COUNTIF(M:M,I23))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N22,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|                       
 [24]|2017/1/23|月  |nm3  |     |   |   |   |   |=IFERROR(INDEX(N:N,MATCH(SMALL(O:O,ROW(A23)),O:O,0)),"")|=IF(I24="","",COUNTIF(M:M,I24))|   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N23,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|                       
 [25]|2017/1/24|火  |     |xy4  |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|=IFERROR(VLOOKUP("*",IF(COUNTIF(N$1:N24,M$1:M$100)=0,M$1:M$100),1,FALSE),"")|                       
 [26]|2017/1/25|水  |nm5  |xy5  |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [27]|2017/1/26|木  |     |xy6  |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [28]|2017/1/27|金  |nm7  |xy7  |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [29]|2017/1/28|土  |     |xy8  |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [30]|2017/1/29|日  |nm9  |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [31]|2017/1/30|月  |nm10 |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [32]|2017/1/31|火  |nm1  |xy1  |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [33]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [34]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [35]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [36]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [37]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [38]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [39]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [40]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [41]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [42]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [43]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [44]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [45]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [46]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [47]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [48]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [49]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [50]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [51]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [52]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [53]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [54]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [55]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [56]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [57]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [58]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [59]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [60]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [61]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [62]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [63]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |=INDEX(C:D,ROW()-INT((ROW()-2)/31)*31,IF(ROW()>=33,2,1))&""|                                                                            |                       
 [64]|         |    |     |     |   |   |   |   |                                                        |                               |   |   |                                                           |                                                                            |                       

(β) 2017/01/16(月) 10:32


ご丁寧に有難うございました。大変助かりました。
(たかなし) 2017/01/16(月) 12:42

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.