[[20190118174554]]　『桁数をバラバラにしたい』（オソマ）　ページの最後に飛ぶ

『桁数をバラバラにしたい』（オソマ）

はじめまして。
エクセルの関数で桁数をバラバラにしたいです。

・I列には1桁～2桁の数字が入り、J列には最高で3桁の数字が入ります。
・LとM列は、I列を分割した数字を入れます。L列は1桁目、M列は2桁目
・N、O、P列は、J列を分割した数字をいれます。N列1桁目、O列2桁目、P列3桁目です。

理想
I列　J列　　　L列　M列　N列　O列　P列
40　　573　　　4　　0　　5　　7　　3　

K列　空欄

L列=MID(I10,1,1)
M列=MID(I10,2,1)

N列=MID(J10,1,1)
O列=MID(J10,2,1)
P列=MID(J10,3,1)

上記の関数を入れて完成したと思ったのですが、例えば、I列が一桁の場合は、
本来は、M列に表示させたいのに、L列に数字が入ってしまいます。

またJ列が2桁の場合も、N～P列は左よせになってしまいます。
無知で申し訳ございませんが教えていただけますと幸いです。

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 L10=MID(TEXT($I$10,"00")&TEXT($J$10,"000"),COLUMN(A1),1)
 右方向にコピーじゃだめですか？
（稲葉） 2019/01/18(金) 18:18

 I10が「4」、J10が「73」だったら、L列とN列はどうなればいいんですか

	I	J	K	L	M	N	O	P
10	4	73			4		7	3

 L10、N10は空白？

 L10 =IFERROR(MID(TEXT($I10,"??"),COLUMN(A1),1)*1,"")　　M10にコピー

 N10 =IFERROR(MID(TEXT($J10,"???"),COLUMN(A1),1)*1,"") 　P10までコピー

 こういうこと？
（笑） 2019/01/18(金) 18:42

 稲葉さんの式をちょっと変更して

 L10 =IFERROR(MID(TEXT($I10,"??")&TEXT($J10,"???"),COLUMN(A1),1)*1,"")

 P10までコピー

 これでよかったかも
（笑） 2019/01/18(金) 19:03

ご返信が遅くなり申し訳ありません。
（稲葉）様　ありがとうございます。
（笑）様　ありがとうございます！今回最後のコメントの式で解決することができました！
ありがとうございます!(^^)!

（オソマ） 2019/01/21(月) 09:48

コメント返信：