[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『if関数で可変の対象を集計したい』(rui)
関数について教えてください。
(タイトルが上手くつけられず、わかりにくく申し訳ありません。。)
A,B,C列の9〜90行目に構成比が入っています。
この構成比にはマイナスのものがあり、マイナスの構成比をなくすために
Aの100行目に、
=IF((A9<0)+(B9<0)+(C9<0),MIN(A9,B9,C9)*-1-MIN(A9,B9,C9)+A9,A9)
という式を入力。これに対して
=IFERROR($A100/($A100+$B100+$C100),0)
という式を入れて、マイナスの構成比を無くしています。、
※上の式に関しては、色々と試してみて一番いい感じの結果になったものを
使用しており、イマイチどういう事をしているのか理解できておりません。。
このA〜Cという列はファイルによって可変するのですが
これを式の中に組み込むことは可能でしょうか?
ちなみに3行目には”商品A””商品B”という名称が入っており
終わりの列はAZ列で固定ですが
商品Aという名称がA〜Cに入っているファイルもあれば
A〜Eまで入っているファイルもあります。
同じ名称の構成比を出したいのですが、同じ数式で全てのファイルを作るのは
難しいでしょうか?
< 使用 Excel:Excel2010、使用 OS:Windows7 >
ちょっと全体のレイアウトが頭に入らないのですが・・・
この数式は、どこのセルに入っているんですか? ↓ >=IFERROR($A100/($A100+$B100+$C100),0)
上の数式はA100セルの構成比ですよね? B100セルの構成比は、どこのセルにどういう数式で入っているんですか?
上の数式で、分子が「$A100」となっているのが不思議に思われるんですけど。
(半平太) 2017/03/24(金) 20:50
お返事ありがとうございます。
説明不足でごめんなさい。
=IFERROR($A100/($A100+$B100+$C100),0)
の式は、Aの190行目に入っています。
一度A100でマイナス分をならし、更にそのならした数字を
A〜Cの数字の中で構成比を出しています。
Bの100には
=IF((A9<0)+(B9<0)+(C9<0),MIN(A9,B9,C9)*-1-MIN(A9,B9,C9)+B9,B9)
という数式は入っており、B190には
=IFERROR($B100/($A100+$B100+$C100),0)
という数式が入っています。
(rui) 2017/03/24(金) 20:53
以下(1)(2)は作業用の行 (1) A98セル =IF(A3="","",MATCH(A$3,$A$3:$AZ$3,0)) (2) A99セル =IF(A3="","",MATCH(1,INDEX(0/($A$3:$AZ$3=A3),0))) それぞれ、右にコピー(AZ列まで)
(3) A100セル =IF(A$3="","",A9-MIN(INDEX($A9:$AZ9,A$98):INDEX($A9:$AZ9,$A99))*OR(INDEX(INDEX($A9:$AZ9,A$98):INDEX($A9:$AZ9,$A99)<0,0))*2) (4) A190セル =IFERROR(A100/SUM(INDEX($A100:$AZ100,A$98):INDEX($A100:$AZ100,A$99)),0) それぞれ、下へ、右へコピー(AZ列まで)
<結果図> 行 __A__ __B__ __C__ __D__ _ E _ 3 商品A 商品A 商品A 商品B 商品C 4 5 6 7 8 9 10 -15 7 29 10 50 30 20 124 11 10 15 7
98 1 1 1 4 5 99 3 3 3 4 5 100 40 15 37 29 0 101 50 30 20 124 0 102 10 15 7 0 0
189 190 0.434783 0.163043 0.402174 1 0 191 0.5 0.3 0.2 1 0 192 0.3125 0.46875 0.21875 0 0
(半平太) 2017/03/24(金) 23:42
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.