[[20190305202733]]　『地域別、重量別送料を求める関数』（にほんゆうびん）　ページの最後に飛ぶ

『地域別、重量別送料を求める関数』（にほんゆうびん）

重量地帯１　２　３
50 　3 　　3 3
100 　3 　　5 6
150 　6 　　6 7
200 　6 　　7 8

上記の重量別料金表が有ります。
地帯１で150ｇ以下なら6、地帯３で200g以下なら8と表示させたいのですが、
どうしたら良いでしょうか？

また重量地帯に加え、発送方法A、B、Cがあり、
それぞれ同様の重量別料金表があります故、
発送方法Aの地帯１で150g以下なら6という結果を出したいです。

＜使用 Excel：Office365、使用 OS：MacOSX ＞

 発送方法ABCについて、表の提示がないですが、
 回答者側で考えた表を作ってもらえます？
 あと、どこに求めたい発送方法や地域（地帯？）の入力があるのか、
 説明いただけると回答しやすいです
（稲葉） 2019/03/06(水) 07:08

 追加で、201グラム以上の値段、または取り扱いなしなど
 情報ください
（稲葉） 2019/03/06(水) 07:09

 返事がないけど・・・夜見られるかわからないのでたたき台
 １）発送方法別に表を分けてください。
 　　重量項目は1～50が1、51～100が51となっています。
 ２）発送方法をB10、重量をB11、地帯をB12に入力してください。
 ３）以下にセルに数式を入れてください。
 　　C10　=FIND(B10,"ABC")
 　　C11　=MATCH(B11,INDEX(($A$3:$A$7,$F$3:$F$7,$K$3:$K$7),,,$C$10),1)
 　　C12　=MATCH(B12,INDEX(($B$2:$D$2,$G$2:$I$2,$L$2:$N$2),,,$C$10),1)
 　　C13　=INDEX((B3:D7,G3:I7,L3:N7),C11,C12,C10)
 ４）C13が送料になります。

     |[A]      |[B]   |[C]   |[D]   |[E]|[F]      |[G]   |[H]   |[I]   |[J]|[K]      |[L]   |[M]   |[N]   
 [1] |発送方法A|      |      |      |   |発送方法B|      |      |      |   |発送方法C|      |      |      
 [2] |重量     |地帯１|地帯２|地帯３|   |重量     |地帯１|地帯２|地帯３|   |重量     |地帯１|地帯２|地帯３
 [3] |        1|     3|     3|     3|   |        1|    31|    31|    31|   |        1|    32|    32|    32
 [4] |       51|     3|     5|     6|   |       31|    31|    51|    61|   |      101|    32|    52|    62
 [5] |      101|     6|     6|     7|   |       91|    61|    61|    71|   |      201|    62|    62|    72
 [6] |      151|     6|     7|     8|   |      121|    61|    71|    81|   |      301|    62|    72|    82
 [7] |      201|取扱無|取扱無|取扱無|   |      151|取扱無|取扱無|取扱無|   |      401|取扱無|取扱無|取扱無
 [8] |         |      |      |      |   |         |      |      |      |   |         |      |      |      
 [9] |         |      |      |      |   |         |      |      |      |   |         |      |      |      
 [10]|発送方法 |A     |     1|      |   |         |      |      |      |   |         |      |      |      
 [11]|重量     |   150|     3|      |   |         |      |      |      |   |         |      |      |      
 [12]|地帯     |地帯１|     1|      |   |         |      |      |      |   |         |      |      |      
 [13]|         |送料  |     6|      |   |         |      |      |      |   |         |      |      |      
（稲葉） 2019/03/06(水) 14:18

 ちょっと確認

 ・地帯コードは実際の表も「1、2、3」なんですか？
 ・発送方法は、実際の表も「A、B、C」なんですか？

 一応、地帯コードは「1、2、3」だとして

 3つの表をそれぞれの発送方法で名前定義
 ※ただし「C」一文字では名前定義できません

 何となく実際は「A、B、C」ではないような気がするので、先に進みます。

	A	B
10	発送	A
11	重量	150
12	地帯	1
13		6

 B13 =IF(COUNTA(B10:B12)<3,"",VLOOKUP(B11,INDIRECT(B10),B12+1,TRUE))

 ■発送方法が実際も「A、B、C」なら

 それぞれの表を「発送A」「発送B」「発送C」と名前定義

 B13 =IF(COUNTA(B10:B12)<3,"",VLOOKUP(B11,INDIRECT("発送"&B10),B12+1,TRUE))

 以上、参考まで
（笑） 2019/03/06(水) 15:16

 笑さんの提示いただいた式は、私の作り直した表（行方向に1,51,101・・・）ってことで、
 VLOOKUP(,,,TRUE)ですよね？
 一応ご確認です。
（稲葉） 2019/03/06(水) 15:44

コメント返信：

[ 一覧(最新更新順) ]

[[20190305202733]] 『地域別、重量別送料を求める関数』（にほんゆうびん） ページの最後に飛ぶ

[[20190305202733]]　『地域別、重量別送料を求める関数』（にほんゆうびん）　ページの最後に飛ぶ