[[20180803211854]] 『在庫管理で出荷品がいつの入荷分でどれだけの量か』(まさる) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『在庫管理で出荷品がいつの入荷分でどれだけの量かを知りたい』(まさる)

初めて書き込ませていただきます。現在在庫管理を任されており、出荷品の内訳詳細が出るように関数でどうにかできないかと悩んでおります。
例1

入荷日 入荷数 出荷日 出荷数
3月1日 106270 4月1日 88000
3月2日 000000 4月2日 88000
3月3日 106270 4月3日 00000

入荷されたものは約1ヶ月後に出荷されます。入出荷の日はランダムで、入荷数106270、出荷数88000は常に一定です。
例1で言いますと、4月1日出荷分は3月1日入庫分から88000出て行く。4月2日出荷分は3月1日分の残りから14700、3月3日分から73300出て行くというのを例1の出荷数の横に出るようにしたいです。

例2

出荷日 出荷数 出荷詳細
4月1日 88000 3月1日88000
4月2日 88000 3月1日14700 3月3日73300

こんな感じにしたいです。
入出荷数の00000は見やすくしただけで、実際には入出荷はないため0でも空白でも構いません。どうかお力添えの程宜しくお願い致します。

< 使用 Excel:unknown、使用 OS:unknown >


3月1日入庫の106270のうちから4月1日に88000を出荷すれば、残りは18270になりますが、この18270の中から4月2日に14700を出荷すれば、残りは3570になります。この3570はどうするのでしょうか?

(産後の酢橘) 2018/08/04(土) 12:40


返信ありがとうございます。
最初の書き込みの数字が間違っておりました。
正しくは
4月2日出荷は3月2日分の残りから18270、3月3日分から69730
になります。
(まさる) 2018/08/04(土) 13:02

 >関数でどうにかできないかと悩んでおります。

 私には、関数で考える気が起きないですぅー
 マクロの方が簡単じゃないですかー?

 >3月2日 000000 4月2日 88000 
 >3月3日 106270 4月3日 00000 
 何故、入荷や出荷がない時も日付を書くんですか?

 >入出荷の日はランダムで、
 日付は各列昇順じゃないのですか?

 >入荷数106270、出荷数88000は常に一定です。
 と言うことは、明細は、最多でも日付は2個で収まりますね? (=H列より右の列が必要になることは無い)

(半平太) 2018/08/04(土) 16:20


半平太様、返信ありがとうございます。
今までマクロに触ったことがなく、また職場にも詳しい人がいないのが現状です。
入出荷があるなら1、ないなら0とし別シートにて入出荷の有無を○×表にしているため、入出荷がなくても日付はあった方が助かります。
日付は各列昇順です。
明細の日付は2個で収まりますので、H列以降は必要ありません。

(まさる) 2018/08/04(土) 17:56


 >今までマクロに触ったことがなく、また職場にも詳しい人がいないのが現状です。

 そうですか。。

 もう少し待ってみてください。
 関数案が提示されるかも知れません。

(半平太) 2018/08/04(土) 18:57


半平太様ありがとうございます。
気長に待ってみます。
(まさる) 2018/08/04(土) 23:43


 数式案を考えてみました。

 この決まりを頼りに作っています。
 ↓
 >入荷数106270、出荷数88000は常に一定です。

 (1) E2セル =IF(P2>=0,O2,"在庫不足")
 (2) F2セル =IF(OR(N(D2)=0,N(E2)=0),"",IF(N(J1)=N(K1),88000,MIN(88000,N(K1)-N(J1))))
 (3) G2セル =IF(N(E2)=0,"",IF(F2=88000,"",AGGREGATE(15,6,$A$2:$A$500/SIGN($B$2:$B$500),M2)))
 (4) H2セル =IF(G2="","",88000-F2)
 (5) J2セル =N(J1)+N(D2)
 (6) K2セル =CEILING(J2,106270)
 (7) L2セル =K2-J2
 (8) M2セル =K2/106270
 (9) N2セル =IF(N(L1)>0,N(M1),N(M1)+1)
 (10) O2セル =IF(N(D2)=0,"",AGGREGATE(15,6,$A$2:$A$500/SIGN($B$2:$B$500),N2))
 (11) P2セル =SUMIF(A:A,"<="&C2,B:B)-K2

 上記2行目の数式を500行目までコピー

 <結果図>
  行 ___A___ ___B___ ___C___ ___D___ ___E___ ___F___ ___G___ ___H___ _I_ ___J___ _____K_____ ___L___ ____M____ ____N____ ____O____ ____P____
   1 入荷日  入荷数  出荷日  出荷数  明細1           明細2               出荷数  所要入荷数  残余    入荷日数  明細1日数 明細1日付 在庫判定
   2 3月1日  106,270 4月1日  88,000  3月1日  88,000                       88,000    106,270  18,270         1          1 3月1日     531,350 
   3 3月2日          4月2日  88,000  3月1日  18,270  3月3日  69,730      176,000    212,540  36,540         2          1 3月1日     425,080 
   4 3月3日  106,270 4月3日                                              176,000    212,540  36,540         2          2            425,080 

(半平太) 2018/08/06(月) 08:17


半平太様、返信が遅くなり大変申し訳ありません。本当にありがとうございます!完璧です!助かりました!
(まさる) 2018/08/06(月) 20:36

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.