[[20180518140521]] 『メールアドレスを分割したい。』(Nara Taro) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『メールアドレスを分割したい。』(Nara Taro)

A1に入力されたメールアドレスをB1に名前、C1に苗字に分割したいのですが、どなたか解決策を教えてください。
よろしくお願いいたします。

A1              B1    C1
nara.taro@yahoo.co.jp  Taro   Nara

< 使用 アプリ:、使用 OS:Windows7 >


 @の前の部分を.で分けるということでいいのだろうか?
 また、.がないものはあるのだろうか?
 もしあったらどうすればいいのあろうか?
(ねむねむ) 2018/05/18(金) 14:15

はい、@の前の部分を.で分けたいです。
.がないことはありません。
必ず.が入ります。
(Nara Taro) 2018/05/18(金) 15:24

 B1:=LEFT(A1,FIND(".",A1)-1)
 C1:=REPLACE(LEFT(A1,FIND("@",A1)-1),1,LEN(B1)+1,"")
 ではどうか。
(ねむねむ) 2018/05/18(金) 15:29

 例示では最初の文字が大文字なのでPROPER関数をかました方がいいかも知れません。
(コナミ) 2018/05/18(金) 15:32

ねむねむさん、コナミさん

ご回答ありがとうございました。
お二方のおかげで、思った通りの作業ができました。

m(_ _)m
(Nara Taro) 2018/05/21(月) 13:29


問題が発生して、困ってます。
メールアドレスに数字が入っている場合があります。
このような場合、どう対処すればよろしいのでしょうか?

A1              B1    C1

 nara.taro123@yahoo.co.jp  Taro   Nara 
(Nara Taro) 2018/05/23(水) 17:06

 数字の部分を省きたいということか?
 数字部分は後ろに固まって入っているだけか?
 先頭や途中、あるいはばらばらに入っているということはあるのだろうか?
(ねむねむ) 2018/05/23(水) 17:10

遅くなって申し訳ありません。

名前の後に数字が入る方がおります。
A2に入力された値を数字を削除して、B2とC2に入れたいです。
ご多忙とは存じますが、ご指導お願いいたします。

A1                 B1    C1
nara.taro123@yahoo.co.jp  Taro   Nara
(Nara Taro) 2018/05/30(水) 11:19


 C1のほうの式を
 =REPLACE(LEFT(A1,MATCH(0,INDEX(0/(MID(SUBSTITUTE(A1,"@","1@"),ROW($1:$50),1)+1),0),0)-1),1,LEN(B1)+1,"")
 でどうか。
(ねむねむ) 2018/05/30(水) 11:28

 おっと一文字目を大文字であればコナミさんの指摘のようにPROPER関数を入れて
 =PROPER(REPLACE(LEFT(A1,MATCH(0,INDEX(0/(MID(SUBSTITUTE(A1,"@","1@"),ROW($1:$50),1)+1),0),0)-1),1,LEN(B1)+1,""))
 か。
(ねむねむ) 2018/05/30(水) 11:30

 1文字の短縮にしかならないが
 =PROPER(REPLACE(LEFT(A1,MATCH(0,INDEX(0/(MID(SUBSTITUTE(A1,"@","1"),ROW($1:$50),1)+1),0),0)-1),1,LEN(B1)+1,"")) 
 でも。
(ねむねむ) 2018/05/30(水) 11:49

ねむねむさん

ご対応ありがとうございました。
問題なく、数字が削除されました。

1点、ROW($1:$50)の意味?役割?を教えていただけないでしょうか?

よろしくお願いいたします。
(Nara Taro) 2018/06/04(月) 17:02


 ROW関数は指定したセルの行番号を返す関数。
 ROW($1:$50)で1、2、3、…、50を返す。
 (MID(SUBSTITUTE(A1,"@","1"),ROW($1:$50),1)
 とMID関数と組み合わせることで対象セルの1文字目から2文字目、3文字目と先頭から1文字ずつ取り出していいる。
(ねむねむ) 2018/06/04(月) 17:11

ねむねむさん

ご対応ありがとうございました。
大変助かりました。
今後とも、よろしくお願いします。

 m(_ _)m
(Nara Taro) 2018/06/05(火) 11:37


コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.