[[20190418092454]]　『当月件数の連続番号を日付+番号をつけたい』（そら）　ページの最後に飛ぶ

『当月件数の連続番号を日付+番号をつけたい』（そら）

A列に入力された日付に対し、B列に連続番号を関数で計算表示する

A（記載日付入力）　　　B（連続番号を表示）
2019/3/1　　　　　1
2019/3/1　　　　　2
2019/3/3　　　　　3
2019/3/5　　　　　4　　　

2019/4/1　　　　　1
2019/4/2　　　　　2

よろしく願いします

＜使用 Excel：Excel2019、使用 OS：Windows8 ＞

 B1: =COUNTIFS($A$1:$A1,">="&DATE(YEAR($A1),MONTH($A1),1),$A$1:$A1,"<"&DATE(YEAR($A1),MONTH($A1)+1,1))
（???） 2019/04/18(木) 09:51

 =IF(A1="","",COUNTIFS(A$1:A1,">"&EOMONTH(A1,-1),A$1:A1,"<="&EOMONTH(A1,0)))
 でも。
（ねむねむ） 2019/04/18(木) 09:56

 A列が昇順であれば
 =IF(A1="","",COUNTIFS(A$1:A1,">"&EOMONTH(A1,-1),A$1:A1,"<="&A1))
 でも。
（ねむねむ） 2019/04/18(木) 09:57

 >2019/3/5　　　　　4　　　 
 >
 >2019/4/1　　　　　1

 月が替わったら、1行空けてるってこと？

 分かりやすいように1行空けただけで、実際は詰めて入力しているのなら
 ↓ でできませんか？（2019年4月の次に、いきなり1年飛んで2020年4月の日付が入るようなことがなければ）

 B2 =IF(A2="","",1)
 B3 =IF(A3="","",IF(MONTH(A3)=MONTH(A2),B2+1,1))
 B3を下にコピー

 または

 B2 =IF(A2="","",IF(TEXT(A1,"m;;")=TEXT(A2,"m"),B1+1,1))
 B2を下にコピー

 実際も月が替われば1行空けてるんだったら
 上のセルが空白かどうかで判定すればいいと思いますけど。

 参考まで
（笑） 2019/04/18(木) 11:37

みなさんご指導ありがとうございます。
思い通りできました有難うございます。
（そら） 2019/04/18(木) 12:47

コメント返信：