[[20180524002840]] 『曖昧検索ですべて抽出』(けい) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『曖昧検索ですべて抽出』(けい)

 「Sheet2」にデータを保存し、「Sheet1のA1」セルに曖昧検索値を入力。
 「Sheet1のB列(B3」に該当の値すべてを抽出したいです。
 関数だけで行う事は可能でしょうか?

 【Sheet1】
   A     B    
 1 りんご 抽出結果   
 2     赤りんご
 3     青りんご
 4     黄りんご
 5     緑りんご
 6 
 7  

 【Sheet2】
   A    
 1 種類
 2 緑ばなな
 3 赤りんご
 4 赤みかん
 5 青りんご
 6 黄りんご
 7 赤ぶどう
 8 青ぶどう
 9 黄ばなな
 10 緑りんご
 11 青ばなな
 12 赤ばなな

< 使用 Excel:Excel2010、使用 OS:Windows7 >


 Sheet1のB2セルに
 =IFERROR(INDEX(Sheet2!A:A,SMALL(IF(COUNTIF(INDIRECT("Sheet2!A"&ROW($2:$100)),"*"&A$1&"*"),ROW($2:$100),""),ROW(A1))),"")
 と入力してShiftキーとCtrlキーを押しながらEnterキーで式を確定(確定後、式が{}で囲まれればOK)その後、
 下へフィルコピーではどうか。

(ねむねむ) 2018/05/24(木) 09:06


 なお上記式ではSheet2のデータが最大100行までを対象としている。
 もっとある場合は式中の100をすべて大きくしてくれ。

(ねむねむ) 2018/05/24(木) 09:08


 >「Sheet1のB列(B3」に該当の値すべてを抽出したいです。

 B3? 意味不明なので無視します。

 B2 =IF($A$1="","",IFERROR(INDEX(Sheet2!A:A,SMALL(IF(ISNUMBER(FIND($A$1,Sheet2!$A$2:$A$100)),ROW($A$2:$A$100)),ROW(A1))),""))

 Ctrl+Shift+Enterで確定し、下コピー、でも。

 ■ついでの作業列案
 Sheet2
 B2 =IF(Sheet1!$A$1="","",IF(ISNUMBER(FIND(Sheet1!$A$1,A2)),ROW(),""))
 下コピー

 Sheet1
 B2 =IFERROR(INDEX(Sheet2!A:A,SMALL(Sheet2!B:B,ROW(A1))),"")

 Enterだけで確定し、下コピー

 フィルターオプションでもできます。

 参考まで
(笑) 2018/05/24(木) 11:38

 私の式ではA1セルに未入力の場合、すべてが抜き出されることになる。
 もし、A1セルが空白の場合は何も抜き出さないようにするには
 =IF(A$1="","",IFERROR(INDEX(Sheet2!A:A,SMALL(IF(COUNTIF(INDIRECT("Sheet2!A"&ROW($2:$100)),"*"&A$1&"*"),ROW($2:$100),""),ROW(A1))),""))
 としてくれ。
 (Shift+Ctrl+Enterは忘れずに)
(ねむねむ) 2018/05/24(木) 12:46

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.