[[20171203112419]]　『カウントの数だけ行数を取りたいのですが』（Yuriko.m）　ページの最後に飛ぶ

『カウントの数だけ行数を取りたいのですが』（Yuriko.m）

エクセルのことでおしえてください。スナックのママです。

下のような表があります。Ｂ10からＷ60までです。合計数量というのは、お酒の合計の数(本)です。
カウントというのは、お酒を入れてくれている法人数と、個人の数(顧客数)です。
これを、同じ表のＡAから、並べたいのです。ＡA10からＡG85までです。
カウントの合計数だけ行数を取って、あとで、顧客の名前をいれたいと思っています。
カウントの数だけ行数を取る方法と、その次の行のAFに合計といれ、ＡＧにカウント合計をいれる方法をおしえてください。関数がありますでしょうか？
よろしくお願いいたします。

表の名前　　　顧客カウント表

     Ｂ　　　  Ｍ　　　　  Ｏ　　　　　　    Ｕ　　　　　　Ｖ　　　　　　　　　Ｗ
9　　コード　 商品　　     合計数量　　　 カウント法人　カウント個人　　　カウント合計
10　　25　　　A　　　　  　 10　　　　　    3　　　　　　    2　　　　　　　　　　　5  
11　　28　　　　B　　　　  　6　　　　　　 0　　　　　    　2　　　　　　　　　　　2
12　　41　　　Ｃ　　　　　   4　　　　　　 2　　　　　　  　1　　　　　　　　　　　3

　
　
　　　　ＡＡ　　　ＡＢ　　　　　ＡＥ　　　　　　ＡＦ　　　　ＡＧ
9　　　番号　　　商品　　　　　顧客名
10　　　25　　　　Ａ　　　
11　　　25　　　　Ａ
12　　　25　　　　Ａ
13　　　25　　　　Ａ
14　　　25　　　　Ａ
15　　　　　　　　　　　　　　　　　　　　　　　合計　　　　　5
16　　　28　　　　Ｂ
17　　　28　　　　Ｂ
18　　　　　　　　　　　　　　　　　　　　　　　合計　　　　　2
19　　　41　　　　Ｃ　
20　　　41　　　　Ｃ
21　　　41　　　　Ｃ　　　　

22　　　　　　　　　　　　　　　　　　　　　　　合計　　　　　3

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 ＞その次の行のAFに合計といれ、ＡＧにカウント合計をいれる方法をおしえてください。
 ＞関数がありますでしょうか？

 関数はちょっと無理があります。(本来データを入れるセルにも数式が入っちゃいます)

 マクロ案はどうですか？

 ＜マクロの貼り付け方＞
 目的のシートの「シート見出し」を右クリックして、「コードの表示(V)」を選ぶと
 画面中央に白いエリアが表れます。(VBE画面です）

 その白いエリアに後記マクロを貼り付けたら、Alt+F11でエクセルに戻れば、準備完了です。

 ＜使い方＞
 　AA9(番号)セルをダブルクリックすると表が自動的に作成されます。
 　※書出し先をクリアにするので前のデータは消えます。危ないんで、それでいいか、初めに聞いてきます。

 ＜貼り付けるマクロ＞
 ’　↓
 Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
     Dim cel As Range, Num As Long, rowOffset As Long

     If Target.Address = "$AA$9" Then
         If MsgBox("AA10:AG85はクリアされます。いいですね？", vbYesNo) = vbYes Then
             Cancel = True

             Range("AA10:AG85").ClearContents

             rowOffset = 0

             For Each cel In Range("B10", Cells(Rows.Count, "B").End(xlUp))
                 Num = Cells(cel.Row, "W").Value

                 Range("AA10").Offset(rowOffset).Resize(Num, 2).Value _
                     = Array(cel.Value, Cells(cel.Row, "M").Value)

                 Cells(10 + Num + rowOffset, "AF").Value = "合計"
                 Cells(10 + Num + rowOffset, "AG").Value = Num
                 rowOffset = rowOffset + Num + 1
             Next
         End If
     End If
 End Sub

（半平太） 2017/12/03(日) 23:34

半平太さま、まことにありがとうございます。
今日は、スナック休日で、箱根にきています。
今日の夜に半平太さまの案でやってみますね。
ありがとうございます。
（Ｙuriko.m） 2017/12/04(月) 09:01

半平太さま、できました。
ありがとうございます。
これで、お客様のボトル管理などをエクセルで
やってみたいと思います。
また、わからないことがあったら
質問させてください。
よろしくお願いいたします。

（Ｙuriko.m） 2017/12/04(月) 19:37

コメント返信：

[ 一覧(最新更新順) ]

[[20171203112419]] 『カウントの数だけ行数を取りたいのですが』（Yuriko.m） ページの最後に飛ぶ

[[20171203112419]]　『カウントの数だけ行数を取りたいのですが』（Yuriko.m）　ページの最後に飛ぶ