[[20181007222853]]　『下記条件のカウントの仕方が知りたい』（ygr）　ページの最後に飛ぶ

『下記条件のカウントの仕方が知りたい』（ygr）

A列-E列まで1000行で1から9までの数字が入ってるセルがあり列のどこかに1が入っていた時にその列のどこかに2があった場合を1カウントとして1000行までの同条件をカウントしたいのですがご教授頂けませんでしょうか。

例
ABCDE
123456 ←1カウント 1があって2がある
734561 ←0カウント 1があって2がない
523467 ←0カウント 1がなくて2がある

ABCDEFGH

          1
123456   2◯
734561   3◯
523467   4◯

この◯のとこに列のどこかに1がある時その列のどこかに2がある集計を1000行程度行いたい

＜使用 Excel：Excel2007、使用 OS：Windows10 ＞

もっと良い方法はあるとおもいますが、
H列、J列を作業列として
H列に「=CONCATENATE(A1,B1,C1,D1,E1,F1)」で文字列として結合して
J列に「=COUNTIFS(H1,"*1*",H1,"*2*")」で目的の数"字"が含まれるか判定してみてはどうでしょうか？

（もこな２） 2018/10/08(月) 01:45

数字は例で書いておりまして実は1-30程度あるのでその方法だと難しいかもしれません
（ygr） 2018/10/08(月) 03:18

 1行の中に、1と2が両方存在する時に、1や2が複数存在しないと言う前提なら力業で以下の式で出来ます。
 =SUMPRODUCT((A1:A1000=1)*(A1:E1000=2))+SUMPRODUCT((B1:B1000=1)*(A1:E1000=2))+SUMPRODUCT((C1:C1000=1)*(A1:E1000=2))+SUMPRODUCT((D1:D1000=1)*(A1:E1000=2))+SUMPRODUCT((E1:E1000=1)*(A1:E1000=2))

 上記式は、1,1,2,3,4 のように1と2があり、且つ1(もしくは2や両方)が複数の時は重複でカウントされてしまいます。

 G列を作業列に使って、H1に結果を表示なら以下です。
 此方は1や2が複数あっても大丈夫です。
 G1 =COUNTIF(A1:E1,1)*COUNTIF(A1:E1,2)
 H1 =COUNTIF(G:G,">0")

（sy） 2018/10/08(月) 08:01

	A	B	C	D	E	F	G	H	I
1								1	
2	1	2	3	4	5	6		2	1
3	7	3	4	5	6	1		3	2
4	5	2	3	4	6	7		4	2
5								5	2
6								6	2
7								7	1
8								8	0
9								9	0

 H1に1、H2より下に組み合わせ数値

 I2 =SUM((MMULT(($A$2:$F$1001=H$1)+($A$2:$F$1001=$H2),{1;1;1;1;1;1})=2)*1)
 下へコピー。

 ※数値ダブりは考慮してまへん。
（GobGob） 2018/10/08(月) 11:25

 一応、ダブり考慮

 =SUM((MMULT((A$2:F$1001=H$1)*1,{1;1;1;1;1;1})>0)*(MMULT((A$2:F$1001=H2)*1,{1;1;1;1;1;1})>0))
（GobGob） 2018/10/08(月) 12:26

コメント返信：

[ 一覧(最新更新順) ]

[[20181007222853]] 『下記条件のカウントの仕方が知りたい』（ygr） ページの最後に飛ぶ

[[20181007222853]]　『下記条件のカウントの仕方が知りたい』（ygr）　ページの最後に飛ぶ