[[20190114112233]]　『重複』（まさ）　ページの最後に飛ぶ

『重複』（まさ）

C列に=B2&C2　式を入れ下へコピーしています。
D列に重複式　=IF(ISNA(VLOOKUP(D2,$D$2:$D$7,1,FALSE)),"","重複")を入れました。
C列の空白部分も重複と出るので、空白にする方法を教えて下さい。

	A	B	C	D(重複）
1	5	A	 =B2&C2	 =IF(ISNA(VLOOKUP(D2,$D$2:$D$7,1,FALSE)),"","重複")
2	2	b	2b	重複
3	1	c	1c	重複
4				重複
5				重複
6				重複
7				重複

Windows 10を使用しています。
宜しくお願いいたします。
　　　まさ

＜使用 Excel：unknown、使用 OS：unknown ＞

 よーわかりませんが。。。

 ・1行目のB2&C2って「=A1&B1」の間違い?

 ・D列は循環参照にならない？

（GobGob） 2019/01/14(月) 15:18

 一応。

 C1 =A1&B1
 D1 =IF(COUNTIF(C:C,C1)>1,"重複","")

 C1:D1 下へコピー。

 ってこと？
（GobGob） 2019/01/14(月) 15:19

（GobGob）さん
　
　有難うございます。
　C列は私が間違っていました。

　下記のように再度テストした結果
　C列　C7までコピーしました。

　A4:B7が空白の場合　D4：D7の重複を無くしたいのですか
　
　アドバイス宜しくお願いいたします。
　

	A	B	C	D(重複）
1	5	A	 =A1&B1	  =IF(COUNTIF(C:C,C1)>1,"重複","")
2	2	b	2b	
3	1	c	1c	
4				重複
5				重複
6				重複
7				重複
				重複

（まさ） 2019/01/14(月) 17:40

=IF(OR(A1="",B1=""),"",IF(COUNTIF($C$1:$C$7,C1)>1,"重複",""))
または
=IF(AND(A4="",B4=""),"",IF(COUNTIF($C$1:$C$7,C4)>1,"重複",""))
状況により使い分けてください。

（のりん） 2019/01/14(月) 19:10

 別案で、、
 =IF(COUNT(A1:C1)=0,"",IF(COUNTIF(C:C,C1)>1,"重複",""))
（SoulMan） 2019/01/14(月) 19:47

（のりん）さん

　有難うございました。
　
　見事に重複が消えました。

　（まさ）
（まさ） 2019/01/15(火) 03:41

追伸

＞C列の空白部分も重複と出るので、
「=A1&B1」の「&」はご存知だと思いますので割愛させてもらいます。
よって「C1」の値は文字列になります。空白である「""」で処理されるため以降
空白部分は「重複」となります。
（まさ） 2019/01/14(月) 17:40のなかで
＞D4：D7の重複を無くしたいのですか
「B4～B7」の式を削除してみてください。「重複」は出で来ないです。

このように数式が入っているセルを扱うには注意が必要です。

参考にしてください。

（まさ）さんの表をお借りしました。

		A	B	C	D	E

	1	5	A	5A		重複
	2	2	b	2b		重複
	3	1	c	1c		重複
	4	5	A	5A	重複	重複
	5	2	b	2b	重複	重複
	6	1	c	1c	重複	重複
	7	5	A	5A	重複	重複

D1=IF(AND(A1="",B1=""),"",IF(COUNTIF($C$1:$C1,C1)>=2,"重複",""))
E1=IF(AND(A1="",B1=""),"",IF(COUNTIF($C$1:$C$7,C1)>=2,"重複",""))

D1は２つ目以降の重複データをチェック
E1は重複するデータを全てチェック
※引数リスト(値)の設定に注意する。
D1はＢ列を絶対、行を相対にしているのに対しE1は列、行とも絶対にしている。

私の場合は上記の表のように二種類を表示させています。重複削除はD1の方で行っています。
今のところ手動で削除していますが。
（のりん） 2019/01/15(火) 22:12

（SoulMan）　さん

大変申し訳ありませんでした。
SoulManの指導で見事に解決したのを
他の人の名前で更新してしまいました。
本当に有難う御座いました。

　（まさ）
（まさ） 2019/01/19(土) 05:00

 ↓ の式で解決したってこと？
 ＞=IF(COUNT(A1:C1)=0,"",IF(COUNTIF(C:C,C1)>1,"重複",""))

 B列とC列は文字列なのに、なんでCOUNT関数（数値の個数）なんですかね？

 =IF(C1="","",IF(COUNTIF(C:C,C1)>1,"重複",""))

 でいいのでは？

 ■参考
 C列を使わなくてもできそうですけど

 Excelのバージョンが不明ですが、
 2007以降なら COUNTIFS（≠COUNTIF）で

 =IF(A1&B1="","",IF(COUNTIFS(A:A,A1,B:B,B1)>1,"重複",""))

 2003以前なら SUMPRODUCT で

 以上
（笑） 2019/01/19(土) 17:32

コメント返信：

[ 一覧(最新更新順) ]

[[20190114112233]] 『重複』（まさ） ページの最後に飛ぶ

[[20190114112233]]　『重複』（まさ）　ページの最後に飛ぶ