[[20190622163351]] 『複数条件に合う抽出』(LL) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『複数条件に合う抽出』(LL)

	A	B	C
1		色	大きさ
2	あ	130	180
3	い	150	210
4	う	200	250
5	え	220	300

というシート1から

	A	B	C
1	色	大きさ	
2	101-200	201-300	い
3			う

とシート2のC2以下にしたい場合
C2以下はどう関数を入れるのでしょう。
A2の101-200は101以上200未満という意味です。

< 使用 Excel:unknown、使用 OS:unknown >


 べたべたな式ですけど、、、↓と入力してCtrl+Shift+Enter でどうでしょう?

 =IFERROR(INDEX(Sheet1!$A$2:$A$5,
SMALL(IF((Sheet1!$B$2:$B$5>=101)*(Sheet1!$B$2:$B$5<=200)*(Sheet1!$C$2:$C$5>=201)*(Sheet1!$C$2:$C$5<=300),ROW($A$1:$A$4)),ROW(A1))),"")
(SoulMan) 2019/06/22(土) 18:58

 >A2の101-200は101以上200未満という意味です。 
 であれば「う」の200で200未満ではないので抜き出す対象ではないのでは?
(ねむねむ) 2019/06/24(月) 09:17

 おっと
 >であれば「う」の200で200未満ではないので抜き出す対象ではないのでは?
 は
 であれば「う」の色は200で200未満ではないので抜き出す対象ではないのでは?

(ねむねむ) 2019/06/24(月) 09:18


 ひとまずA-BをA以上B未満として。
 =IFERROR(INDEX(Sheet1!A$1:A$5,SMALL(IF((Sheet1!B$2:B$5>=LEFT(A$2,FIND("-",A$2)-1)*1)*(Sheet1!B$2:B$5<=REPLACE(A$2,1,FIND("-",A$2),"")*1)*(Sheet1!C$2:C$5>=LEFT(B$2,FIND("-",B$2)-1)*1)*(Sheet1!B$2:B$5<=REPLACE(B$2,1,FIND("-",B$2),"")*1),ROW($2:$5),""),ROW(A1))),"")
 Shift+Ctrl+Enterで式を確定で(確定後、式が{}で囲まれればOK)
(ねむねむ) 2019/06/24(月) 09:24

 私の式の場合は最初の
 Sheet1!A$1:A$5
 部分を必ず1行目からとしてくれ。
(ねむねむ) 2019/06/24(月) 09:24

 すまない。
 式は
 =IFERROR(INDEX(Sheet1!A$1:A$5,SMALL(IF((Sheet1!B$2:B$5>=LEFT(A$2,FIND("-",A$2)-1)*1)*(Sheet1!B$2:B$5<=REPLACE(A$2,1,FIND("-",A$2),"")*1)*(Sheet1!C$2:C$5>=LEFT(B$2,FIND("-",B$2)-1)*1)*(Sheet1!C$2:C$5<=REPLACE(B$2,1,FIND("-",B$2),"")*1),ROW($2:$5),""),ROW(A1))),"")
 だった。

(ねむねむ) 2019/06/24(月) 09:28


 なお、色の下限をA2セル、上限をB2セル、大きさの下限をC2セル、上限をD2セルに入れるようにすると式は
 =IFERROR(INDEX(Sheet1!A$1:A$5,SMALL(IF((Sheet1!B$2:B$5>=A$2)*(Sheet1!B$2:B$5<=B$2)*(Sheet1!C$2:C$5>=C$2)*(Sheet1!C$2:C$5<=D$2),ROW($2:$5),""),ROW(A1))),"")
 で。
 (Shift+Ctrl+Enterを忘れずに)
(ねむねむ) 2019/06/24(月) 09:32

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.