[[20171114141558]]　『住所から市と町を抜き出したい』（柴）　ページの最後に飛ぶ

『住所から市と町を抜き出したい』（柴）

住所が“市”と“町”を抜き出す関数を教えてください。

Ｈ列に住所データがあります。
その住所から“市”と“町”を抜き出す関数をＩ列に設定しました。

        H     　　　　　　　　　  I
1       お客さま／住所　　　　　 地域
2       川越市野田町１丁目       川越市
3       毛呂山町大字市場        毛呂山町大字市

H2セルの住所データが“毛呂山町大字市場”の為、I3セルに表示された地域名が“毛呂山町大字市”になってしまいました。(T_T)

これを“毛呂山町”と表示させるには私が設定した関数
=IF(ISERROR(FIND("市",H2))=FALSE,LEFT(H2,FIND("市",H2)),IF(ISERROR(FIND("町",H2))=FALSE,LEFT(H2,FIND("町",H2)),"")) をどのように修正したらよいでしょうか?

すみませんがご指導ください。
よろしくお願いします。

＜使用 Excel：Excel2007、使用 OS：WindowsXP ＞

 市区町村名が同じものは全国に沢山ありますので、もっと限定できる条件が必要ですよ。

 埼玉県に限っての話なんですか？

（半平太） 2017/11/14(火) 15:02

半平太さま
とりあえず埼玉限定です。
（柴） 2017/11/14(火) 15:07

I2=IF(IFERROR(FIND("町",H2),LEN(H2)+1)>IFERROR(FIND("市",H2),LEN(H2)+1),LEFT(H2,IFERROR(FIND("市",H2),LEN(H2)+1)),IF(IFERROR(FIND("町",H2),LEN(H2)+1)<IFERROR(FIND("市",H2),LEN(H2)+1),LEFT(H2,IFERROR(FIND("町",H2),LEN(H2)+1)),""))
（mm） 2017/11/14(火) 15:42

mmさまご回答ありがとうございます。

関数コピペしたらエラーコード＃ＮＡＭＥ？出てしまいました。
（柴） 2017/11/14(火) 16:07

すみません。
Excelのバージョン確認したら2007ではなく2003でした。<(_ _)>
（柴） 2017/11/14(火) 16:14

 埼玉県限定なら・・・

 I2セル =LEFT(H2,MIN(FIND({"村","町","市"},H2&"市町村")))

 <結果図>
  行  _________H_________  _____I_____
   1  お客さま／住所       地域       
   2  川越市野田町１丁目   川越市     
   3  毛呂山町大字市場     毛呂山町   
   4  東秩父村坂本１丁目   東秩父村   
   5  さいたま市北区       さいたま市

（半平太） 2017/11/14(火) 16:23

半平太さま
ありがとうございました。
希望する結果が表示されました。

（柴） 2017/11/14(火) 20:57

コメント返信：

[ 一覧(最新更新順) ]

[[20171114141558]] 『住所から市と町を抜き出したい』（柴） ページの最後に飛ぶ

[[20171114141558]]　『住所から市と町を抜き出したい』（柴）　ページの最後に飛ぶ