[[20171004150635]]　『表から選択』（SMASH）　ページの最後に飛ぶ

『表から選択』（SMASH）

下記のような表があります。
7番を選ぶと「FFF」と表示させたいのですが
どのようにすればいいでしょうか？

書式はこのままで抽出したいです。
VLOOKUPしか知識がないので、教えて頂けたら幸いです。

A列　B列　　C列　D列
1　　AAA　　6　　EEE
2　　BBB　　7　　FFF
3　　CCC　　8　　GGG
4　　DDD　　9　　HHH
5　　QQQ　　10　　III

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

 =IFERROR(VLOOKUP(A10,A1:B5,2,FALSE),VLOOKUP(A10,C1:D5,2,FALSE))
 や
 =VLOOKUP(A10,IF(COUNTIF(A1:A5,A10),A1:B5,C1:D5),2,FALSE)
 ではどうか。
（ねむねむ） 2017/10/04(水) 15:18

 上記の式はA10セルに検索値が入力される場合。
（ねむねむ） 2017/10/04(水) 15:19

 すでに回答ついてますが、7番でFFFなら普通にVLOOKUPでできますよね？
 後、書式はこのまま、というのはどういう意味ですか？
（コナミ） 2017/10/04(水) 15:25

ねむねむ様
回答ありがとうございます。

もう一つ教えてください。

条件が4つある場合はどのように書式を組めばいいですか？
やってみたのですが、3つ目、4つ目の条件の組み方がわからなくて。。
すみません。
（SMASH） 2017/10/04(水) 15:32

 私の式は2条件ということで作ったもの。
 一応IFERROR関数およびIF関数部分を重ねて対応もできるが式がどんどん長くなっていく。
 =INDEX(B1:D5,SUMPRODUCT((A1:C5=A10)*ROW(1:5)),SUMPRODUCT((A1:C5=A10)*COLUMN(A:C)))
 ではどうか。
 B1:D5部分は結果の範囲、A1:C5は検索範囲となる。

（ねむねむ） 2017/10/04(水) 15:42

 条件が四つ（検索範囲がA1:G5、結果範囲がB1:H5の場合）の場合は
 =INDEX(B1:H5,SUMPRODUCT((A1:G5=A10)*ROW(1:5)),SUMPRODUCT((A1:G5=A10)*COLUMN(A:G)))
 で。
（ねむねむ） 2017/10/04(水) 15:44

 =INDEX(B:H,SUMPRODUCT((A1:G5=A10)*ROW(1:5)),SUMPRODUCT((A1:G5=A10)*COLUMN(A:G)))
 のほうがいいか。
（ねむねむ） 2017/10/04(水) 15:52

コメント返信：

[ 一覧(最新更新順) ]

[[20171004150635]] 『表から選択』（SMASH） ページの最後に飛ぶ

[[20171004150635]]　『表から選択』（SMASH）　ページの最後に飛ぶ