[[20180302162319]]　『このケースでの関数を教えてください』（れい）　ページの最後に飛ぶ

『このケースでの関数を教えてください』（れい）

どなたかこのケースの解決法（関数）をご教示いただけませんでしょうか。

　 A 　 B　 C 　D　 E　 F
1　　 1月 2月 3月　　 1月
2 売上 10 40
3 予算 20 20

F1の表示が「1月」の場合、F2に　B2からB3を引いた数字(このケースでは「-10」）を表示させたい。
F1の表示を「2月」に変更した場合、F2に　C2からC3を引いた数字(このケースでは「20」）を表示させたい。

＜使用 Excel：Excel2013、使用 OS：Windows8 ＞

 =HLOOKUP(F1,B1:D3,2,0)-HLOOKUP(F1,B1:D3,3,0)
 でどうでしょうか？
（bi） 2018/03/02(金) 16:49

 実際の表は12月まであるんですか？

 必ず「1月」から始まって、月が連続しているのなら

 F1には「1」とか「2」とか、数値だけを入力（「月」を入力しない）

 =INDEX(B2:D2,F1)-INDEX(B3:D3,F1)
 とか
 =INDEX(B2:D2-B3:D3,F1)
 とか、でも

 参考まで
（笑） 2018/03/02(金) 17:21

(bi)さんのご回答試しましたら、上手く機能しました。ありがとうございます！

追加で質問させてください。

 　 A 　B　 C 　D　 E　 F
1      1月 2月 3月　　 1月
2 売上 10  40
3 予算 20  20
4
5 売上 0 25
6 予算 25 0

F1の表示が「1月」の場合、F5に　B5からB6を引いた数字(このケースでは「-25」）を表示させたい。
F1の表示を「2月」に変更した場合、F5に　C5からC6を引いた数字(このケースでは「25」）を表示させたい。

(笑）様、ありがとうございます。はい、実際は12月まであります。かつ、下にだーっと顧客別に並んでいます。月表示は一番上だけです。今回は「月」表示が必須ですので、教えていただいたやり方は適用できませんが、参考にさせていただきます。
（れい） 2018/03/02(金) 18:01

=HLOOKUP(F1,B1:D6,5,0)-HLOOKUP(F1,B1:D6,6,0) かと思いましたが#REF!で機能しませんでした。
（れい） 2018/03/02(金) 18:04

 ＞=HLOOKUP(F1,B1:D6,5,0)-HLOOKUP(F1,B1:D6,6,0) かと思いましたが#REF!で機能しませんでした。

 こちらで試してみたところ問題なく表示されました。実際のセル位置と合っているかなど
 もう一度よく確かめてみてください。
（bi） 2018/03/03(土) 08:43

機能しました！！（bi）さん、ありがとうございました！！！！！
業務改善に繋がり助かりました！
（れい） 2018/03/03(土) 09:30

 ＞今回は「月」表示が必須ですので、教えていただいたやり方は適用できません

 どういうこと？
「月」を入力しないのは「F1」だけですよ？

 100万歩譲って、F1も「2月」のように「月」も入力する必要があるとして、

 ＞下にだーっと顧客別に並んでいます。

 何行目まで続いているのか知りませんが、
 チマチマと1行1行数式を変更していくつもりですか？

 F2 =INDEX(B2:D2-B3:D3,LEFT($F$1,LEN($F$1)-1))

 F2:F4を選択して、下にだーっとオートフィルするだけでできませんか？
 ~~~~~~~~~~~~~~~
 行数によってはHLOOKUPはあまりお勧めできません。
 どうしてもHLOOKUPでやりたいんだったら

 F2 =HLOOKUP($F$1,$B$1:D3,ROW(A2),0)-HLOOKUP($F$1,$B$1:D3,ROW(A3),0)

 同様にF2:F4を選択して、下にだーっとコピー

 参考まで
（笑） 2018/03/03(土) 10:05

 並び順が変わることがあって、1行目を検索する必要があるのなら

 F2 =INDEX(B2:D2-B3:D3,MATCH($F$1,$B$1:$D$1,0))

 F2:F4を選択して、下にだーっとコピー

 参考まで
（笑） 2018/03/03(土) 10:51

 F2 =SUMIF($B$1:$D$1,$F$1,B2:D2)-SUMIF($B$1:$D$1,$F$1,B3:D3)

 これでもいいです。

 しつこくてすみません
（笑） 2018/03/03(土) 17:15

コメント返信：