[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『計算式について』(ユカ)
マッサージ部位 変形徒手部位 距離 合計
の4項目につての計算式を教えていただけますでしょうか。
マッサージ部位は1部位340円
変形徒手部位は1部位 780円
マッサージ部位欄には1〜5の数字が入ります。
変形徒手部位欄には1〜4の数字が入ります。
距離は1キロ〜4キロの場合2300円
4キロ以上の場合は2700円
合計欄に マッサージ部位 340円×1〜5 + 変形徒手部位 780円×1〜4
+ 距離が1〜4キロの場合は2300円 ・4キロ以上の場合は2700円の合計金額が
出るようにする計算式を教えていただけますでしょうか。
お忙しいところお手数おかけいたします。
宜しくお願い致します。
< 使用 Excel:Excel2013、使用 OS:Windows10 >
A B C D 1 マッサージ部位 変形徒手部位 距離 合計 2 2 3 5 5720 3 2 3 2 5320
4キロ以下2300,4キロ超える2700といううことで D1に =IF(COUNT(A2:C2)=0,"",IF(C2>=4,2700+(A2*340)+(B2*780),2300+(A2*340)+(B2*780))) あと下へ、づりづり 間違えていましたら済みません m(_ _)m ^^; でわ
(隠居じーさん) 2019/01/15(火) 20:49
追加事項としまして、距離が0キロの場合は、マッサージ部位+変形徒手部位の合計のみが入るようにしていただきたいのですが、お分かりになりますでしょうか。
今の計算式ですと、距離0キロでも+2300円されてしまいますので、そちらが解決できる計算式を教えていただけますでしょうか。
大変お手数おかけいたします。
よろしくお願い致します。m(__)m
(ユカ) 2019/01/15(火) 21:42
これは、お店なのかな? 明細が見えた方がよくないですか?
項目 単価 数量 金額 マッサージ部位 340 1 340 =B2*C2 変形徒手部位 780 3 2340 距離1キロ〜4キロ 2300 0 0 距離4キロ以上 2700 0 0 合計 4 2680 =SUM(D2:D5) (SoulMan) 2019/01/15(火) 21:57
A B C D 1 マッサージ部位 変形徒手部位 距離 合計 2 2 3 5 5720 3 2 3 2 5320
この表で、距離が0キロの時に距離の金額が入らないようにしたいのです。
計算式は隠居じー様に教えていただいた
D欄に
=IF(COUNT(A2:C2)=0,"",IF(C2>=4,2700+(A2*340)+(B2*780),2300+(A2*340)+(B2*780)))
こちらの計算式で概ね良いのですが、距離0キロの時にも
2300円が入ってしまうので、そちらの解決計算式をどなたかお教えいただけますでしょうか。
よろしくお願い致します。
お手数おかけいたします。。
(ユカ) 2019/01/15(火) 22:26
こうかな? =IF(COUNT(A2:C2)=0,"",IF(C2=0,(A2*340)+(B2*780),IF(C2>=4,2700+(A2*340)+(B2*780),2300+(A2*340)+(B2*780)))) (SoulMan) 2019/01/15(火) 22:31
なんとなく↓こっちの方がいいかも? =IF(COUNT(A2:C2)=0,"",IF(C2=0,(A2*340)+(B2*780),IF(C2<4,2300+(A2*340)+(B2*780),2700+(A2*340)+(B2*780)))) (SoulMan) 2019/01/15(火) 22:40
SoulManさん ユカ さん すみません ありがとうございました。 寝ていました ^^ zzzz 解決されたみたいなので 失礼致します m(__)m でわ
(隠居じーさん) 2019/01/15(火) 23:19
まだ、トピ主さんからお返事頂いていませんよ 私ももう寝ます おやすみなさい😘 (SoulMan) 2019/01/15(火) 23:22
はい でわ おやすみなさい ^^
(隠居じーさん) 2019/01/15(火) 23:25
おかげ様で概ね解決いたしました。
何度か返信したのですが、送れていませんでした。
遅いお時間までお付き合いいただきありがとうございました。
残る問題は、
4キロピッタリの場合は2300円
4.1キロの場合は2700円になるようにしたいのですが。。
現在は4キロの場合、2700円になってしまうのです。
何度もすみません。
お時間のある時に教えていただけますでしょうか。
よろしくお願い致しますm(__)m
(ユカ) 2019/01/15(火) 23:45
>4キロピッタリの場合は2300円
C2<4 を C2<=4 とすればよいです。 =IF(COUNT(A2:C2)=0,"",IF(C2=0,(A2*340)+(B2*780),IF(C2<=4,2300+(A2*340)+(B2*780),2700+(A2*340)+(B2*780))))
往療料 2,300円
往療距離が片道4キロメートルを超えた場合は、2,700円
なのですね。。。
(檸檬) 2019/01/16(水) 01:32
=SUMPRODUCT(A2:B2,{340,780})+LOOKUP(CEILING(C2,4),{0,4,5},{0,2300,2700}) ~~~~~~~(1)~~~~~~~~~~~~~~~~~ ~~~~(2)~~~~~ ~~~~~~~~~(3)~~~~~~~~~~ こういうのだと、分かりにくいですか?
(1)で(マッサージ部位×340円)+(変形徒手部位×780)を計算して
(2)で距離を計算 0 = 0─移動無し 0.1 = 4┐ 3.9 = 4┼4km以内 4.0 = 4┘ 4.1 = 5─4km超え
(3)で距離に応じた金額を出す 0 = 0円 4以下 = 2300円 5以上 = 2700円
わかりにくかったら、隠居じーさんさんの式を少し整頓して =IF(COUNT(A2:C2)=0,"",(A2*340)+(B2*780)+IF(C2=0,0,IF(C2>4,2700,2300))) こちらのほうが、あとから直しやすいかなと。 (稲葉) 2019/01/16(水) 08:33
計算式の説明で、誤りがあったので訂正します。 (2)で距離を計算 〜〜中略 4.1 = 5─4km超え ←誤り 4.1 = 8─4km超え ←正しくは4の倍数にあたる、8が返ります。 CEILING関数は、二番目の引数に指定した値に切り上げる関数で、今回は4を指定したので 0,4,8,12,16・・・の値を返します。
(3)の補足 LOOKUPの検索は、「検査範囲内で検査値以下の最大値が、一致する値」として判断されますので、 3つ目の引数を省略して説明すると LOOKUP(0,{0,4,5}) = 0 LOOKUP(4,{0,4,5}) = 4 LOOKUP(8,{0,4,5}) = 5 ← 8は{0,4,5}の中にないので、検査値以下の最大である、5を返します。 LOOKUP(12,{0,4,5}) = 5 ←12は{0,4,5}の中にないので、検査値以下の最大である、5を返します。 となり、この結果に3つ目の引数を追加すると
LOOKUP(0,{0,4,5},{0,2300,2700}) = 0 LOOKUP(4,{0,4,5},{0,2300,2700}) = 2300 LOOKUP(8,{0,4,5},{0,2300,2700}) = 2700 LOOKUP(12,{0,4,5},{0,2300,2700}) = 2700 となります。
(稲葉) 2019/01/16(水) 09:04
=A2*340+B2*780+IF(C2>0,IF(C2>4,2700,2300)) (GobGob) 2019/01/16(水) 10:32
皆様お忙しいところ、ご丁寧に回答していただきましてありがとうございました。
おかげ様で、必要としていた計算式が無事に完成致しました。
心より感謝申し上げます。
ありがとうございました。
(ユカ) 2019/01/16(水) 11:39
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.