[[20170621101417]]　『複数条件で最小値を表示したい』（mori）　ページの最後に飛ぶ

『複数条件で最小値を表示したい』（mori）

現在以下のようなシートがあります。
　A B C
1 1 1 0
2 1 2 5
3 1 3 6
4 2 1 0
5 2 2 0
6 2 3 3

A列には日にちを表す数字
B列には分類を表す数字
C列には値を表す数字

が入っています。
やりたいことは、
条件１：日付が指定した値の時
条件２：C列に0以上の数字が入っている中で
抽出：B列の分類最小値（一番最初にC列の数字が出現したB列の値）
です。

別シートには、日付が縦に入ったものがありますのでその横に分類が表示されるのが理想です。
＜別シート＞

よろしくお願いいたします。

＜使用 Excel：Excel2012(Mac)、使用 OS：Windows7 ＞

 元シートがSheet1だとして。

 別シートのB1セルに
 =INDEX(Sheet1!B$1:B$10,MATCH(1,INDEX(((Sheet1!A$1:A$10=A1)*Sheet1!C$1:C$10>0)*1,0),0))
 と入力して下へフィルコピーではどうか。
（ねむねむ） 2017/06/21(水) 10:41

ねむねむさん早々に御回答いただきありがとうございました！
やりたい事そのものができました！
ありがとうございました！
（mori） 2017/06/21(水) 10:55

 同じようで、ちょっとだけ違います。

 B1 =IFERROR(INDEX(Sheet1!$B$1:$B$100,MATCH(1,INDEX((Sheet1!$A$1:$A$100=A1)*(Sheet1!$C$1:$C$100>0),0),0)),"")
                                                                            ~~~~~~~~~~~~~~~~~~~~~~
 ついでに別案。

 B1 =MIN(IF((Sheet1!$A$1:$A$100=A1)*(Sheet1!$C$1:$C$100>0),Sheet1!$B$1:$B$100))

 これは Ctrl＋Shift＋Enter で確定。
 該当なしの場合「0」になるので表示形式で「0」を非表示にする。

 参考まで。
（笑） 2017/06/21(水) 11:04

笑さん、ありがとうございます！
該当なしの場合「0」になるのは非常に助かります。
またMIN関数で色々試していて迷宮入りしていたので、
別案で自身の間違いが分かり、すっきりしました！
早々のご回答ありがとうございました！！
（mori） 2017/06/21(水) 11:31

 ＞該当なしの場合「0」になるのは非常に助かります。

 IFERRORで始まってる式は、該当なしの場合は空白「""」になります。
「0」の方がいいんだったら、最後の「""」を「0」にしてください。

 参考まで。
（笑） 2017/06/21(水) 11:52

コメント返信：

[ 一覧(最新更新順) ]

[[20170621101417]] 『複数条件で最小値を表示したい』（mori） ページの最後に飛ぶ

[[20170621101417]]　『複数条件で最小値を表示したい』（mori）　ページの最後に飛ぶ